_Excel_BookOpen issue - (Moved)

[UEZ]

One web created Excel sheet is crashing when calling the _Excel_BookOpen function.

"C:\Program Files (x86)\AutoIt3\Include\Excel.au3" (227) : ==> Variable must be of type "Object".:
$oExcel.Windows($oWorkbook.Name).Visible = $bVisible
$oExcel.Windows($oWorkbook.Name)^ ERROR

Local $oWorkbook = $oExcel.Workbooks.Open($sFilePath, $bUpdateLinks, $bReadOnly, Default, $sPassword, $sWritePassword) in line 225 seems to load the file but no error is set.

Is there any way to catch those errors to avoid app crash? ObjEvent("AutoIt.Error", "ErrFunc") doesn't catch it!

 

Tested on 3.3.14.2 and 3.3.15.0 and Office 2013.

Edited September 23, 2015 by UEZ

[mLipok]

I see there is 

    ; Error handler, automatic cleanup at end of function
    Local $oError = ObjEvent("AutoIt.Error", "__Excel_COMErrFunc")

 

in this function:

Func _Excel_BookOpen($oExcel, $sFilePath, $bReadOnly = Default, $bVisible = Default, $sPassword = Default, $sWritePassword = Default, $bUpdateLinks = Default)
    ; Error handler, automatic cleanup at end of function
    Local $oError = ObjEvent("AutoIt.Error", "__Excel_COMErrFunc")
    #forceref $oError
    If Not IsObj($oExcel) Or ObjName($oExcel, 1) <> "_Application" Then Return SetError(1, @error, 0)
    If Not FileExists($sFilePath) Then Return SetError(2, 0, 0)
    If $bReadOnly = Default Then $bReadOnly = False
    If $bVisible = Default Then $bVisible = True
    Local $oWorkbook = $oExcel.Workbooks.Open($sFilePath, $bUpdateLinks, $bReadOnly, Default, $sPassword, $sWritePassword)
    If @error Then Return SetError(3, @error, 0)
    $oExcel.Windows($oWorkbook.Name).Visible = $bVisible
    ; If a read-write workbook was opened read-only then set @extended = 1
    If $bReadOnly = False And $oWorkbook.Readonly = True Then Return SetError(0, 1, $oWorkbook)
    Return $oWorkbook
EndFunc   ;==>_Excel_BookOpen

 

So this should not throw error like this one you get.

 

 

 

 

[UEZ]

Exactly, that's the point!

Another issue is when I've a comma separated text file it works to load it with

Local $oWorkbook = _Excel_BookOpenText($oExcel, @ScriptDir & "\Test.txt")

but it doesn't when the file extension is csv:

Local $oWorkbook = _Excel_BookOpenText($oExcel, @ScriptDir & "\Test.csv")

 

Edited September 23, 2015 by UEZ

[mLipok]

One web created Excel sheet ......

What you mean ? Can you provide example file ? Which Excel version ?

[UEZ]

The generated Excel file is from the company I'm working for and it is confidential. Sorry, I cannot publish it here!

It can be that the generated Excel sheet is somehow "buggy". I've no information about how the XLSX file is generated.

 

[mLipok]

The generated Excel file is from the company I'm working for and it is confidential. Sorry, I cannot publish it here!

It can be that the generated Excel sheet is somehow "buggy". I've no information about how the XLSX file is generated.

It was obvious to me and did not require clarification.

But I see that I must clarify my earlier question.

Can you provide example file ?

I was thinking about something like this:

Make copy, delete all unneeded data, leave only empty sheets, Test it again with your script.
Next change the name of all sheets (simply "Sheet1", "Sheet2"...), and test it again.
If the issue will still exist, then remove any other confidential data and test it again, eventualy post to the forum such a clean and "buggy" XLSX file (of course: If the policy of the company and the right people permit).

 

Edited September 23, 2015 by mLipok
typo

[UEZ]

I'm currently developing a tool to display a rack layout using the generated xlsx sheet. I cannot tell the users to make several modifications to the Excel sheet to get it run using my AutoIt script.

The exported XLSX is not always "buggy" but another issue is that the _Excel_FilterSet also doesn't work properly. I'm thinking about to use only the CSV file but as mentioned in post#3 the file has to be renamed to txt to run properly on non US system settings for delimiter. On my system the default delimiter is ";".

[water]

I was able to work with the example file and this are my findings:

• _Excel_BookOpen returns an object. I checked this by using IsObj()
• The object is not of the needed type "_Workbook". I checked this by using ObjName()
• As the object is of the wrong type the next command using this object failed ($oExcel.Windows($oWorkbook.Name).Visible = $bVisible)
• This strange behavior is only seen with AutoIt 3.3.14.x. It works as expected with 3.3.12.0.

[mLipok]

This looks like a job for Dev.

On reflection it possible that I had a similar problem with other UDF, for now I can not grasp him, but sometimes simply a program crashes with using some objects (because of that I did not report it yet), and in my case the problem arises with Au3.3.14.x 
This issue directed my search for a new track (must recheck my script).

[mLipok]

I was able to work with the example file and this are my findings:

• The object is not of the needed type "_Workbook". I checked this by using ObjName()
• As the object is of the wrong type the next command using this object failed ($oExcel.Windows($oWorkbook.Name).Visible = $bVisible)

For this case I start to Validate with ObjName() each object in XMLWrapperEx Beta.

 

Edit: 
But only for parameters.

