(Solved) GUIRegisterMsg() Starts To Not Working After Adding A Control

[Adele]

Hi everyone. I want to detect when any key is pressed with GUIRegisterMsg(). The issue is that, before adding any control to GUI, it works but when I added, it starts to not working. I somehow don't understand the issue's source.

For example, by this way it works without any issue :

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

GUIRegisterMsg($WM_KEYDOWN, "KeyPress")
$hGUI = GUICreate("")

GUISetState()

While True
    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Func KeyPress()
    MsgBox(0, "", "A key has been pressed.")
EndFunc

But when I added a label, it starts to not working.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

GUIRegisterMsg($WM_KEYDOWN, "KeyPress")
$hGUI = GUICreate("")

;A control to test the issue, GUIRegisterMsg starts not working after it was added
GUICtrlCreateLabel("Test", 10, 10, 300, 300)

GUISetState()

While True
    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Func KeyPress()
    MsgBox(0, "", "A key has been pressed.")
EndFunc

I've searched and I couldn't find something interesting with this. Thank you in advance.

Edited September 17, 2015 by Adele

[JohnOne]

Probably because you have a blocking function in your message handler. You are going to get unexpected behaviour, so a simple answer to why with label? is "unexpected."

[kylomas]

Adele,

A static control cannot accept keyboard input.  One possible workaraound...

#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("")

;A control to test the issue, GUIRegisterMsg starts not working after it was added
local $lbl010 = GUICtrlCreateLabel("Test", 10, 10, 200, 200, $ss_sunken)

guictrlsetstate($lbl010,$GUI_DISABLE)

GUISetState()

GUIRegisterMsg($WM_KEYDOWN, "KeyPress")

While True
    $iMsg = GUIGetMsg()
    Switch $iMsg

        Case $GUI_EVENT_CLOSE
            ExitLoop

    EndSwitch

WEnd



Func KeyPress($hWnd, $iMsg, $wParam, $lParam)
    ConsoleWrite($wParam & ' - ' & $lParam & @CRLF)
    ;MsgBox(0, "", "A key has been pressed.")
EndFunc

Note - Please heed J1's observation about message handlers.  The doc is very specific about their use.

kylomas

EDIT: Please read the forum rules regarding keyloggers. 

Edited September 17, 2015 by kylomas
Additional info

[Adele]

There isn't a special reason for I use label. I'll prepare a ordinary interface with using GUI controls like input, label... As well as when I pressed to any key, the program will detect that.

[kylomas]

You may not have seen my edit.  Please read the forum rules regarding keyloggers.

kylomas

[Adele]

I don't make a program similar keylogger. Only the program's window is active, it should detect key pressing. I prepare a screensaver. I don't need to get which key was pressed. I need to detect when any key was pressed.

Edited September 17, 2015 by Adele

[kylomas]

Adele,

Glad to hear it.  You may be interested in _WinAPI_GetIdleTime.  See the Help file.

kylomas

[Adele]

@kylomas Thank you, I guess this will help me.