A strange problem in combo box.

[kcvinu]

Hi all,

I am playing with a combo box. The code from help file is working. But the code i wrote is not working. Help file uses "_GUICtrlComboBox_Create" for creating combo box. But i used native "GUICtrlCreateCombo". Then i replaced my native combo creation function with the UDF. Then my code worked. I think the hi word and low word parameters are the problem. 

Here is my code.

expandcollapse popup

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Local $sCMB_Items = "Apple|Orange|Mango|Banana|Grape"
#Region ### START Koda GUI section ### Form=
Global $hForm1 = GUICreate("Form1", 283, 188, 312, 166)
Global $hCombo1 = GUICtrlCreateCombo("", 40, 48, 185, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
GUICtrlSetData($hCombo1, $sCMB_Items)
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode
    $hWndFrom = $lParam
    $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word
    $iCode = BitShift($wParam, 16) ; Hi Word
    Switch $hWndFrom
        Case $hCombo1
            Switch $iCode
                Case $CBN_DBLCLK
                    ; Insert your code here
                    MsgBox(0,"","$CBN_DBLCLK")
                Case $CBN_DROPDOWN
                    ; Insert your code here
                    MsgBox(0,"","$CBN_DROPDOWN")
                Case $CBN_EDITCHANGE
                    ; Insert your code here
                    MsgBox(0,"","$CBN_EDITCHANGE")
                Case $CBN_SELCHANGE
                    ; Insert your code here
                    MsgBox(0,"","$CBN_SELCHANGE")

            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

And this is the code from help file. Slightly modified. But working

expandcollapse popup

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Global $g_hCombo

Example()

Func Example()
    Local $hGUI

    ; Create GUI
    $hGUI = GUICreate("(UDF) ComboBox Create", 400, 296)
    $g_hCombo = _GUICtrlComboBox_Create($hGUI, "", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Add files
    _GUICtrlComboBox_BeginUpdate($g_hCombo)
    _GUICtrlComboBox_AddDir($g_hCombo, "", $DDL_DRIVES, False)
    _GUICtrlComboBox_EndUpdate($g_hCombo)

    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $hWndFrom, $iIDFrom, $iCode
    $hWndFrom = $lParam
    $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word
    $iCode = BitShift($wParam, 16) ; Hi Word
    Switch $hWndFrom
        Case $g_hCombo
            Switch $iCode
                Case $CBN_CLOSEUP ; Sent when the list box of a combo box has been closed
                    MsgBox(0,"","$CBN_CLOSEUP")
                Case $CBN_DBLCLK ; Sent when the user double-clicks a string in the list box of a combo box
                    MsgBox(0,"","$CBN_DBLCLK")
                Case $CBN_DROPDOWN ; Sent when the list box of a combo box is about to be made visible
                    MsgBox(0,"","$CBN_DROPDOWN")
                Case $CBN_EDITCHANGE ; Sent after the user has taken an action that may have altered the text in the edit control portion of a combo box
                    MsgBox(0,"","$CBN_EDITCHANGE")
                Case $CBN_EDITUPDATE ; Sent when the edit control portion of a combo box is about to display altered text

                Case $CBN_ERRSPACE ; Sent when a combo box cannot allocate enough memory to meet a specific request

                Case $CBN_KILLFOCUS ; Sent when a combo box loses the keyboard focus

                Case $CBN_SELCHANGE ; Sent when the user changes the current selection in the list box of a combo box
                    MsgBox(0,"","$CBN_SELCHANGE")

            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

For those who wants the au3 file;

Here it is

 

Code From help file.au3

My code.au3

[Melba23]

kcvinu,

When you create a control using a native GUICtrlCreate* function, the return value is a ControlID - an integer value. AutoIt uses this ControlID to identify the control - it is in fact the index of the internal array that AutoIt uses to track native control. When you create a control using a UDF, the return is a handle -  a special unique value used by Windows to track virtually everything in the system.

In your first script above you are using the native command - so the $hCombo1 variable holds a ControlID (and should really be named $idCombo1 or $cCombo1). However, in the message handler you are looking for the handle:

$hWndFrom = $lParam

$iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word
$iCode = BitShift($wParam, 16) ; Hi Word
Switch $hWndFrom

    Case $hCombo1

If you replace $hWndFrom with $iIDFrom, you will find that the code works as expected - because you are now checking the ControlID and not the handle. In the second script, you create the combo via the UDF and so get a handle returned - unsurprisingly this works as you are this time checking the handle directly. All clear?

And as always I would counsel against using blocking functions (such as MsgBox) inside a message handle you do in both scripts - the Help file specifically mentions this and it is a warning that should be heeded.

M23

[kcvinu]

@Melba23 Yes. everything is now clear. Thank you for detailed replay. And that MsgBoxes. That is only for testing purpose. I can use console write instead. Once again thanks a lot.