2DArray --> Neo4j

[iamtheky]

Hopefully this expands as I get to play more with Neo4j.  Starting simple here is an example of mapping artists to the bands they are in (a not quite complete Puscifer visualization).

 

 

 

expandcollapse popup

;2DArray TO Neo4j
#include<array.au3>

Local $aBandMaster[0]           ;  declare this array fo later
Local $aArray[1][2]             ; declare this array for right....now

$aArray[0][0] = "name"          ;Title of column 1, will also be the Property of the NODEs established by the elements in this column
$aArray[0][1] = "is_member_of"  ;Title of column 2, will also be the Relationship of the items in column 1 to those in column 2

$Property = $aArray[0][0]                ; Using 0,0 as property
$Relationship = $aArray[0][1]            ; using 0,1 as relationship


                                        ;creating a 2D array with semicolon as the delimiter between the NAME (The Property) ; IS_MEMBER_OF (The Relationship)
                                        ;(The Relationship) for this example, is a comma delimited list of the bands that the person IS_MEMBER_OF

_ArrayAdd($aArray , "Jeff;Puscifer,APC,EODM,TBM,CarinaRound,Filter" , 0 , ";")
_ArrayAdd($aArray , "MJK;Puscifer,APC,Tool" , 0 , ";")
_ArrayAdd($aArray , "MattMc;Puscifer,EODM,TBM" , 0 , ";")
_ArrayAdd($aArray , "Carina;Puscifer,CarinaRound" , 0 , ";")
_ArrayAdd($aArray , "MatMit;Puscifer" , 0 , ";")
_ArrayAdd($aArray , "Paul;Puscifer,Ministry" , 0 , ";")
_ArrayAdd($aArray , "Mahsa;Puscifer,Omniflux" , 0 , ";")

;~ _ArrayDisplay($aArray)                   ; Mira! it is the array we just created



$sOutStr = "Create" & @LF                   ;sOutStr will be the running catchall for the command we eventually want to run in Neo4j

For $i = 1 to ubound($aArray) - 1

    $sOutStr &= "(" & $aArray[$i][0] & ":Person {" & $Property & ": '" & $aArray[$i][0] & "'})," & @LF     ; as we are looping through, use column one to create NODES that are PERSONS (this is assumed unique, if not you should get on that)

    _ArrayAdd($aBandMaster , stringsplit($aArray[$i][1] , "," , 2))                                         ; also while looping split all the comma delimited strings in column 2 and make one big list of bands stored in $aBandMaster

;~     _ArrayDisplay($aBandMaster , "BandMaster")
Next

$aBands = _ArrayUnique($aBandMaster)        ; unique that master list and now we have a nice list of all of the bands from everyones list

;~ _ArrayDisplay($aBands , "unique bands")

For $k = 1 to $aBands[0]

    $sOutStr &= "(" & $aBands[$k] & ":Band {" & $Property & ": '" & $aBands[$k] & "'})," & @LF              ;roll through that list once creating NODES, one for each BAND

Next

For $i = 1 to ubound($aArray) - 1

    $aPersonalBands = stringsplit($aArray[$i][1] , "," , 2)                     ; second loop, only this time we are building relationships, so we are working only off of the comma separated list for each individual

        For $k = 0 to ubound($aPersonalBands) - 1

            $sOutStr &= "(" & $aArray[$i][0] & ")-[:" & $Relationship & "]->(" & $aPersonalBands[$k] & ")," & @LF                   ;Since those NODES were created above, we know their names and can build RELATIONSHIPS

        Next

Next


consolewrite(stringtrimright($sOutstr , 2) & @LF)                                   ; This should be able to copy/paste directly into Neo4j



;  match n optional match (n)-[r]-() return n, r;                                   ; you need to run this afterward in Neo4j for the visualization

 

 

Edited December 28, 2015 by iamtheky
updated visual and code

[argumentum]

... Hopefully this expands as I get to play more with Neo4j. ...

Hope it does, because to get a clue, I installed the Community Edition and I'd like to try it   

[iamtheky]

i went the docker route for installing neo4j.  I believe the latest docker installer comes with Kitematic, which essentially gives you a storefront to just spin up and down environments way easy.

[guinness]

Cool @iamtheky. It's strange because for 10 years now I have been saying that I can connect any band or musician back to Tool, so funny you should create this example.

[iamtheky]

*update to give the visual a little more substance, and to make sure it was handling single entries ok (it was!)

[iamtheky]

* I get to see EODM tonight - would have been more fitting in the locked Paris thread, but I am so glad these guys are finishing their tour.  It's the biggest ..i., that can be given.