parse URL?

[elmoi0010]

Good morning, am here again.. 

Is there a way to get just the images who have "paso_0","paso_1" from URL with "_IEImgGetCollection"?

i tryed this from autoit help webpage

; Create browser at AutoIt homepage, get Img collection
; and display src URL for each

#include <IE.au3>
#include <MsgBoxConstants.au3>

Local $oIE = _IECreate("http://www.recetasgratis.net/receta-de-limonada-brasilena-57084.html")
Local $oImgs = _IEImgGetCollection($oIE)
Local $iNumImg = @extended

Local $sTxt = "There are " & $iNumImg & " images on the page" & @CRLF & @CRLF
For $oImg In $oImgs
    $sTxt &= $oImg.src & @CRLF
Next
MsgBox($MB_SYSTEMMODAL, "Img Info", $sTxt)

_IEQuit($oIE)

I get the image URL's but i just those who have "paso_0","paso_1". Something like stringregexp but i really dont know how, new to this.. Thanks in advanced to all guys.

[mLipok]

If StringRegExp($oImg.src, "(paso_0|paso_1)") then
        $sTxt &= $oImg.src & @CRLF
    EndIf

 

[Danyfirex]

if You don't want to use IE

#include <Array.au3>

Local $sData=InetRead("http://www.recetasgratis.net/receta-de-limonada-brasilena-57084.html")

Local $aReg=StringRegExp(BinaryToString($sData),'\<img.*src\=\"(.*)\"',3)

;~ _ArrayDisplay($aReg)

For $i= 0 to UBound($aReg)-1
if StringRegExp($aReg[$i], "(paso_0|paso_1)") then
     ConsoleWrite($aReg[$i] & @CRLF)
;~   InetGet($aReg[$i],"filepath.jpg") For downloading
EndIf
Next

Saludos

[mikell]

#include <Array.au3>

Local $sData = BinaryToString(InetRead("http://www.recetasgratis.net/receta-de-limonada-brasilena-57084.html"))
Local $aReg = StringRegExp($sData,'<img\h*src="([^"]+(?:paso_0|paso_1)[^"]+)', 3)

_ArrayDisplay($aReg)

Edited October 5, 2015 by mikell

[jguinch]

(?:paso_0|paso_1)  =  paso_[01] 

Another one (for double and simple quotes cases) :

Local $aReg=StringRegExp( $sData,'<img.+?src=(?|"([^"]+paso_[01][^"]+)|''([^'']+paso_[01][^'']+))',3)

 

Edited October 5, 2015 by jguinch