EXAMPLE: Proper usage ie.au3 UDF with AutoIt v3.3.14.x

[mLipok]

Lately, in this forum, there were many questions and problems referring to the use of ie.au3 UDF using the latest version of AutoIt v3.3.14.x.

I would like to present the correct usage of the UDF.
I hope that it will help many users to prevent problems.

 

expandcollapse popup

#include <ie.au3>
#include <MsgBoxConstants.au3>

; STEP 1
; YOU MUST SET ANY COM ERROR HANDLER IN ONE OF THE FOLLOWING WAY

; STEP 1: CASE 1
; you should set COM Error Handler Function for ie.au3 UDF
_IEErrorHandlerRegister(_User_ErrFunc)

; STEP 1: CASE 2
; eventually if you not want to recieve additional information
; you can use just the same function without parameter
; _IEErrorHandlerRegister()

; STEP 1: CASE 3
; or use your own global COM Error Handler
;~ Global $oCOMErrorHandler = ObjEvent("AutoIt.Error", _User_ErrFunc)

; STEP 2
; if you do not wish to get in Console Output Pane information like the following:
;           --> IE.au3 T3.0-2 Error from function _IEAction(click), $_IESTATUS_InvalidDataType
;   You can uncomment this following line:
;       _IEErrorNotify(False)


_Example()
Func _Example()

    ; First lets create some IE Object
    Local $oIE = _IECreate('google.com')
    ; you should always check for @error in any function (even you own made)
    If @error Then
        MsgBox($MB_ICONERROR, '_IECreate', '@error = ' & @error & @CRLF & '@extended = ' & @extended)
        ; Set @error when you return from function with Failure
        Return SetError(1,0,0)
    Endif

    ; here we try to get reference to LuckyStrike button
    Local $oLuckyStrike = _IEGetObjByName($oIE, 'btnI')
    ; you should always check for @error in any function (even you own made)
    If @error Then
        MsgBox($MB_ICONERROR, '_IEGetObjByName', '@error = ' & @error & @CRLF & '@extended = ' & @extended)
        ; Set @error when you return from function with Failure
        Return SetError(2,0,0)
    Endif

    ; here we try to click LuckyStrike button with previously achieved Object which is a reference to HTML DOM OBJECT in IE Instance
    _IEAction($oLuckyStrike, 'click')

    ; you should wait when page is loading
    _IELoadWait($oIE)

    ; some user interaction
    If MsgBox($MB_YESNO, 'Question', 'Do you want to back ?') = $IDYES Then
        _IEAction($oIE, 'back')
    EndIf

EndFunc   ;==>_Example



; User's COM error function.
; After SetUp with ObjEvent("AutoIt.Error", ....) will be called if COM error occurs
Func _User_ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptFullPath & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_User_ErrFunc

 

Regards,
mLipok

 

Edited October 4, 2015 by mLipok
topic tilte changed, minior script changes

[Quantumation]

Where do you get ie.au3 UDF, i'm looking all over the forum and the searches always bring me to @water's outlook UDF, can you post a link of how to get the ie.au3 UDF please?

[mLipok]

"c:\Program Files (x86)\AutoIt3\Include\IE.au3" 

[Quantumation]

Oh i'm an idiot, I thought this was something that we had to download separately. Thank you @mLipok

[mLipok]

Second interesting example, showing how to wait for full page load (with all frames):

expandcollapse popup

#include <ie.au3>
#include <Timers.au3>

_IEErrorHandlerRegister(_User_ErrFunc)

_Example()

Func _Example()
;~  http://www.aaronpeters.nl/blog/iframe-loading-techniques-performance?%3E

;~  Local $oIE = _IECreate('http://www.aaronpeters.nl/blog/testpages/iframe-dynamic-after-onload.htm', 0, 1, 0)
;~  Local $oIE = _IECreate('http://www.aaronpeters.nl/blog/testpages/iframe-dynamic-asynch.htm', 0, 1, 0)
    Local $oIE = _IECreate('http://stevesouders.com/efws/iframe-onload-nonblocking.php?t=1453416601', 0, 1, 0)
    Local $hStarttime = _Timer_Init()
    _IELoadWait($oIE)
    ConsoleWrite('> 1 = ' & _Timer_Diff($hStarttime) & @CRLF)
    _IELoadWait_ForAllFrames($oIE)
    ConsoleWrite('> 2 = ' & _Timer_Diff($hStarttime) & @CRLF)
    _IEQuit($oIE)
EndFunc   ;==>_Example


Func _IELoadWait_ForAllFrames(ByRef $oObject, $iDelay = 0, $iTimeout = Default)
    _IELoadWait($oObject, $iDelay, $iTimeout)
    If @error Then Return SetError(@error, @extended, -1)

    Local $oFrames_coll = _IEFrameGetCollection($oObject)
    #forceref $oFrames_coll
    Local $iNumFrames = @extended
    Local $oFrame = Null
    For $iFrame_idx = 0 To ($iNumFrames - 1)
        $oFrame = _IEFrameGetCollection($oObject, $iFrame_idx)
        _IEDocGetObj($oFrame)
        If Not @error Then
            _IELoadWait($oFrame, $iDelay, $iTimeout)
            If @error Then Return SetError(@error, @extended, -1)
        EndIf
    Next

    Return SetError($_IESTATUS_Success, 0, 1)

EndFunc   ;==>_IELoadWait_ForAllFrames


; User's COM error function.
Func _User_ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptFullPath & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_User_ErrFunc

 

It was earlier published here:

 

Edited February 17, 2016 by mLipok
added COM Error Handler

[JohnOne]

It's interesting that you do not use your "Proper usage" in example,

Edited February 17, 2016 by JohnOne

[mLipok]

Good point. Fixed.
Thanks @JohnOne

mLipok

[funky_batman]

for this  i understand..

MsgBox($MB_ICONERROR, '_IECreate', '@error =

 

 

but, for this i don't understand.

' & @error & @CRLF & '@extended = ' & @extended)

can you more explain to me?

 

[mLipok]

For example:

_IETagNameGetCollection(....)

 

Return Value

Success:	an object variable containing the specified Tag collection, @extended = specified Tag count.
Failure:	sets the @error flag to non-zero.
@error:	3 ($_IEStatus_InvalidDataType) - Invalid Data Type 4 ($_IEStatus_InvalidObjectType) - Invalid Object Type 5 ($_IEStatus_InvalidValue) - Invalid Value 7 ($_IEStatus_NoMatch) - No Match
@extended:	Contains invalid parameter number