read the string inbetween 2 strings

[Sandhya]

I need to read the value, normally a number, inbetween 2 strings from a text file. I tried the following code, but not returned result. please tell me a way.

Local $file = "D:\AutoIT\CMP.TXT"
Run ("notepad.exe " & $file)
WinWaitActive ("CMP.TXT")
Local $sTemp = FileReadLine($file)
Local $aArray = _StringBetween($sTemp, "All selected attributes", "Long identifier")
_ArrayDisplay($aArray)

Edited September 15, 2015 by Sandhya

[jchd]

What has Notepad doing here? And what is in the file exactly?

[Sandhya]

i need to find the value between two string in a log file.

[jchd]

So leave Notepad alone and go ahead. If anything fails, post a short reproducer so that somebody can help.

[kcvinu]

@Sandhya , As jchd said, you don't need to open notepad for this. First of all read all lines of the text file to an array. That's what you did in your script. And then loop through each element in your array. Check for your number in each element. You can use regular expression for this. 

 

[Sandhya]

You mean like the below one?

Local $file = "D:\AutoIT\CMP.TXT"
Local $sTemp = FileReadLine($file)
Local $aArray = _StringBetween($sTemp, "All selected attributes", "Long identifier")
_ArrayDisplay($aArray)

this will not even open the file right?

i tried like this also. but didnt work.

Local $file = "D:\AutoIT\CMP.TXT"

Local $start = "All selected attributes"
Local $end = "Long identifier"
Local $hFileOpen = FileOpen($file, $FO_READ)
WinWaitActive ("CDM_CMP.TXT")
Local $sTemp = FileReadLine($hFileOpen)
Local $aArray = _StringBetween($sTemp, $start, $end)
_ArrayDisplay($aArray)

Edited September 15, 2015 by Sandhya

[JLogan3o13]

Take out the WinWaitActive. This works just fine for me (saved the text file to my desktop):

#include <Array.au3>
#include <File.au3>
#include <String.au3>

Local $file = @DesktopDir & "\CMP.TXT"
Local $start = "All selected attributes"
Local $end = "Long identifier"
Local $hFileOpen = FileOpen($file, $FO_READ)
Local $sTemp = FileReadLine($hFileOpen)
Local $aArray = _StringBetween($sTemp, $start, $end)
_ArrayDisplay($aArray)
FileClose($file)

 

[guinness]

@Sandhya when you post code please wrap inside a code block.

[ViciousXUSMC]

Try something like this?

#Include <File.au3>
#Include <String.au3>
#Include <Array.au3>

$vFile = @ScriptDir & "\cmp.txt"

Local $aFile
Local $aFinal[0]

_FileReadToArray($vFile, $aFile)

For $i = 1 to $aFile[0]
    $sTemp = _StringBetween($aFile[$i], "All selected attributes", "Long identifier")
    If $sTemp <> 0 Then _ArrayAdd($aFinal, $sTemp[0])
Next

_ArrayDisplay($aFinal)

And I am not sure but it may be faster with RegEx

#Include <File.au3>
#Include <String.au3>
#Include <Array.au3>
#Include <StringConstants.au3>

$vFile = @ScriptDir & "\cmp.txt"

Local $aFile
Local $aFinal[0]

_FileReadToArray($vFile, $aFile)

For $i = 1 to $aFile[0]
    ;$sTemp = _StringBetween($aFile[$i], "All selected attributes", "Long identifier")
    $sTemp = StringRegExp($aFile[$i], "(?i)all selected attributes (.*) long identifier", $STR_REGEXPARRAYMATCH)
    If $sTemp <> 0 Then _ArrayAdd($aFinal, $sTemp)
Next

_ArrayDisplay($aFinal)

And this possibly faster yet.

#Include <File.au3>
#Include <String.au3>
#Include <Array.au3>
#Include <StringConstants.au3>

$vFile = @ScriptDir & "\cmp.txt"

$hFile = FileOpen($vFile)
$sFile = FileRead($hFile)
Local $aFinal[0]

$aFinal = StringRegExp($sFile, "(?i)all selected attributes (.*) long identifier", $STR_REGEXPARRAYGLOBALMATCH)

FileClose($hFile)

_ArrayDisplay($aFinal)

 

String Between.au3

String Between RegEx.au3

String Between RegEx2.au3

cmp.txt

Edited September 15, 2015 by ViciousXUSMC

[kcvinu]

You mean like the below one?

Local $file = "D:\AutoIT\CMP.TXT"
Local $sTemp = FileReadLine($file)
Local $aArray = _StringBetween($sTemp, "All selected attributes", "Long identifier")
_ArrayDisplay($aArray)

