Snowfall

[Gianni]

it's snowing....

#include <WindowsConstants.au3>
#include <WINAPI.au3>
Local $isnowflakes = 500 ; number of snowflakes
Local $iMinR = 5 ; minimum length of the snowflake's side
Local $iMaxR = 8 ; max length
Local $aSnow[$isnowflakes][5]
Local $AlphaKey = 0xABABAB, $hBackground = GUICreate("", @DesktopWidth, @DesktopHeight, 0, 0, $WS_POPUPWINDOW, $WS_EX_LAYERED + $WS_EX_TOPMOST)
GUISetBkColor($AlphaKey, $hBackground)
_WinAPI_SetLayeredWindowAttributes($hBackground, $AlphaKey, 0, $LWA_COLORKEY)
GUISetState(@SW_SHOW, $hBackground)

For $i = 0 To UBound($aSnow) - 1
    _Randomize($aSnow, $i, $iMinR, $iMaxR)
    $aSnow[$i][3] = GUICtrlCreateLabel("", $aSnow[$i][1], $aSnow[$i][2], $aSnow[$i][0], $aSnow[$i][0])
    GUICtrlSetBkColor(-1, 16777215) ; snow white
Next

While 1
    For $i = 0 To UBound($aSnow) - 1
        $aSnow[$i][2] += $aSnow[$i][4] ; increment y pos
        GUICtrlSetPos($aSnow[$i][3], $aSnow[$i][1], $aSnow[$i][2])
        If $aSnow[$i][2] > @DesktopHeight Then
            _Randomize($aSnow, $i, $iMinR, $iMaxR)
            GUICtrlSetPos($aSnow[$i][3], $aSnow[$i][1], $aSnow[$i][2], $aSnow[$i][0], $aSnow[$i][0])
        EndIf
    Next
WEnd

Func _Randomize(ByRef $aSnow, $i, $iMinR, $iMaxR)
    $aSnow[$i][0] = Random($iMinR, $iMaxR, 0) ; dimension of snow
    $aSnow[$i][1] = Random(0 - $iMaxR, @DesktopWidth + $iMaxR, 0) ; x position
    $aSnow[$i][2] = 0 - $iMaxR ; y position (out of screen at startup)
    $aSnow[$i][4] = Random(0.1, $iMaxR * 3)
EndFunc   ;==>_Randomize

 

[Valuater]

Nice!!

[TheDcoder]

Much smoother and nicer with

$isnowflakes = 20

TD

Edited December 25, 2015 by TheDcoder

[Jos]

Very nice

[Gianni]

WOW, Thank you all for the appreciation,
sometime even a very simple script it's enough to make a funny effect.
Thanks and happy holidays to all

 

[Melba23]

Chimp,

Made my day - thanks a lot.

M23

Edited December 25, 2015 by Melba23
Wrong button - too soon

[aa2zz6]

Whoa! That's pretty neat!

[mLipok]

Very nice, all the more so when I look out the window it is still a lack of snow
Thanks Chimp

mLipok

 

[Lakes]

What others say, good effect from a simple script.

[ioa747]

Thanks for sharing.
Impressed by the simplicity.
I played around with it a bit and came up with this variation.

Spoiler

 

expandcollapse popup

; https://www.autoitscript.com/forum/topic/179498-snowfall
;----------------------------------------------------------------------------------------
; Title...........: Snowing.au3
; Description.....: it's snowing....
; AutoIt Version..: 3.3.16.1   Author: Gianni  Mod: ioa747
; Note............: Testet in Win10 22H2  Script Version: 1.0
;----------------------------------------------------------------------------------------
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#include <WindowsConstants.au3>
#include <WINAPI.au3>

HotKeySet("{ESC}", "_Exit")

; it's snowing....
_Snowing()

;----------------------------------------------------------------------------------------
Func _Snowing()
    Local $isnowflakes = 200 ; number of snowflakes
    Local $iMinR = 5 ; minimum size of the snowflake
    Local $iMaxR = 10 ; maximum size of the snowflake
    Local $aSnow[$isnowflakes][5]
    Local $AlphaKey = 0xABABAB
    Local $iZoom
    Local $hBackground = GUICreate("", @DesktopWidth, @DesktopHeight, 0, 0, $WS_POPUPWINDOW, BitOR($WS_EX_COMPOSITED, $WS_EX_LAYERED, $WS_EX_TOPMOST))

    GUISetBkColor($AlphaKey, $hBackground)
    _WinAPI_SetLayeredWindowAttributes($hBackground, $AlphaKey, 0, $LWA_COLORKEY)
    GUISetState(@SW_SHOW, $hBackground)

    ; Initialize snowflakes
    For $i = 0 To UBound($aSnow) - 1
        $aSnow[$i][3] = GUICtrlCreateIcon(@ScriptDir & "\flake2.ico", -1, -20, -20, 16, 16)
        _Randomize($aSnow, $i, $iMinR, $iMaxR, 1)
    Next

    While 1
        For $i = 0 To UBound($aSnow) - 1
            ; Update y position
            $aSnow[$i][2] += $aSnow[$i][4] + Abs(Int($aSnow[$i][2] / 20)) ; increment y pos + speed

            ; Reset snowflake if it goes off-screen
            If $aSnow[$i][2] > @DesktopHeight Then
                _Randomize($aSnow, $i, $iMinR, $iMaxR)
            EndIf

            ; Update x position + wind effect
            $aSnow[$i][1] += (Mod($i, 10) = 0) ? Random(20, 30, 1) : Random(10, 15, 1)

            ; Reset snowflake if it goes off the right side
            If $aSnow[$i][1] > @DesktopWidth Then
                $aSnow[$i][1] = -5
            EndIf

            $iZoom = Abs(Int($aSnow[$i][2] / 100))

            ; Update the position of the snowflake
            GUICtrlSetPos($aSnow[$i][3], $aSnow[$i][1], $aSnow[$i][2], $aSnow[$i][0] + $iZoom, $aSnow[$i][0] + $iZoom)
        Next
        Sleep(10)
    WEnd
EndFunc   ;==>_Snowing
;----------------------------------------------------------------------------------------
Func _Randomize(ByRef $aSnow, $i, $iMinR, $iMaxR, $iflag = 0)
    $aSnow[$i][0] = Random($iMinR, $iMaxR, 1)  ; size of snowflake
    $aSnow[$i][1] = Random(0, @DesktopWidth, 1)  ; x position
    $aSnow[$i][2] = -($iflag = 0 ? 2 * $iMaxR : Random(2 * $iMaxR, @DesktopHeight, 1))  ; y position
    $aSnow[$i][4] = Random(2, 12, 1)  ; speed
EndFunc   ;==>_Randomize
;----------------------------------------------------------------------------------------
Func _Exit()
    Exit
EndFunc   ;==>_Exit
;----------------------------------------------------------------------------------------

 

 

snowflake:  flake2.ico

Edited December 4 by ioa747