Autoit total numbers inside notepad file (solved)

[KANlFUSA]

any idea to make an autoit script auto total the numbers inside notepad file and show the result in msgbox?

like' 133+34+55+41+639.3 = msgbox the total amount.

 

 

below is notepad user.txt

-------------------------------------------------------

[user]

133

34

55

41

639.3

 

Input=0

--------------------------------------------------------

Edited August 31, 2015 by KANlFUSA

[Danyfirex]

it is not the best way but should work.

#include <Array.au3>
Local $sData=fileread("user.txt")
$sData=StringMid($sData,1,StringInStr($sData,"Input")) ;just for avoid last number (0) no needed if is 0
Local $aData=StringRegExp($sData,"[-+]?[0-9]*\.?[0-9]+",3)

;~ _ArrayDisplay($aData) array result of numbers

Local $sResult=""
For $i= 0 to UBound($aData)-1
    $sResult&= (($i <> 0) ? "+" : "")  & $aData[$i]

Next

MsgBox(0,"",$sResult & " = " & Execute($sResult))

Saludos

Edited August 22, 2015 by Danyfirex

[CrypticKiwi]

here is another way without using regex...you decide which is better for you

$Handle = FileOpen("user.txt",0)
$Read = FileRead($Handle)
$Counter = 0
$Sum = 0
$Exit = True
$Readline = ""
while $Exit 
$Counter += 1
$ReadLine = FileReadLine("user.txt",$Counter)
if @error <> 0 Then
    $Exit = False
    EndIf
$Sum += $ReadLine
WEnd

MsgBox("","",$Sum)

 

Edited August 22, 2015 by CrypticKiwi
Edit for a better way to detect end of File

[KANlFUSA]

Thank you Danyfirex

&

Thank you CrypticKiwi

 

[iamtheky]

probably edge cases aplenty, but shorter:

#include <Array.au3>
Local $sData=FileRead("user.txt")
Local $aData = StringRegExp($sData , "\n(\d+\.*\d*)" , 3)
msgbox(0, '' , execute(_ArrayToString($aData , "+")))

 

[Malkey]

Length really doesn't matter. But, just in case there's this one.

MsgBox(0, 'Results', Execute(StringRegExpReplace(FileRead("user.txt"), "\D*(\d+\.?\d*)\R*", "\1+") & 0))

 

[jchd]

This is much better in that it adds the first line and allows for various line terminations, but we might as well allow signed values:

MsgBox(0, 'Results', Execute(StringRegExpReplace($sData, "([+-]?\d+\.?\d*)\R*", "\1+") & '0'))

 

[Gianni]

@kanifusa if you want read the numbers directly from the running notepad rather than from a file you can use this snippet

if WinExists("[CLASS:Notepad]", "") then $sData = WinGetText(WinGetHandle("[CLASS:Notepad]", ""))

MsgBox(0, 'Results', Execute(StringRegExpReplace($sData, "([+-]?\d+\.?\d*)\R*", "\1+") & '0')) ; <- this by jchd