_IEgetobjbyclassname()

[uncommon]

I think this has been around in IE for a while. Seems useful. Would it be possible to put something like this into the next IE UDF update? I know dale is the one who manages it. Maybe he can chime in? BTW I pretty much changed the settings around from _IEgetobjbyname()

expandcollapse popup

;#FUNCTION#=============================================================================================================
; Name...........: _IEClassNameGetCollection()
; Description ...: Returns an Object or a Colection of objects
; Syntax.........: (ByRef $o_object, $s_ClassName, $i_index = -1)
; Parameters ....: $o_object - The document object from IE
;                  $s_ClassName - The Name of the class to reference
;                  $i_index -     [optional] -1 (default) returns a colection, else use a 0 based index to indicate the object in sequence
; Return values .: Success - Object or a Colection of objects
;                  Failure - returns 0 sets the @error flag to non-zero.
;                   3 ($_IEStatus_InvalidDataType) - Invalid Data Type
;                   4 ($_IEStatus_InvalidObjectType) - Invalid Object Type
;                   5 ($_IEStatus_InvalidValue) - Invalid Value
;                   7 ($_IEStatus_NoMatch) - No Match
; Author ........: XThrax aka uncommon
; Remarks .......: This fuctions was pretty much stolen from Dale Hohm the IE UDF creator so much credit to him.
;                  
; Related .......: _IETagNameAllGetCollection()
; Link ..........;https://www.autoitscript.com/forum/topic/177201-_iegetobjbyclassname
;                 https://msdn.microsoft.com/en-us/library/ff975198(v=vs.85).aspx
; Example .......; No
; =====================================================================================================================
Func _IEClassNameGetCollection (ByRef $o_object, $s_ClassName, $i_index = -1)
    If Not IsObj($o_object) Then
        __IEConsoleWriteError("Error", "_IEClassNameGetCollection", "$_IEStatus_InvalidDataType")
        Return SetError($_IEStatus_InvalidDataType, 1, 0)
    EndIf
    ;
    If Not __IEIsObjType($o_object, "browserdom") Then
        __IEConsoleWriteError("Error", "_IEClassNameGetCollection", "$_IEStatus_InvalidObjectType")
        Return SetError($_IEStatus_InvalidObjectType, 1, 0)
    EndIf

    Local $oTemp
    If __IEIsObjType($o_object, "documentcontainer") Then
        $oTemp = _IEDocGetObj($o_object)
    Else
        $oTemp = $o_object
    EndIf

    $i_index = Number($i_index)
    Select
        Case $i_index = -1
            Return SetError($_IEStatus_Success, $oTemp.getElementsByClassName($s_ClassName).length, _
                    $oTemp.getElementsByClassName($s_ClassName))
        Case $i_index > -1 And $i_index < $oTemp.getElementsByClassName($s_ClassName).length
            Return SetError($_IEStatus_Success, $oTemp.getElementsByClassName($s_ClassName).length, _
                    $oTemp.getElementsByClassName($s_ClassName).item($i_index))
        Case $i_index < -1
            __IEConsoleWriteError("Error", "_IEClassNameGetCollection", "$_IEStatus_InvalidValue", "$i_index < -1")
            Return SetError($_IEStatus_InvalidValue, 3, 0)
        Case Else
            __IEConsoleWriteError("Error", "_IEClassNameGetCollection", "$_IEStatus_NoMatch")
            Return SetError($_IEStatus_NoMatch, 0, 0) ; Could be caused by parameter 2, 3 or both
    EndSelect
EndFunc   ;==>_IEClassNameGetCollection

https://msdn.microsoft.com/en-us/library/ff975198(v=vs.85).aspx

Edited September 11, 2015 by uncommon
Function revised from _IETagNameAllGetCollection()

[Gianni]

Nice

I would set the default value of $iIndex to -1 instead of 0

edit:
also, maybe a function name like _IEClassGetCollection (or something similar)  wouldn't be more consistent with the other _IE* functions that returns a collection or a single obj by index?

Edited September 10, 2015 by Chimp

[uncommon]

  On 9/10/2015 at 5:33 PM, Chimp said:

Nice

I would set the default value of $iIndex to -1 instead of 0

edit:
also, maybe a function name like _IEClassGetCollection (or something similar)  wouldn't be more consistent with the other _IE* functions that returns a collection or a single obj by index?

II didn't think about that. Revised. 

I used an older function that would take forever with for high index numbers because it would loop count EVERY class and remember the ones that had the correct name. Needless to say, this was 100 times faster.

[mLipok]

Recently I learn that this should like this:

expandcollapse popup

;#FUNCTION#=============================================================================================================
; Name...........: _IEClassNameGetCollection()
; Description ...: Returns an Object or a Colection of objects
; Syntax.........: (ByRef $oIE, $sClassName, $iItemIndex = Default)
; Parameters ....: $oIE - The document object from IE
;                  $sClassName - The Name of the class to reference
;                  $iItemIndex -     [optional] Default returns a colection, else use a 0 based index to indicate the object in sequence
; Return values .: Success - Object or a Colection of objects
;                  Failure - returns 0 sets the @error flag to non-zero.
;                   3 ($_IEStatus_InvalidDataType) - Invalid Data Type
;                   4 ($_IEStatus_InvalidObjectType) - Invalid Object Type
;                   5 ($_IEStatus_InvalidValue) - Invalid Value
;                   7 ($_IEStatus_NoMatch) - No Match
; Author ........: XThrax aka uncommon
; Modified ......: mLipok
; Remarks .......: This fuctions was pretty much stolen from Dale Hohm the IE UDF creator so much credit to him.
;
; Related .......: _IETagNameAllGetCollection()
; Link ..........;https://www.autoitscript.com/forum/topic/177201-_iegetobjbyclassname
;                 https://msdn.microsoft.com/en-us/library/ff975198(v=vs.85).aspx
; Example .......; No
; =====================================================================================================================
Func _IEClassNameGetCollection(ByRef $oIE, $sClassName, $iItemIndex = Default)
    If Not IsObj($oIE) Then
        ; __IEConsoleWriteError("Error", "_IEClassNameGetCollection", "$_IEStatus_InvalidDataType")
        Return SetError($_IEStatus_InvalidDataType, 1, 0)
    ElseIf Not __IEIsObjType($oIE, "browserdom") Then
        ; __IEConsoleWriteError("Error", "_IEClassNameGetCollection", "$_IEStatus_InvalidObjectType")
        Return SetError($_IEStatus_InvalidObjectType, 1, 0)
    ElseIf Not IsNumber($iItemIndex) Then
        Return SetError($_IEStatus_InvalidValue, 3, 0)
    ElseIf $iItemIndex = Default Or $iItemIndex >= 0 Then
        Local $oTemp = Null
        If __IEIsObjType($oIE, "documentcontainer") Then
            $oTemp = _IEDocGetObj($oIE)
            If @error Then Return SetError(@error,@extended,0)
        Else
            $oTemp = $oIE
        EndIf

        Local $oClassColl = $oTemp.getElementsByClassName($sClassName)
        If @error Then
            ; __IEConsoleWriteError("Error", "_IEClassNameGetCollection", "$_IESTATUS_GeneralError", "")
            Return SetError($_IESTATUS_GeneralError, 3, 0)
        ElseIf (Not IsObj($oClassColl)) Or $oClassColl = Null Or $oClassColl.length = 0 Then
            ; __IEConsoleWriteError("Error", "_IEClassNameGetCollection", "$_IEStatus_NoMatch")
            Return SetError($_IEStatus_NoMatch, 0, 0) ; Could be caused by parameter 2, 3 or both
        Else
            If $iItemIndex = Default Then
                Return SetError($_IEStatus_Success, $oClassColl.length, $oClassColl)
            ElseIf $iItemIndex > $oClassColl.length Then
                Return SetError($_IEStatus_InvalidValue, $oClassColl.length, 0)
            Else
                $oItem = $oClassColl.Item($iItemIndex)
                If @error Then
                    Return SetError($_IESTATUS_GeneralError, 3, 0)
                ElseIf (Not IsObj($oItem)) Or $oItem = Null Then
                    Return SetError($_IEStatus_NoMatch, 0, 0) ; Could be caused by parameter 2, 3 or both
                Else
                    Return SetError($_IEStatus_Success, 0, $oItem)
                EndIf
            EndIf
        EndIf

    Else
        ; __IEConsoleWriteError("Error", "_IEClassNameGetCollection", "$_IEStatus_InvalidValue", "$iItemIndex < -1")
        Return SetError($_IEStatus_InvalidValue, 3, 0)
    EndIf

EndFunc   ;==>_IEClassNameGetCollection

 

REMARK: Not tested.

[mLipok]

  On 9/10/2015 at 6:25 AM, uncommon said:

Would it be possible to put something like this into the next IE UDF update?

Expand  

I think: Yes.