Attachment blocking in IE

[Israel]

Good afternoon

Is there anything that will block the attachment to the browser as shown in the function below?

oie = _IEAttach $ (WinGetHandle ("[Active]"), "hWnd")

Is returning me: -> IE.au3 T3.0-1 Warning function from _IEAttach, $ _IESTATUS_NoMatch

Thank you

[mLipok]

; wrong
oie = _IEAttach $ (WinGetHandle ("[Active]"), "hWnd")

; correct
$oie = _IEAttach(WinGetHandle ("[Active]"), "hWnd")

btw. are you sure WinGetHandle return to you correct window ?

try this

Local $hWindow = WinGetHandle ("[Active]")
ConsoleWrite(WinGetTitle($hWindow) & @CRLF)
$oie = _IEAttach($hWindow, "hWnd")

 

[Israel]

mLipok,

The syntax above was in error, but I saw that you understand the correct way. As for the code that sent me it is the same thing, only separated the functions. Does not work yet.

I was wondering if there is any blockage, as this same function connects in some applications, but does not connect in others.

[mLipok]

Did you notice what was in console :

ConsoleWrite(WinGetTitle($hWindow) & @CRLF)

??

Can you share here to the forum, this secret  information

 

 

[jguinch]

Another way could be to use the "instance mode" with _IEAttach : in this case, the attachment can operates without having the IE window actived.

$oIE = _IEAttach("", "instance")

 

[Israel]

jguinch,

For instance it did not work

[Israel]

mLipok,

The result was:

Filas - Filas de Trabalho - Internet Explorer
--> IE.au3 T3.0-1 Warning from function _IEAttach, $_IESTATUS_NoMatch

>Exit code: 0    Time: 244.7

The name of my window and the error in not attach.

[mLipok]

and this:

expandcollapse popup

#include <ie.au3>
#include <MsgBoxConstants.au3>

WinActivate('[REGEXPTITLE:.*?Internet Explorer]')
Local $hWindow = WinGetHandle("[Active]")
ConsoleWrite(WinGetTitle($hWindow) & @CRLF)
Local $oie = _IEAttach_TEST($hWindow, "hWnd")
If @error Then MsgBox($MB_ICONERROR, '_IEAttach_TEST', _
        '@error = ' & @error & @CRLF & '@extended = ' & @extended)

MsgBox(0, '', _IEDocReadHTML($oie))


Func _IEAttach_TEST($sString, $sMode = "title")
    $sMode = StringLower($sMode)
    Local $oShell = ObjCreate("Shell.Application")
    Local $oShellWindows = $oShell.Windows(); collection of all ShellWindows (IE and File Explorer)
    Local $iNotifyStatus, $bIsBrowser, $sTmp
    Local $bStatus
    For $oWindow In $oShellWindows
        $bIsBrowser = True
        ; Trap COM errors and turn off error notification
        $bStatus = __IEInternalErrorHandlerRegister()
        If Not $bStatus Then __IEConsoleWriteError("Warning", "_IEAttach", _
                "Cannot register internal error handler, cannot trap COM errors", _
                "Use _IEErrorHandlerRegister() to register a user error handler")
        ; Turn off error notification for internal processing
        $iNotifyStatus = _IEErrorNotify() ; save current error notify status
        _IEErrorNotify(False)

        ; Check conditions to verify that the object is a browser
        If $bIsBrowser Then
            $sTmp = $oWindow.type ; Is .type a valid property?
            If @error Then $bIsBrowser = False
        EndIf
        If $bIsBrowser Then
            $sTmp = $oWindow.document.title ; Does object have a .document and .title property?
            If @error Then $bIsBrowser = False
        EndIf

        ; restore error notify
        _IEErrorNotify($iNotifyStatus) ; restore notification status
        __IEInternalErrorHandlerDeRegister()
        ;------------------------------------------------------------------------------------------

        If $bIsBrowser Then
            Switch $sMode
                Case "hwnd"
                    If _IEPropertyGet($oWindow, "hwnd") = $sString Then
                        Return SetError($_IESTATUS_Success, 0, $oWindow)
                    EndIf
                Case Else
                    ; Invalid Mode
                    __IEConsoleWriteError("Error", "_IEAttach", "$_IESTATUS_InvalidValue", "Invalid Mode Specified")
                    Return SetError($_IESTATUS_InvalidValue, 2, 0)
            EndSwitch
        EndIf
    Next
    __IEConsoleWriteError("Warning", "_IEAttach", "$_IESTATUS_NoMatch")
    Return SetError($_IESTATUS_NoMatch, 1, 0)
EndFunc   ;==>_IEAttach_TEST