How to call COM method that expects pointers as params?

[corgano]

My end goal is to get the caret position in microsoft word and turn it into an absolute x/y screen coordinate.

I'm trying to turn some code from C++ to autoit, found here
https://groups.google.com/d/msg/microsoft.public.word.vba.general/pKq4PsqD3cM/yDukAS5Bk3cJ
And I'm stuck when trying to call.Window.GetPoint Method (Word)
https://msdn.microsoft.com/EN-US/library/office/ff836626.aspx
I tried calling it like this:
 

#include <MsgBoxConstants.au3>
#include <Word.au3>
#include <Array.au3>

; Create application object
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocAttach Example", _
        "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; *****************************************************************************
; Attach to the active doc
; *****************************************************************************
Local $oDoc = _Word_DocGet ( $oWord , 0 )

Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")

;//position dialog relative to word insertion point (caret)
$left = 0
$top = 0
$width = 0
$height = 0
$r = $oDoc.Application.Selection.Range
$w = $oDoc.ActiveWindow

$w.GetPoint( $left, $top, $width, $height, $r );

ConsoleWrite("left "&$left&"    top "&$top&@CRLF)

And I keep getting this error:
 

New AutoIt v3 Script.au3 (27) : ==> COM Error intercepted !
    err.number is:      0x800706F4
    err.windescription: A null reference pointer was passed to the stub.

    err.description is:     
    err.source is:      
    err.helpfile is:    
    err.helpcontext is:     
    err.lastdllerror is:    0
    err.scriptline is:  27
    err.retcode is:     0x00000000

left 0  top 0

How do I call it properly?

[corgano]

Still no replies? Should I repost in the general help section?

[mLipok]

$r = $oDoc.Application.Selection.Range
MsgBox(0, '@error', @error)
$w = $oDoc.ActiveWindow

add @error checking and say what you get.

[mLipok]

Still no replies? Should I repost in the general help section?

Do not post multiple topics on the same question.
btw. This indead should be posted in GH&S  

as this on in which we are now is for using this:

 Katalog: c:\Program Files (x86)\AutoIt3\AutoItX

10.07.2015  13:16    <DIR>          .
10.07.2015  13:16    <DIR>          ..
10.07.2015  11:51           206 272 AutoItX.chm
10.07.2015  11:51            22 458 AutoItX.psd1
10.07.2015  11:51            41 272 AutoItX3.Assembly.dll
10.07.2015  11:43            49 518 AutoItX3.Assembly.xml
10.07.2015  11:51           456 008 AutoItX3.dll
10.07.2015  11:51            49 976 AutoItX3.PowerShell.dll
09.07.2015  13:22            12 993 AutoItX3_DLL.h
10.07.2015  11:43            28 976 AutoItX3_DLL.lib
10.07.2015  11:51           515 400 AutoItX3_x64.dll
10.07.2015  11:43            27 546 AutoItX3_x64_DLL.lib
10.07.2015  13:16    <DIR>          Examples

 

[corgano]

$r = $oDoc.Application.Selection.Range
MsgBox(0, '@error', @error)
$w = $oDoc.ActiveWindow

add @error checking and say what you get.

I added checks for both $r and $w to see if there were any errors and to make sure they were objects, and they all check out. That is not the issue as far as I can tell.

My question is how do I call Window.GetPoint, assuming $w is a valid window and $r is a valid range.

[LarsJ]

I rarely visit this forum. If you're still interested, you do it this way:

$tLeft   = DllStructCreate( "int" )
$tTop    = DllStructCreate( "int" )
$tWidth  = DllStructCreate( "int" )
$tHeight = DllStructCreate( "int" )

$pLeft   = DllStructGetPtr( $tLeft )
$pTop    = DllStructGetPtr( $tTop )
$pWidth  = DllStructGetPtr( $tWidth )
$pHeight = DllStructGetPtr( $tHeight )

$w.GetPoint( $pLeft, $pTop, $pWidth, $pHeight, $r )

$left   = DllStructGetData( $tLeft, 1 )
$top    = DllStructGetData( $tTop, 1 )
$width  = DllStructGetData( $tWidth, 1 )
$height = DllStructGetData( $tHeight, 1 )