Com error in presence ComErrorHandler

[Iczer]

I have some script with ComErrorHandler, but i still sometime get fatal com errors. Why its happen? How i can counter this "The requested action with this object has failed" com error?

if i restart script error do not happen.

"E:\Some folder\Some script.au3" (1264) : ==> The requested action with this object has failed.:
$sVar = $oIE.document.body.getElementsByTagName("table").item(0).getElementsByTagName("td").item(0).getElementsByTagName("a").item(1).innerText
$sVar = $oIE.document.body.getElementsByTagName("table").item(0)^ ERROR

Com Error Handler :

Global $__ComErrorHandler = ObjEvent("AutoIt.Error", "Template_COMErrFunc")

;==============================================================
Func Template_COMErrFunc()
    Return Call("ComErrorHandlerFunction",$__ComErrorHandler)
EndFunc
;==============================================================
Func ComErrorHandlerFunction($errorEvent)
    If IsObj($errorEvent) Then

        ConsoleWrite("!--> DeluxeComErrorHandler: COM Error Encountered in " & @ScriptName & @CR)
        ConsoleWrite("----> Scriptline = " & $errorEvent.scriptline & @CR)
        ConsoleWrite("----> Number Hex = " & Hex($errorEvent.number, 8) & @CR)
        ConsoleWrite("----> Number = " & $errorEvent.number & @CR)
        ConsoleWrite("----> Win Description = " & StringStripWS($errorEvent.WinDescription, 2) & @CR)
        ConsoleWrite("----> Description = " & StringStripWS($errorEvent.description, 2) & @CR)
        ConsoleWrite("----> Source = " & $errorEvent.Source & @CR)
        ConsoleWrite("----> Help File = " & $errorEvent.HelpFile & @CR)
        ConsoleWrite("----> Help Context = " & $errorEvent.HelpContext & @CR)
        ConsoleWrite("----> Last Dll Error = " & $errorEvent.LastDllError & @crlf)
        ConsoleWrite("----> Last Dll Error = " & $errorEvent.ScriptName & @crlf)

        Local $HexNumber = Hex($errorEvent.number, 8)
        SetError($HexNumber)
    Else
        SetError(1)
    EndIf
    Return 0
EndFunc
;==============================================================

 

[mLipok]

Hello.

I have some script with ComErrorHandler, but i still sometime get fatal com errors. Why its happen? How i can counter this "The requested action with this object has failed" com error?

if i restart script error do not happen.

"E:\Some folder\Some script.au3" (1264) : ==> The requested action with this object has failed.:
$sVar = $oIE.document.body.getElementsByTagName("table").item(0).getElementsByTagName("td").item(0).getElementsByTagName("a").item(1).innerText

This element expression is too long.

Try like this:

 

Local $oTables_coll = $oIE.document.body.getElementsByTagName("table")
If @error Then
    ;...
Else
    If $oTables_coll.length > 0 Then
        Local $oTDs_coll = $oTables_coll.item(0).getElementsByTagName("td")
        If @error Then
            ;...
        Else
            Local $oTagA_Cols = $oTDs_coll.item(0).getElementsByTagName("a")
            If @error Then
                ;...
            Else
                MsgBox(0, '', $oTagA_Cols.item(1).innerText)
            EndIf
        EndIf

    EndIf
EndIf

 

EDIT:

just you must do it STEP BY STEP with checking @error 

 

mLipok

Edited September 29, 2015 by mLipok
element >> expression

[mLipok]

here you have some imp (duplicated description):

ConsoleWrite("----> Last Dll Error = " & $errorEvent.LastDllError & @crlf)
        ConsoleWrite("----> Last Dll Error = " & $errorEvent.ScriptName & @crlf)

 

 

This is realy not needed:

Local $HexNumber = Hex($errorEvent.number, 8)
        SetError($HexNumber)
    Else
        SetError(1)
    EndIf
    Return 0

unless you are doing it for your own purposes, because AutoIt does not need it.

[Iczer]

thanks, i will try something like that:

Local $oTables_coll = $oIE.document.body.getElementsByTagName("table")
If (Not @error) And ($oTables_coll.length > 0) Then
    Local $oTDs_coll = $oTables_coll.item(0).getElementsByTagName("td")
    If (Not @error) And ($oTDs_coll.length > 0) Then
        Local $oTagA_Cols = $oTDs_coll.item(0).getElementsByTagName("a")
        If (Not @error) And ($oTagA_Cols.length > 1) Then
            MsgBox(0, '', $oTagA_Cols.item(1).innerText)
        EndIf
    EndIf
EndIf

but isn't AutoIt also execute this long string step by step? ComErrorHandler should work on every step i think...

[mLipok]

I'm not sure, but this is good question to get answer and put it to the HelpFile.
I hope @Jon answer on your question.

 

cheers,

mLipok

[mLipok]

For reference:

I think you would be intrested to look here: