Thousand Separator

[NoizeBit]

Hello,

Once again, I'd like to ask for some help. I'd like to have 10,000.00 as a result here instead of 100,00.00. What do I need to change?

StringRegExpReplace("10000.00", '(\A\d{1,3}(?=(\d{3})+\z)|\d{3}(?=\d))', '\1,')

The string might change from time to time to 1000.00 or 1000000.00, so it would be great to have this thousand separator all the time.

Thanks!

Edited August 29, 2015 by NoizeBit

[Melba23]

NoizeBit,

I still use the old function that was removed a while ago:

expandcollapse popup

;===============================================================================
; Function Name:   _StringAddThousandsSep()
; Description:     Returns the original numbered string with the Thousands and or Decimal delimiter(s) inserted.
; Syntax:          _StringAddThousandsSep($s_string[, $i_convert_lcid = -1[, $i_current_lcid = -1]])
; Parameter(s):    $s_string         - The string to be converted.
;                  $i_convert_lcid   - Optional: Default or -1 wll be the User default locale else:
;                                      LCID of what you want to convert number to.
;                  $i_current_lcid   - Optional: Default or -1 wll be the User default locale else:
;                                      LCID number was converted with originally.
; Requirement(s):
; Return Value(s): - Success - The string with Thousands delimiter added.
;                  - Failure - Returns empty string and sets @error to 1.
; Author(s):       SmOke_N, Valik, GEOSoft

; Modification(s):
; Note(s):    Changes are script breaking after AutoIt version 3.3.0.0
;             LCID numbers can be obtained by pre-pending the OSLang codes in the help file appendix with "0x".
; Example(s):

;===============================================================================

$sRet = _StringAddThousandsSep("10000.00")
ConsoleWrite($sRet & @CRLF)

Func _StringAddThousandsSep($s_string, $i_convert_lcid = -1, $i_current_lcid = -1)
    ; $LOCALE_USER_DEFAULT = 0x0400
    If $i_current_lcid = -1 Or $i_current_lcid = Default Then $i_current_lcid = 0x0400
    If $i_convert_lcid = -1 Or $i_convert_lcid = Default Then $i_convert_lcid = 0x0400

    ; Get lcid decimal and thousands separators
    Local $t_buff_tmp = DllStructCreate("char[4]")
    DllCall("kernel32.dll", "int", "GetLocaleInfo", "int", $i_current_lcid, _
            "int", 0x0E, "ptr", DllStructGetPtr($t_buff_tmp), "int", 4)
    If @error Then Return SetError(1, 0, "")
    Local $s_cur_dec = DllStructGetData($t_buff_tmp, 1)

    DllCall("kernel32.dll", "int", "GetLocaleInfo", "int", $i_convert_lcid, _
            "int", 0x0E, "ptr", DllStructGetPtr($t_buff_tmp), "int", 4)
    If @error Then Return SetError(1, 0, "")
    Local $s_con_dec = DllStructGetData($t_buff_tmp, 1)

    DllCall("kernel32.dll", "int", "GetLocaleInfo", "int", $i_convert_lcid, _
            "int", 0x0F, "ptr", DllStructGetPtr($t_buff_tmp), "int", 4)
    If @error Then Return SetError(1, 0, "")
    Local $s_con_tho = DllStructGetData($t_buff_tmp, 1)

    ; For later formatting
    Local $i_number = StringRegExpReplace($s_string, "(\" & $s_cur_dec & "\d+\z)|(^-|\d+)|(\D)", "$2")
    Local $i_dec = StringRegExpReplace($s_string, "(.+?\" & $s_cur_dec & ")(\d+\z)", "$2")
    If @extended = 0 Then $i_dec = ""

    Local $i_str_len = StringLen($s_string) * 4
    Local $t_numberfmt = DllStructCreate("uint;uint;uint;ptr;ptr;uint")
    Local $t_thousands = DllStructCreate("wchar[2]")
    Local $t_decimal = DllStructCreate("wchar[2]")
    Local $t_buffer = DllStructCreate("wchar[" & $i_str_len & "]")

    DllStructSetData($t_thousands, 1, $s_con_tho)
    DllStructSetData($t_decimal, 1, $s_con_dec)
    DllStructSetData($t_numberfmt, 3, 3)
    DllStructSetData($t_numberfmt, 4, DllStructGetPtr($t_decimal))
    DllStructSetData($t_numberfmt, 5, DllStructGetPtr($t_thousands))
    DllStructSetData($t_numberfmt, 6, 1)

    DllCall("kernel32.dll", "int", "GetNumberFormatW", _
            "int", $i_convert_lcid, "int", 0, _
            "wstr", $i_number, "ptr", DllStructGetPtr($t_numberfmt), _
            "ptr", DllStructGetPtr($t_buffer), "int", $i_str_len)

    If $i_dec = "" Then $s_con_dec = ""
    Return DllStructGetData($t_buffer, 1) & $s_con_dec & $i_dec

EndFunc   ;==>_StringAddThousandsSep

M23

Edited August 30, 2015 by Melba23

[guinness]

