TrayCreateItem setting ToolTips

[nitekram]

I have tried _GUIToolTip_AddTool() & GUICtrlSetTip() & TrayItemGetHandle()  but have had no luck...is there a way that I have missed, or is it not possible to create a ToolTip for an individual item in the Tray?

[JohnOne]

Can you show your TrayItemGetHandle() effort of adding a tooltip?

[nitekram]

I have tried this, with no success. It is only an example, so you with have to kill the process to kill the script.

 

#include <MsgBoxConstants.au3>
#include <TrayConstants.au3> ; Required for the $TRAY_ICONSTATE_SHOW constant.

Opt("TrayMenuMode", 3) ; The default tray menu items will not be shown and items are not checked when selected. These are options 1 and 2 for TrayMenuMode.


Global $tAlarmItem = TrayCreateItem("test")
;GUICtrlSetTip($tAlarmItem, "tip of my label")

Global $hAlarmItemTrayTip = TrayItemGetHandle($tAlarmItem)
GUICtrlSetTip($hAlarmItemTrayTip, "tip of my label")

While 1

WEnd

 

[JohnOne]

It's a good question.

Sorry I could not help.

Here's what I was trying for the record.

#include <MsgBoxConstants.au3>
#include <TrayConstants.au3> ; Required for the $TRAY_ICONSTATE_SHOW constant.
#include <GuiToolTip.au3>
HotKeySet("{Esc}", "_Exit")

Opt("TrayMenuMode", 7) ; The default tray menu items will not be shown and items are not checked when selected. These are options 1 and 2 for TrayMenuMode.
Opt("TrayIconHide", 0)
TraySetToolTip(" ")


$hwnd = WinGetHandle(AutoItWinGetTitle())
Global $tAlarmItem = TrayCreateItem("test")
$chwnd = ControlGetHandle($hwnd, "", $tAlarmItem) ;GUICtrlGetHandle($tAlarmItem)
$tt = _GUIToolTip_Create($chwnd)
_GUIToolTip_AddTool($tt, $chwnd, "Tip Text")

While 1
    Sleep(1000)
WEnd

Func _Exit()
    Exit
EndFunc   ;==>_Exit

 

[BrewManNH]

GUICtrl functions generally work with control IDs and not handles to controls.Also, the TrayItemGetHandle function doesn't seem to work on TrayItems, only on TrayCreate IDs. Sounds like it's either misnamed, or not working as it should.

[nitekram]

It's a good question.

Sorry I could not help.

Here's what I was trying for the record.

#include <MsgBoxConstants.au3>
#include <TrayConstants.au3> ; Required for the $TRAY_ICONSTATE_SHOW constant.
#include <GuiToolTip.au3>
HotKeySet("{Esc}", "_Exit")

Opt("TrayMenuMode", 7) ; The default tray menu items will not be shown and items are not checked when selected. These are options 1 and 2 for TrayMenuMode.
Opt("TrayIconHide", 0)
TraySetToolTip(" ")


$hwnd = WinGetHandle(AutoItWinGetTitle())
Global $tAlarmItem = TrayCreateItem("test")
$chwnd = ControlGetHandle($hwnd, "", $tAlarmItem) ;GUICtrlGetHandle($tAlarmItem)
$tt = _GUIToolTip_Create($chwnd)
_GUIToolTip_AddTool($tt, $chwnd, "Tip Text")

While 1
    Sleep(1000)
WEnd

Func _Exit()
    Exit
EndFunc   ;==>_Exit

 

I have tried that as well, no luck, and that is what I actually tried first as my GUI already was using this same process/function with no issues

 

EDIT

I also tried the same code with the TrayItemGetHandle with no luck either

 

 

Edited October 20, 2015 by nitekram

[LarsJ]

A way to do it is to use a WH_MSGFILTER hook procedure to catch the messages from the tray menu:

expandcollapse popup

#NoTrayIcon
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Opt("TrayMenuMode", 3) ; The default tray menu items will not be shown and items are not checked when selected. These are options 1 and 2 for TrayMenuMode.

Global Const $tagMSG = "hwnd hwnd;uint message;wparam wParam;lparam lParam;dword time;int X;int Y"
Global $iDisplay, $iPrinter, $iAbout, $iExit

Example()