this will not even open the file right?

 

Function FileReadLine will accept an optional parameter line. But you didn't provided it. So i am assuming that your txt file had only one line text. If it is right, then you can do some error check. I think your variable $sTemp is probably null value . Do one thing. First open the file with FileOpen() function. Then use the file handle instead of file path in FileReadLine function. 

[Malkey]

If the first and only line of the file is needed then use FileReadLine().

#include <Array.au3>
#include <String.au3>

Local $file = "CMP1.TXT"
If FileExists($file) = 0 Then
    FileWrite($file, "To all selected attributes 26 Long identifier end" & @CRLF & "Next line All selected attributes 522 long identifier to end.")
EndIf

Local $aArray = _StringBetween(FileRead($file), "All selected attributes", "Long identifier", $STR_ENDNOTSTART)

_ArrayDisplay($aArray)
FileDelete($file)

 

[Sandhya]

Thank you all.

Some problem with text file itself. Otherwise the code is perfect.

[Sandhya]

if space and next line are there, will it be able to identify the value? That is what is happening in my case. the below given text are part of the file and I need to find the value "5".

  All selected attributes              5
  Long identifier

[kcvinu]

@Sandhya If the file has more lines, then you need to supply the line number parameter for FileReadLine function. Otherwise it will read the first line. As far as i know your problem, i can tell you that using regular expression will solve your problem easily. If your file has more than one line and you don't know in which line the number resides, then you can read all line to an array and loop through them and check each line with regex.

[ViciousXUSMC]

Can you post a full example of your text file?  Is the value always a single number?

It will be pretty easy using one of the two RegEx examples I have above once we know exactly what it is your looking at. 

I am no RegEx guy but I came up with this that works given the example you gave.

#Include <File.au3>
#Include <String.au3>
#Include <Array.au3>
#Include <StringConstants.au3>

$vFile = @ScriptDir & "\cmp.txt"

$hFile = FileOpen($vFile)
$sFile = FileRead($hFile)
Local $aFinal[0]

$aFinal = StringRegExp($sFile, "(?i)all selected attributes\s+(\w+)\s", $STR_REGEXPARRAYGLOBALMATCH)

FileClose($hFile)

_ArrayDisplay($aFinal)

 

Edited September 16, 2015 by ViciousXUSMC

[iamtheky]

$aMatch = stringregexp(stringstripws($sString , 8) , "(?i)allselectedattributes(\d+)longidentifier" , 3)
_ArrayDisplay($aMatch)

 

[ViciousXUSMC]

If "longidentifier" is on a new line its not going to show up in that search is it? as a @LF or @CRLF is not stripped as whitespace.

[iamtheky]

it will

Whitespace includes Chr(9) thru Chr(13) which are HorizontalTab, LineFeed, VerticalTab, FormFeed, and CarriageReturn. Whitespace also includes the null string ( Chr(0) ) and the standard space ( Chr(32) ).

$sString = "All selected attributes              5" & @CRLF & "Long identifier"
;~ $sString = "To all selected attributes 26 Long identifier end" & @CRLF & "Next line All selected attributes 522 long identifier to end."

$aMatch = stringregexp(stringstripws($sString , 8) , "(?i)allselectedattributes(\d+)longidentifier" , 3)

for $sMatch in $aMatch
   msgbox(0, '' , $sMatch)
next

 

Edited September 16, 2015 by boththose

[ViciousXUSMC]

Well that is good to know, so it puts the entire file on a single line basically as a giant block of text

Since the OP said "usually" a number I think that means we may need to take into account for words as well.  I had to make the \w lazy else it was pulling bad results.  This looks good to me other than if your words had a space the space would be stripped as my example file has "test string 2" it will result with "teststring2"

#Include <File.au3>
#Include <String.au3>
#Include <Array.au3>
#Include <StringConstants.au3>

$vFile = @ScriptDir & "\cmp.txt"

$hFile = FileOpen($vFile)
$sFile = FileRead($hFile)
$sFileStrip = StringStripWS($sFile, $STR_STRIPALL)
Local $aFinal[0]

$aFinal = StringRegExp($sFileStrip, "(?i)allselectedattributes(\w+?)longidentifier", $STR_REGEXPARRAYGLOBALMATCH)

FileClose($hFile)

_ArrayDisplay($aFinal)

 

String Between RegEx3.au3

cmp.txt

Edited September 16, 2015 by ViciousXUSMC

[Sandhya]

Thanks a lot guys..

Edited September 18, 2015 by Sandhya