Prevent combo from updating before user selects a item in it

[TheDcoder]

Hello , I am experiencing a problem with Combo controls... They get updated even before the user selects the item! Use this script to test this:

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 366, 115, 301, 138)
$Combo1 = GUICtrlCreateCombo("Combo1", 104, 24, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

GUICtrlSetData($Combo1, "Test")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
    ConsoleWrite(GUICtrlRead($Combo1) & @CRLF)
WEnd

Try hovering over "Test" (don't select it!) and watch the STDOUT stream (SciTE Output Panel located at the bottom of SciTE), it shows "Test" instead of "Combo1"

 

Anyone know how to avoid this? Thanks in Advance, TD

Edited December 12, 2015 by TheDcoder

[JohnOne]

What?

Are you smoking something young man?

[TheDcoder]

@JohnOne ?

[JohnOne]

EDIT: Sorry, TD I misread your question?

Edited December 12, 2015 by JohnOne

[JohnOne]

I imagine you would have to register a gui message, and prevent the default message from being sent on mouseover or enter or something.

Sorry, for poor answer, It's all I have.

[Melba23]

TheDcoder,

Use a CueBanner like this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>

$hGUI = GUICreate("Test", 500, 500)
$cCombo = GUICtrlCreateCombo("", 10, 10, 200, 25)
GUICtrlSetData($cCombo, "Test")
_GUICtrlComboBox_SetCueBanner($cCombo, "Combo1")

$cButton = GUICtrlCreateCheckbox("Test", 10, 100, 80, 30)
GUICtrlSetState($cButton, $GUI_FOCUS)

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch



    If GUICtrlRead($cCombo) Then
        ConsoleWrite(GUICtrlRead($cCombo) & @CRLF)
    EndIf
WEnd

You need the button because the CueBanner is only visible when the combo does not have focus.

M23

[TheDcoder]

@Melba23 Not what I was expecting, I need all the elements to be in the combo

[LarsJ]

You can try something like this:

expandcollapse popup

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListBox.au3>
Global $bSelChanged = True

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 366, 115, 301, 138)
$Combo1 = GUICtrlCreateCombo("Combo1", 104, 24, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData($Combo1, "Test")
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
    If $bSelChanged Then
      ConsoleWrite(GUICtrlRead($Combo1) & @CRLF)
      $bSelChanged = False
    EndIf
WEnd

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
  #forceref $hWnd, $iMsg
  Local $hWndFrom, $iIDFrom, $iCode, $hWndListBox
  ;If Not IsHWnd($g_hListBox) Then $hWndListBox = GUICtrlGetHandle($g_hListBox)
  $hWndFrom = $lParam
  $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word
  $iCode = BitShift($wParam, 16) ; Hi Word

  ;Switch $hWndFrom
    ;Case $g_hListBox, $hWndListBox
      Switch $iCode
        Case $LBN_SELCHANGE ; Sent when the selection in a list box has changed
          $bSelChanged = True
          ; no return value
      EndSwitch
  ;EndSwitch
  Return $GUI_RUNDEFMSG
EndFunc

 

[Melba23]

TheDcoder,

If all you want is to read the combo when it changes than just set a case for it:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("Test", 500, 500)
$cCombo = GUICtrlCreateCombo("", 10, 10, 200, 25)
GUICtrlSetData($cCombo, "Combo1|Test", "Combo1")

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cCombo

            ConsoleWrite(GUICtrlRead($cCombo) & @CRLF)
    EndSwitch
WEnd

You really do need to give more explanation of what you require when you post - far too often lately you have just thrown out a snippet and expected the community to work out what it is that you want to happen. Explaining in more detail means that others will not waste their time posting possible solutions which turn out not to be what you require.

M23

[TheDcoder]

@LarsJ Thanks for the solution but M23's solution seems better, sorry!

@Melba23 That was astonishingly simple , Thanks!

You really do need to give more explanation of what you require when you post - far too often lately you have just thrown out a snippet and expected the community to work out what it is that you want to happen...

I will keep note of that.. The reason partly maybe that it was Midnight and I was sleepy when I posted my questions recently, sorry!

[LarsJ]

You could at least have looked at GUICtrlCreateCombo in the help file.

[TheDcoder]

@LarsJ I did read the Remarks but ignored the example