Variable to get function name

[ChrisMax]

Hello all,

I'm in the process of creating a small project for my company. So I've gone through most of the code so far and am quite happy with the result.

Before I show you the code in question, let me tell you, .... am no dev what so ever

Well, that said, the code I'm sending is a logger, that I made for my needs. Out of all the functions in it, there are two that I use all the time 'Logger' and 'Error'. Those two will write OK message and KO messages respectively to the proper files.

Now let's focus on: 

Func Error($sError)
      Local $eTimeStamp = @MON & "-" & @MDAY & "-" & @YEAR & " -- " & @HOUR & ":" & @MIN & ":" & @SEC & "." & @MSEC & " - " & @ScriptName & " - "
      Filewrite($LogError, $eTimeStamp & $sError & @crlf)
EndFunc

The issue I have with this is the "@ScriptName" variable used here which throws the name of my MAIN.au3. What I would like to be able to do, is to log the name of the Function that hanged to make troubleshoot easier. 

This is the way I'm coding this : 

• Main.au3 - Calls 
  • Install.au3
    • Logger.au3
  • Uninstall
    • Logger.au3

Taking the example above, is there any variable that would write "Install.au3" instead of "Main.au3" or do I have to use a second argument to Error() ?

Thanks for taking the time to read this (if you reached this far )

Chris

[Melba23]

ChrisMax,

I would add a Global variable to the Main script and then set it to the name of each function as the code enters - you can then use that variable in place of @‌ScriptName.

M23

[ChrisMax]

Yeah ... that's a way I did not think about. Thanks will check how it looks like. Appreciate the tip

[jchd]

In practice you'll need to use a LIFO container (= a stack) to cope with nested function calls. You also may want to avoid storing multiple entries when inside a primary recursive call, storing just an invokation counter along with the function name. Non-primary recursion is a bit harder to deal with, however.

[jdelaney]

I like to declare a variable within a function with the name (always make it local, but for ease, always the same named variable), and then I always pass it to a logging function to output it in the logs with the message and a date/time stamp.  I also like having a global counter to do indents, so I can visually see in the log what function called which function.

Simple example:

expandcollapse popup

#include <Date.au3>
Global $giSubFunction = 0
Local $sFuncName = @ScriptName

Logging("Starting script")
a()
Logging("EndIng script")



Func a ()
    $giSubFunction +=1
    Local $sFuncName = "a"
    Logging("Starting Func a",$sFuncName)

    b()

    Logging("Ending Func a",$sFuncName)
    $giSubFunction -=1
EndFunc



Func b ()
    $giSubFunction +=1
    Local $sFuncName = "b"
    Logging("Starting Func b",$sFuncName)
    Logging("Ending Func b",$sFuncName)
    $giSubFunction -=1
EndFunc



Func Logging($sCallersLog,$sCallersFuncName=$sFuncName)
    $sNow = _Now()
    ConsoleWrite(StringFormat("%-" & $giSubFunction + StringLen($sNow) + 1 & "s", $sNow) & $sCallersFuncName & ": " & $sCallersLog & @CRLF)
EndFunc

 

output:

11/6/2015 5:42:48 PM test.au3: Starting script
11/6/2015 5:42:48 PM  a: Starting Func a
11/6/2015 5:42:48 PM   b: Starting Func b
11/6/2015 5:42:48 PM   b: Ending Func b
11/6/2015 5:42:48 PM  a: Ending Func a
11/6/2015 5:42:48 PM test.au3: EndIng script

 

Edited November 7, 2015 by jdelaney

[mLipok]

@jdelaney Good idea

here is my variation:

expandcollapse popup

#include <Date.au3>

LoggingStart("Starting Script")
Main()
LoggingEnd("Ending Script")

Func Main()
    LoggingStart(Main)
    Step2()
    LoggingEnd(Main)
EndFunc   ;==>Main

Func Step2()
    LoggingStart(Step2)
    InternalOrInner()
    LoggingEnd(Step2)
EndFunc   ;==>Step2

Func InternalOrInner()
    LoggingStart(InternalOrInner)
    MsgBox(0, 'Test', @ScriptLineNumber)
    LoggingEnd(InternalOrInner)
EndFunc   ;==>InternalOrInner

#Region Logging Functions
Func LoggingStart($sCallersFuncName)
    __Logging('Starting', $sCallersFuncName, +1)
EndFunc   ;==>LoggingStart

Func LoggingEnd($sCallersFuncName)
    __Logging('Ending', $sCallersFuncName, -1)
EndFunc   ;==>LoggingEnd

Func __Logging($sCallersLog, $sCallersFuncName, $iIndentation)
    Local Static $iIndent_static = 0
    If $iIndentation = +1 Then $iIndent_static += $iIndentation

    If IsFunc($sCallersFuncName) Then $sCallersFuncName = FuncName($sCallersFuncName)
    $sNow = _Now()
    ConsoleWrite(StringFormat("%-" & $iIndent_static + StringLen($sNow) + 1 & "s", $sNow) & $sCallersLog & ' > ' & $sCallersFuncName & " < " & @CRLF)
    If $iIndentation = -1 Then $iIndent_static += $iIndentation
EndFunc   ;==>__Logging
#EndRegion Logging Functions

 

Edited November 7, 2015 by mLipok
Func __Logging( ..... should be internal

[jdelaney]

Good additions with the functions.  Makes things much easier to modify, and cleaner.  FuncName is a new one to me, but I'm stuck in a legacy version of autoit

Edited November 7, 2015 by jdelaney

[mLipok]

Oh joy.
I just now realize that my own logging function (which I use in my daily work), also should be modified.
It should'nt be for me so difficult, ...... as I have only to modify my own script parser .

 

Edited November 7, 2015 by mLipok

[iamtheky]

You said "function" but the example was "file"

Taking the example above, is there any variable that would write "Install.au3" instead of "Main.au3"

If that is the case, you just need to use @ScriptFullPath

 

Nm all that,  the scope problem that fixed for me does not seem to be the same for your intent as you , can the function examples provided be modified to do the file thing in the OP?

dammit, now im going to be up trying to make the functions in my includes log their full path everytime they fire, and make sure that i scope my stuff in the future to accomodate being logged as such.

Edited November 7, 2015 by boththose

[ChrisMax]

Hello All,

Sorry I did not get back to you earlier on this. In then end I did something of the sort as well.

Thank you all for the help

Chris