Noob Question: Best way of populating a 2 dimensional array?

[TheDcoder]

Hello, I wonder if there is a better way than this!:

#include <Array.au3>

Local $aArray[1][3]

$aArray[0][0] = 1
$aArray[0][1] = 2
$aArray[0][2] = 3

;$aArray[0] = [1, 2, 3]

_ArrayDisplay($aArray)

IIRC line no. 9 should work, but its not

 

Thanks in Advance, TD

[Gianni]

in your listing you are mixing 2D and 1D arrays...?
in line 2 you are using a 2d array (with just 1 row) and you can populate it like this:

Local $aArray[1][3] = [[1,2,3]]

if it were with 2 rows you should populate like this:

Local $aArray[2][3] = [[1,2,3],[4,5,6]]

while in line 9 you are declaring an 1d array, the syntax is ok, but since you are declaring a variable, you have to add the "Local" or "Global" statement. Also you should use the right number for the wanted elements [3]

Local $aArray[3] = [1, 2, 3]

 

[TheSaint]

_StringSplit if you want to start from scratch. But it also depends on the data and type.

Forget the above, I had a dumb moment, where I got 3D, 2D and 1D mixed up in my head ... 2D being thought of as normal. I think some of my brain cells are still celebrating Xmas.

Edited December 28, 2015 by Santa

[TheDcoder]

@Chimp Thanks!

On line no. 9 I was trying to populate $aArray's Row 0 with 1, 2 & 3, Not (re)declare $aArray!

@TheSaint will try

Edited December 28, 2015 by TheDcoder

[water]

Regarding line 9:
You can't access a "row" of a 2D array this way. You have to access each element and fill it with data.

How many elements are we talking about?

[water]

Another idea:
_FileReadToArray supports CSV files so you could store your values in a file and populate the 2D array with a single line of code.

[TheDcoder]

  On 12/28/2015 at 9:30 AM, water said:

How many elements are we talking about?

10 elements with 3 columns each... 10 * 3 = 30 lines of code

[TheDcoder]

@water Too much pain for a small task

[water]

Global $aArray[10][3] = [[10,20,30], [11,21,31], [12,22,32], [...], [...], [...], [...], [...], [...], [19,29,39]]

 

[TheDcoder]

@water Yeah, I know! I want to do it after declaring it... Maybe a feature request?

[water]

Why do you want to do it after declaration? What is the advantage?

[TheDcoder]

@water No reason actually... would be great if it would be implemented

[water]

Why should something be implemented that has no advantage (in our company we call it "use case")?

[TheDcoder]

@water Just a thought =)

[TheSaint]

I amended my earlier post ... it is the Silly Season.

[Melba23]

TheDcoder,

You could always use a self-coded wrapper function:

#include <Array.au3>

Local $aArray[1][3]

Local $sInsert = "1|2|3"

_ArrayReplaceRow($aArray, $sInsert, 0)

_ArrayDisplay($aArray, "", Default, 8)

Func _ArrayReplaceRow(ByRef $aTarget, $aSource, $iRow)

    _ArrayInsert($aArray, $iRow, $sInsert)
    _ArrayDelete($aArray, $iRow + 1)

EndFunc

M23

[TheDcoder]

@Melba23 How did you pull this off?

#include <Array.au3>

Local $aArray[1][3]

Local $sInsert = "1|2|3"

_ArrayReplaceRow($aArray, $sInsert, 0)

_ArrayDisplay($aArray, "", Default, 8)

Func _ArrayReplaceRow(ByRef $aTarget, $aSource, $iRow)
; How did you manage to get $sInsert's value inside the function? Ins't it Local(ly) declared?
    _ArrayInsert($aArray, $iRow, $sInsert)
    _ArrayDelete($aArray, $iRow + 1)

EndFunc

 

[Melba23]

TheDcoder,

  Quote

How did you pull this off?

By a fluke - Local variables cannot exist outside of a function and are treated as Global even if not declared as such. What I should, of course, have posted was:

#include <Array.au3>

Local $aArray[1][3]

Local $sInsert = "1|2|3"

_Insert($aArray, $sInsert, 0)

_ArrayDisplay($aArray, "", Default, 8)

Func _Insert(ByRef $aTarget, $sSource, $iRow)

    _ArrayInsert($aTarget, $iRow, $sSource)
    _ArrayDelete($aTarget, $iRow + 1)

EndFunc

M23

[mikell]

An other -obvious- way to skin this cat...

#include <Array.au3>

Local $aArray[1][3]

Local $sInsert = "1,2,3"

_Insert($aArray, $sInsert, 0)

_ArrayDisplay($aArray, "", Default, 8)

Func _Insert($aTarget, $sSource, $iRow)
     Local $a = StringSplit($sSource, ",")
     For $i = 1 to $a[0]
          $aTarget[$iRow][$i-1] = $a[$i]
     Next
EndFunc

 

[Gianni]

<..snap..>

removed as off topic....

Edited December 28, 2015 by Chimp