There is also a regex version by @AZJIO somewhere on the forum. The thousandth separator is a funny thing, because in some countries a comma (,) represents a decimal character. For example in the UK and USA, 1,000 is one thousand, whereas somewhere else it would be 1.000. Weird isn't it!

Edited August 29, 2015 by guinness

[iamtheky]

If I had that need I would end up with something more like:

 

 

msgbox(0, '' , _AddThousandsSep("1000000000.98")) ; default comma
msgbox(0, '' , _AddThousandsSep("10000.00" , ".")) ; specify period
msgbox(0, '' , _AddThousandsSep("1987" , "|")) ; specify pipe


Func _AddThousandsSep($sString , $sSep = ",")

$aString = stringsplit($sString , "." , 2)
$nMax = round(stringlen($aString[0]) / 3)
local $aNum[$nMax]
$sWorking = $aString[0]
$sOut = ""

for $i = 0 to $nMax
    If stringlen($sWorking) > 2 Then
        $sOut = $sSep & stringright($sWorking , 3) & $sOut
        $sWorking = stringtrimright($sWorking , 3)
    Else
        $sOut = ubound($aString) > 1 ? stringright($sWorking , stringlen($sWorking)) & $sOut & "." & $aString[1] : stringright($sWorking , stringlen($sWorking)) & $sOut
        exitloop
    EndIf
next

return $sOut

EndFunc

 

 

 

 

This one may be the dirtiest kind of clean:   *for prices...anything out to the tenths

;~ $sString = "1000000000.98"
;~ $sString = "10000.00"
;~ $sString = "1987"
msgbox(0, '' , stringreverse(stringregexpreplace(stringreverse($sString) , "(\d\d\d)" , "$1,")))

 

Edited August 29, 2015 by boththose

[mikell]

There is also a regex version by @AZJIO somewhere on the forum.

Yes, this is a typical exercise for regex  
I used it when learning the \G anchor

$sInput = "1234567890.1234"
$sOutput = StringRegExpReplace($sInput, '\G(\d+?)(?=(\d{3})+(\D|$))', '$1,')
MsgBox(0, "", $sInput & @crlf & $sOutput)

 

[guinness]

Is that your version of AZJIO's. If AZJIO's please provide a backlink for attribution.

[mikell]

No, it's not AZJIO's solution (I don't know it and its link), it's another one

[NoizeBit]

Thank you guys for the contributions, I'll try all of them. Thanks again 

[NoizeBit]

There is also a regex version by @AZJIO somewhere on the forum. The thousandth separator is a funny thing, because in some countries a comma (,) represents a decimal character. For example in the UK and USA, 1,000 is one thousand, whereas somewhere else it would be 1.000. Weird isn't it!

Exactly, in my country 1,000.00 would look like 1.000,00 - I'd say annoying at best if you're dealing with currencies all day long 

[Melba23]

NoizeBit,

The function I posted should get that right as it checks for the language settings. All you need to do is set the correct $i_convert_lcid  & $i_current_lcid values and you (should) get the correct separators for that language - certainly worked for me when I tested just now.

M23

[jguinch]

Really nice Mikell !

Another way, with _WinAPI_CreateNumberFormatInfo :

#include <WinAPILocale.au3>

$sInput = "-1234567890.2244"

$sOutput = _WinAPI_CreateNumberFormatInfo ( StringLen( StringRegExpReplace($sInput, "\d+\.?(.*)", "$1")), 0, 3, ".", ",", 1 )
MsgBox(0, "", _WinAPI_GetNumberFormat(0, $sInput,$sOutput ))

 

Edited August 30, 2015 by jguinch

[mikell]

Melba,
"$en" flag = 1 means en notation, 0 means european 

$sInput1 = "1234567890,1234"
$sOutput1 = _StringAddThousandsSep($sInput1, 0)
MsgBox(0, "", $sInput1 & @crlf & $sOutput1)

$sInput2 = "-1234567890.1234"
$sOutput2 = _StringAddThousandsSep($sInput2, 1)
MsgBox(0, "", $sInput2 & @crlf & $sOutput2)

Func _StringAddThousandsSep($s_string, $en)
   Return StringRegExpReplace($s_string, '\G(-?\d+?)(?=(\d{3})+(\D|$))', "$1" & Chr($en*44+(not $en)*46))
     ; or this to avoid error checking on the flag
  ; Return StringRegExpReplace($s_string, '\G(-?\d+?)(?=(\d{3})+(\D|$))', "$1" & (($en = 0) ? "," : "."))
EndFunc

Edit

jguinch, what if there are no decimals ?

Edited August 30, 2015 by mikell

[jguinch]

@Mikell :  edited.
Try yours with a negative number

[mikell]

Last post edited 

[AZJIO]

http://autoit-script.ru/index.php?topic=3814.msg27783#msg27783

[NoizeBit]

NoizeBit,

The function I posted should get that right as it checks for the language settings. All you need to do is set the correct $i_convert_lcid  & $i_current_lcid values and you (should) get the correct separators for that language - certainly worked for me when I tested just now.

M23

Thanks Melba, I'll definitely give it a shot, seems like what I'm looking for.