Func Example()
  Local $iSettings = TrayCreateMenu("Settings") ; Create a tray menu sub menu with two sub items.
  $iDisplay = TrayCreateItem("Display", $iSettings)
  $iPrinter = TrayCreateItem("Printer", $iSettings)
  TrayCreateItem("") ; Create a separator line.

  $iAbout = TrayCreateItem("About")
  TrayCreateItem("") ; Create a separator line.

  $iExit = TrayCreateItem("Exit")
  
  Local $hMessageHandler = DllCallbackRegister( "MessageHandler", "long", "int;wparam;lparam" )
  Local $hMessageHook = _WinAPI_SetWindowsHookEx( $WH_MSGFILTER, DllCallbackGetPtr( $hMessageHandler ), 0, _WinAPI_GetCurrentThreadId() )

  TraySetState(1) ; Show the tray menu.

  While 1
    Switch TrayGetMsg()
      Case $iAbout ; Display a message box about the AutoIt version and installation path of the AutoIt executable.
        MsgBox($MB_SYSTEMMODAL, "", "AutoIt tray menu example." & @CRLF & @CRLF & _
            "Version: " & @AutoItVersion & @CRLF & _
            "Install Path: " & StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", 0, -1) - 1)) ; Find the folder of a full path.

      Case $iDisplay, $iPrinter
        MsgBox($MB_SYSTEMMODAL, "", "A sub menu item was selected from the tray menu.")

      Case $iExit ; Exit the loop.
        ExitLoop
    EndSwitch
  WEnd

  DllCallbackFree( $hMessageHandler )
  _WinAPI_UnhookWindowsHookEx( $hMessageHook )
EndFunc   ;==>Example

Func MessageHandler( $nCode, $wParam, $lParam )
  Local $tMSG = DllStructCreate( $tagMSG, $lParam )
  Local $iMsg = DllStructGetData( $tMSG, "message" )
  If $iMsg = $WM_MENUSELECT Then
    Local $iwParam = DllStructGetData( $tMSG, "wParam" )
    Local $idMenu = BitAND( $iwParam, 0xFFFF )
    Switch $idMenu
      Case $iDisplay
        ToolTip( "Tooltip for Display menu" )
      Case $iPrinter
        ToolTip( "Tooltip for Printer menu" )
      Case $iAbout
        ToolTip( "Tooltip for About menu" )
      Case $iExit
        ToolTip( "Tooltip for Exit menu" )
      Case Else
        ToolTip( "" )
    EndSwitch
  EndIf
EndFunc

 

[nitekram]

A way to do it is to use a WH_MSGFILTER hook procedure to catch the messages from the tray menu:

expandcollapse popup

#NoTrayIcon
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Opt("TrayMenuMode", 3) ; The default tray menu items will not be shown and items are not checked when selected. These are options 1 and 2 for TrayMenuMode.

Global Const $tagMSG = "hwnd hwnd;uint message;wparam wParam;lparam lParam;dword time;int X;int Y"
Global $iDisplay, $iPrinter, $iAbout, $iExit

Example()

Func Example()
  Local $iSettings = TrayCreateMenu("Settings") ; Create a tray menu sub menu with two sub items.
  $iDisplay = TrayCreateItem("Display", $iSettings)
  $iPrinter = TrayCreateItem("Printer", $iSettings)
  TrayCreateItem("") ; Create a separator line.

  $iAbout = TrayCreateItem("About")
  TrayCreateItem("") ; Create a separator line.

  $iExit = TrayCreateItem("Exit")
  
  Local $hMessageHandler = DllCallbackRegister( "MessageHandler", "long", "int;wparam;lparam" )
  Local $hMessageHook = _WinAPI_SetWindowsHookEx( $WH_MSGFILTER, DllCallbackGetPtr( $hMessageHandler ), 0, _WinAPI_GetCurrentThreadId() )

  TraySetState(1) ; Show the tray menu.

  While 1
    Switch TrayGetMsg()
      Case $iAbout ; Display a message box about the AutoIt version and installation path of the AutoIt executable.
        MsgBox($MB_SYSTEMMODAL, "", "AutoIt tray menu example." & @CRLF & @CRLF & _
            "Version: " & @AutoItVersion & @CRLF & _
            "Install Path: " & StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", 0, -1) - 1)) ; Find the folder of a full path.

      Case $iDisplay, $iPrinter
        MsgBox($MB_SYSTEMMODAL, "", "A sub menu item was selected from the tray menu.")

      Case $iExit ; Exit the loop.
        ExitLoop
    EndSwitch
  WEnd

  DllCallbackFree( $hMessageHandler )
  _WinAPI_UnhookWindowsHookEx( $hMessageHook )
EndFunc   ;==>Example

Func MessageHandler( $nCode, $wParam, $lParam )
  Local $tMSG = DllStructCreate( $tagMSG, $lParam )
  Local $iMsg = DllStructGetData( $tMSG, "message" )
  If $iMsg = $WM_MENUSELECT Then
    Local $iwParam = DllStructGetData( $tMSG, "wParam" )
    Local $idMenu = BitAND( $iwParam, 0xFFFF )
    Switch $idMenu
      Case $iDisplay
        ToolTip( "Tooltip for Display menu" )
      Case $iPrinter
        ToolTip( "Tooltip for Printer menu" )
      Case $iAbout
        ToolTip( "Tooltip for About menu" )
      Case $iExit
        ToolTip( "Tooltip for Exit menu" )
      Case Else
        ToolTip( "" )
    EndSwitch
  EndIf
EndFunc

 

This is closer than I have got, so it will work, but a single question...I notice that the message comes up and is cut off, is there someway I can have it pop to from the left, rather than the right?

 

EDIT - it appears that depending on where you first interact with the control that it places it to the right, so going all the way to the right of the control, will cut off even more of the displayed tooltip.

Edited October 20, 2015 by nitekram

[JohnOne]

Yes, set the x and y parameters of ToolTip()

[nitekram]

Yes, set the x and y parameters of ToolTip()

That is the ticket...thanks for everyone's help!!!

[LarsJ]

And you can get the current mouse position as the X and Y members of the $tagMSG structure.

[nitekram]

And you can get the current mouse position as the X and Y members of the $tagMSG structure.

I have not worked with this type of variable before...I tried to use Msgbox to get the info, but that did not work, as I just got over lapping Msgboxes. How would I pull that info?
I have also tried:
ConsoleWrite(DllStructGetData($tagMSG, 'x') & @CRLF)
ConsoleWrite(DllStructGetData($tagMSG, 'y') & @CRLF)

I have also tried this:

 

Func MessageHandler($nCode, $wParam, $lParam)
    Local $tMSG = DllStructCreate($tagMSG, $lParam)
    Local $iMsg = DllStructGetData($tMSG, "message")

    Local $x, $y


Local $iMouse_X = DllStructCreate($tagMSG, $x)
Local $iMouse_Y = DllStructCreate($tagMSG, $y)
    ConsoleWrite(DllStructGetData($tagMSG, $iMouse_X) & ' x ' & @CRLF)
    ConsoleWrite(DllStructGetData($tagMSG, 'y') & @CRLF)

I would say I am a real noob when it comes to pointers, so any further help would be appreciative. For the time being, I am just using the desktop width as a way of getting it to a somewhat readable area - would use also stringlen() after creating the string for each tooltip

 

Actually a real noob at Structs - looking to use this as a way of maybe learning it a little better. Thanks again for your help.

Edited October 20, 2015 by nitekram

[nitekram]

I got it now...took a bit, thanks again everyone

 

Func MessageHandler($nCode, $wParam, $lParam)
    Local $tMSG = DllStructCreate($tagMSG, $lParam)
    Local $iMsg = DllStructGetData($tMSG, "message")
    Local $iX = DllStructGetData($tMSG, "X")
    Local $iY = DllStructGetData($tMSG, "Y")

 

EDIT not resolved yet

Okay, that was giving me the mouse cords, but I was not able to get the tooltip to show...also I was getting (not every time, but at least once while hovering mouse over the toolbaritem - X = 1476462617 Y = -180939672

 

I do not think my screen is that large lol, so I must be doing something wrong?

Edited October 20, 2015 by nitekram

[JohnOne]

Yeah I get weird results with 

Case $iPrinter
        ToolTip( DllStructGetData($tMSG, "X") & "," & DllStructGetData($tMSG, "Y"))

I just used

Case $iDisplay
        ToolTip( "Tooltip for Display menu", MouseGetPos(0) - 150,  MouseGetPos(1) - 20)

 

[LarsJ]

It seems as if X and Y is only the current mouse position if it's a mouse related message eg. $WM_MOUSEMOVE. For other messages X and Y seems to be undefined. This should work:

expandcollapse popup

#NoTrayIcon
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Opt("TrayMenuMode", 3) ; The default tray menu items will not be shown and items are not checked when selected. These are options 1 and 2 for TrayMenuMode.

Global Const $tagMSG = "hwnd hwnd;uint message;wparam wParam;lparam lParam;dword time;int X;int Y"
Global $iDisplay, $iPrinter, $iAbout, $iExit

Example()

Func Example()
  Local $iSettings = TrayCreateMenu("Settings") ; Create a tray menu sub menu with two sub items.
  $iDisplay = TrayCreateItem("Display", $iSettings)
  $iPrinter = TrayCreateItem("Printer", $iSettings)
  TrayCreateItem("") ; Create a separator line.

  $iAbout = TrayCreateItem("About")
  TrayCreateItem("") ; Create a separator line.

  $iExit = TrayCreateItem("Exit")
  
  Local $hMessageHandler = DllCallbackRegister( "MessageHandler", "long", "int;wparam;lparam" )
  Local $hMessageHook = _WinAPI_SetWindowsHookEx( $WH_MSGFILTER, DllCallbackGetPtr( $hMessageHandler ), 0, _WinAPI_GetCurrentThreadId() )

  TraySetState(1) ; Show the tray menu.

  While 1
    Switch TrayGetMsg()
      Case $iAbout ; Display a message box about the AutoIt version and installation path of the AutoIt executable.
        MsgBox($MB_SYSTEMMODAL, "", "AutoIt tray menu example." & @CRLF & @CRLF & _
            "Version: " & @AutoItVersion & @CRLF & _
            "Install Path: " & StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", 0, -1) - 1)) ; Find the folder of a full path.

      Case $iDisplay, $iPrinter
        MsgBox($MB_SYSTEMMODAL, "", "A sub menu item was selected from the tray menu.")

      Case $iExit ; Exit the loop.
        ExitLoop
    EndSwitch
  WEnd

  DllCallbackFree( $hMessageHandler )
  _WinAPI_UnhookWindowsHookEx( $hMessageHook )
EndFunc   ;==>Example

Func MessageHandler( $nCode, $wParam, $lParam )
  Local Static $iMouseX, $iMouseY
  Local $tMSG = DllStructCreate( $tagMSG, $lParam )
  Local $iMsg = DllStructGetData( $tMSG, "message" )
  Switch $iMsg
    Case $WM_MENUSELECT
      Local $iwParam = DllStructGetData( $tMSG, "wParam" )
      Local $idMenu = BitAND( $iwParam, 0xFFFF )
      Switch $idMenu
        Case $iDisplay
          ToolTip( "Tooltip for Display menu", $iMouseX - 100, $iMouseY )
        Case $iPrinter
          ToolTip( "Tooltip for Printer menu", $iMouseX - 100, $iMouseY )
        Case $iAbout
          ToolTip( "Tooltip for About menu", $iMouseX - 100, $iMouseY )
        Case $iExit
          ToolTip( "Tooltip for Exit menu", $iMouseX - 100, $iMouseY )
        Case Else
          ToolTip( "" )
      EndSwitch
    Case $WM_MOUSEMOVE
      $iMouseX = DllStructGetData( $tMSG, "X" )
      $iMouseY = DllStructGetData( $tMSG, "Y" )
  EndSwitch
EndFunc

 

[nitekram]

That worked great...thanks - I had to add the stringlen() though, as each tool tip message was different in size, so some still extended outside of the display.

I thank you again for your help, but I wish it was as easy as adding tooltips to a GUI.

[VAN0]

Is there a way display the tooltip under the menu item, rather then under cursor?

Edited August 26, 2017 by VAN0

[VAN0]

Found a way by using _GUICtrlMenu_GetItemRect() on the menu item, then use 0 and 3 values for x and y of the tooltip.

To get coordinates of tray menu item, I used this:

$tMyTrayMenuItem = TrayCreateItem("My tray menu item")
$tMyTrayMenuItemPos = _GUICtrlMenu_GetItemCount(TrayItemGetHandle(0)) - 1
$rect = _GUICtrlMenu_GetItemRect(Default, TrayItemGetHandle(0), $tMyTrayMenuItemPos)
ToolTip("Tooltip text", $rect[0], $rect[3])

P.S.

The tricky part for me was get the menu item position to use in _GUICtrlMenu_GetItemRect(), because TrayCreateItem() returns control ID instead and I couldn't find any command that would reveal position of a menu item.