[Solved] ArrayInsert and overwrite

[Myicq]

I am currently doing a project involving keeping some parameters in an internal 2d array. I am reading part of that to and from an ini file.

As part of the reading I need to put the variables from the ini file into the 2D array. I have found _arrayinsert(), but that creates additional lines.

Bascially I would like something as this:

Original array:

[1]  a1  a2  a3  a4
[2]  b1  b2  b3  b4
[3]  c1  c2  c3  c4

And reading setting for "2" being    d1  d2  d3  d4   I should now have

[1]  a1  a2  a3  a4
[2]  d1  d2  d3  d4
[3]  c1  c2  c3  c4

Is there a built-in UDF or similar to do something like that already ? Or did I missing something real obvious ?

I have rolled my own code, which works. But of course it could be improved.

; function to insert and OVERWRITE data in a 2d array..
; so we can insert data and NOT create new rows..
Func _array_insert2d_overwrite(byref $sourceArray, $where, $dataarray)
    ; do we have arrays at all
    if not IsArray($sourceArray) then
        return 3
    EndIf

    if not IsArray($dataarray) then
        return 4
    EndIf


    ; check if sizes are OK
    if UBound($sourceArray,2) < UBound($dataarray) then   ; ,2 is for number of COLUMNS
        return 2
    EndIf

    if UBound($sourceArray) < $where then       ; this is ROWS
        return 1                                ; that row does not exist
    EndIf

    ; we should be OK to do action now.
    for $i = 0 to UBound($dataarray)-1
        $sourceArray[$where][$i] = $dataarray[$i]
    Next
EndFunc

Thanks for all comments, happy to learn from you all !

 

Edited November 19, 2015 by Myicq
solved marking

[TouchOdeath]

You could _arraydelete then _arrayinsert the same index.

[BrewManNH]

Just overwrite the contents of the row of the array, no need to use any of the array functions for this at all. A simple loop would suffice.

[TouchOdeath]

Just overwrite the contents of the row of the array, no need to use any of the array functions for this at all. A simple loop would suffice.

I agree this is the best solution, It looks like hes already doing that in his function.  As far as improvements to his function, Its best practice to only have one single 'return' in a function.  So to fix, use a '$return' variable (and of course make sure your function still flows properly).

Edited November 18, 2015 by TouchOdeath

[AutoBert]

The solution of MyICQ is Errorhandling and a (very) little bit faster. It's also better readable and so why not?

Edited November 18, 2015 by AutoBert

[czardas]

Here's a solution that drops items if not enough columns are available, or stops overwriting if too many columns exist. Perhaps it's an idea to play around with.

#include <Array.au3>

Local $aArray = [['a1','a2','a3','a4'],['b1','b2','b3','b4'],['c1','c2','c3','c4']]
_ArrayDisplay($aArray, 'before')

Local $aRow = ['d1','d2','d3','d4','d5'], $iRowNum = 1
_RowOverwrite($aArray, $aRow, $iRowNum)
_ArrayDisplay($aArray, 'after')

Func _RowOverwrite(ByRef $aArray, $aRow, $iRowNum)
    If Not (IsArray($aArray) And IsArray($aRow) And IsInt($iRowNum)) Then Return SetError(1) ; one param is not an array, or $iRowNum is not an integer
    If UBound($aArray, 0) <> 2 Or UBound($aRow, 0) <> 1 Then Return SetError(2) ; one array dimension did not match
    If $iRowNum > UBound($aArray) -1 Then Return SetError(3) ; out of bounds row number

    Local $iItems = UBound($aRow), $iCols = UBound($aArray, 2)
    If $iItems > $iCols Then $iItems = $iCols

    For $i = 0 To $iItems - 1
        $aArray[$iRowNum][$i] = $aRow[$i]
    Next
EndFunc

 

Edited November 18, 2015 by czardas