Edited September 23, 2015 by mLipok

[UEZ]

The Excel files are created using Open XML for Office.

[water]

As the way COM errors are handled has changed with 3.3.14.0 and function _Excel_BookOpen misses a call to the COM error handler (which has been fixed in the latest Beta) the function crashes for this very special workbook.
I still don't know why this Workbook provides no name property and returns a very strange object (which should be a _Workbook object).

As a workaround you could insert the following lines into the UDF at the top of function _Excel_BookOpen. This really doesn't solve the problem because the error goes unhandled and might brake the next function that relies on the Workbook object.

; Error handler, automatic cleanup at end of function
    Local $oError = ObjEvent("AutoIt.Error", "__Excel_COMErrFunc")
    #forceref $oError

 

[Lights_On]

Hi Water & All,

I hope it’s okay adding to this post.  I have (almost) exactly the same issue – I get the same error for the same reasons.  I am running V3.3.14.2 and working with Excel 2010.  The code I have the error at is:

 

Local $Data_Table = _Excel_BookOpen($oExcel, "C:\Full_Path_To_The_Script.xlsx", False, True)
    If @error Then
        _log('ERROR - Excel book did not open properly, the @error code is: ' & @error)
    Else
        _log('Excel book open was successful')
    EndIf

I have a ‘home made’ logging system set up and the error is (if it happens) always at this point but does not always happen at this point since sometimes it works.  The wider script loops until end.

There are lots of book open and book close statements in the script – they all have @error checking.  They all open and close fine (according to the log) and I have checked many times all statements to ensure accuracy. All seems good.

So my issue is why am I too getting the same error message as UEZ in post No.1 and also how come the fix suggested by Water in post No.12 not working?  (It matches my UDF – Excel.au3)

I have ensured that I include excel.au3 and also excelconstans.au3 in the script.  I also ensure ProcessClose(“excel.exe”) at the top of my script to ensure a fresh start. I have also tried full path to script as well as @scriptdir…. But always still the same result either way. I also have no macros or anything special like that in the excel documents – they are very basic files with simple rows of data.

The script runs all .xlsx processing and works with several different books – it is just this file that causes the issue.  I create this file with a _Excell_SaveAs but I also do this with other books and use identical statement but only this file has the issue.  This file is opened and closed more often than the others however – could it be that it needs longer to close even though no error is logged and it states it had previously closed fine?

What to try next?  This should work right?

Thank you in advance.

 

[water]

Because the problem is not caused by a missing COM error but by an AutoIt bug. In the first post the problem is caused when accessing a property of an object that doesn't exist.

Add the following function to your script and replace _Excel_BookOpen with _Excel_BookOpenEX.

Func _Excel_BookOpenEX($oExcel, $sFilePath, $bReadOnly = Default, $bVisible = Default, $sPassword = Default, $sWritePassword = Default, $bUpdateLinks = Default)
    ; Error handler, automatic cleanup at end of function
    Local $oError = ObjEvent("AutoIt.Error", "__Excel_COMErrFunc")
    #forceref $oError
    If Not IsObj($oExcel) Or ObjName($oExcel, 1) <> "_Application" Then Return SetError(1, @error, 0)
    If Not FileExists($sFilePath) Then Return SetError(2, 0, 0)
    If $bReadOnly = Default Then $bReadOnly = False
    If $bVisible = Default Then $bVisible = True
    Local $oWorkbook = $oExcel.Workbooks.Open($sFilePath, $bUpdateLinks, $bReadOnly, Default, $sPassword, $sWritePassword)
    If @error Then Return SetError(3, @error, 0)
    Local $oWindow = $oExcel.Windows($oWorkbook.Name) ; <== Modified
    If IsObj($oWindow) Then $oWindow.Visible = $bVisible ; <== Modified
    ; If a read-write workbook was opened read-only then set @extended = 1
    If $bReadOnly = False And $oWorkbook.Readonly = True Then Return SetError(0, 1, $oWorkbook)
    Return $oWorkbook
EndFunc   ;==>_Excel_BookOpen

[Lights_On]

Thank you for the quick reply - I am very grateful.

I have added the above code and so far the problem has not returned but it now stops at:

Local $RowToCopyAfterCalc = $Data_Table.Worksheets(1).Range("A2:AD2")

but not on the first time but instead the 3rd time it is called? the first two times it works fine.  I will check this a little further.

The above code happens before where the prior mentioned code / issue is, so as such I may still have an issue - I will report back.

Thank you.

[Lights_On]

Hi Water, 

Final outcome was that the original issue has never returned since adding your code. Thank you for that. The further problem I have solved with properly using _excel_copy paste as per UDF.

My final issue is all runs fine now but crashes at the end. E.g windows critical error. Odd. I have run scrip in scite with trace and all runs start to finish fine and as expected. Very odd.  That issue is realy for another post however.

Thank you again @water. I see you help lots of people here and I, as many others, am very greatful.

 

Edited January 23, 2016 by Lights_On

[water]

[antonioj84]

Great post water , is this going to be part of the next release (  _Excel_BookOpen with _Excel_BookOpenEX. )

[water]

Will add it to the pinned thread in the GH&S forum: https://www.autoitscript.com/forum/forum/2-autoit-general-help-and-support/

If it still needs to be added to the next AutoIt release depends on how Jon decides to handle the COM error handling in the future (means: revert to how it worked with AutoIt 3.3.12.0 or just remove the bugs in the curent approach).

[water]

Done