Anybody have analog of GUICtrlSetResizing function for _GUICtrlComboBox_Create control?

[Inververs]

Help me please with resizing of _GUICtrlComboBox_Create control
It should resizing like native Combo with

GUICtrlSetResizing($GUI_CMB_LIST, BitOR($GUI_DOCKRIGHT, $GUI_DOCKLEFT, $GUI_DOCKHEIGHT, $GUI_DOCKTOP))

Thank you.

[Melba23]

Inververs,

I usually create an invisible label which has the required resizing parameters and then resize the UDF control to fit it in a WM_SIZE message handler:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>

$hGUI = GUICreate("test", 400, 400, Default, Default, $WS_SIZEBOX)

$cLabel = GUICtrlCreateLabel("", 20, 20, 200, 20) ; Label which will adjust with the GUI
GUICtrlSetBkColor($cLabel, 0xFFCCCC)
GUICtrlSetResizing($cLabel, $GUI_DOCKRIGHT + $GUI_DOCKLEFT + $GUI_DOCKHEIGHT + $GUI_DOCKTOP)

$hCombo = _GUICtrlComboBox_Create($hGUI, "", 20, 20, 200)

GUISetState()

GUIRegisterMsg($WM_SIZE, "_WM_SIZE")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd



Func _WM_SIZE($hWnd, $iMsg, $wParam, $lParam)

    ; Get label posiition and size and adjust child GUI to fit
    $aPos = ControlGetPos($hGUI, "", $cLabel)
    WinMove($hCombo, "", $aPos[0], $aPos[1], $aPos[2], $aPos[3])

EndFunc

Incidentally, you should use normal addition for the resizing parameters, not BitOr as with Windows styles.

M23

[Inververs]

Melba23, it is a good idea, thx.

  Quote

Incidentally, you should use normal addition for the resizing parameters, not BitOr as with Windows styles.

got it.

 

Topic is solved, thanks!