_FileWriteLog Not Working İn Function

[KutayAltinoklu]

First Of All Thanks For Helping me.

#include <File.au3>

Local $ErrorFile = FileOpen(@ScriptDir & "\Log\Error.log", 1)

Func logTest()
    _FileWriteLog($ErrorFile, "Test")
EndFunc

Call ("logTest")

 

Edited August 20, 2015 by KutayAltinoklu

[guinness]

1. Don't use call like that, instead use logTest()
2. Don't forget to tidy up your resources using FileClose()
3. Learn how to error check. Did you place a console write underneath _FileWriteLog() with @error?

Anyway it's pretty simply with a bit of thought process. Use $FO_APPEND + $FO_CREATEPATH in FileOpen(), as your path probably doesn't exist. How do I know? Well FileOpen was returning -1. 

[kylomas]

KutayAltinoklu,

_FileWriteLog Not Working İn Function              

is not really describing the problem, just that there is a problem.  When I ran this I get

"Unable to open file = c:\..."

That can be easily fixed using the following code...

#include <File.au3>

Local $ErrorFile = FileOpen(@ScriptDir & "\Log\Error.log", $FO_APPEND + $FO_CREATEPATH)

Func logTest()
    _FileWriteLog($ErrorFile, "Test")
EndFunc



Call ("logTest")

shellexecute(@ScriptDir & "\Log\Error.log")

Note the addition of a parm to the FileOpen function.

While that works, it is not terribly useful to hardcode a value to write in a function.  Lets change it slightly...

1 - add a parm that contains the string to write to the log function

2 - open/close the error file with each call to the function

3 - invoke function directly, not with Call stmt

#include <File.au3>

Func logTest($sLogEntry)
    Local $ErrorFile = FileOpen(@ScriptDir & "\Log\Error.log", $FO_APPEND + $FO_CREATEPATH)
    _FileWriteLog($ErrorFile, $sLogEntry)
    fileclose($ErrorFile)
EndFunc

logtest('My latest entry')
logtest('and another...')

shellexecute(@ScriptDir & "\Log\Error.log")

If any of this does not make sense read about functions in general and the function that you are using in the Help file.

kylomas 

edit: @‌Guinness - While I was trying to get the screen print to work I see you beat me to it...

Edited August 20, 2015 by kylomas
trying to get screen print of error

[guinness]

Or another way is create a logging API that opens the file once and closes at the end e.g.

expandcollapse popup

#include <File.au3>

Global $g_hLogFile = -1

; Close on AutoIt shutdown
OnAutoItExitRegister(Log_Shutdown)

Example()

Func Example()
    ; Start logging
    Log_Startup()

    ; Write to the log file
    For $i = 0 To 1000
        Log_Write($i)
    Next

    ; Stop logging. NOTE: Done automatically due to registering the function at the start for when AutoIt exists
    ; Log_Shutdown()
EndFunc   ;==>Example

; Tidy up our resources. Returns True or False
Func Log_Shutdown()
    If $g_hLogFile <> -1 Then
        Return FileClose($g_hLogFile) > 0
    EndIf

    Return False
EndFunc   ;==>Log_Shutdown

; Start the logging API. Returns True or False
Func Log_Startup()
    $g_hLogFile = FileOpen(@ScriptDir & "\Log\Error.log", BitOR($FO_APPEND, $FO_CREATEPATH))
    Return $g_hLogFile <> -1
EndFunc   ;==>Log_Startup

; Write a log message. Returns True or False
Func Log_Write($sLogEntry)
    If $g_hLogFile == -1 Then Return False

    Local $iReturn = _FileWriteLog($g_hLogFile, $sLogEntry)
    Return SetError(@error, @extended, $iReturn > 0)
EndFunc   ;==>Log_Write

 

[guinness]

I guess the likes mean you're happy with the responses here?

[KutayAltinoklu]

I guess the likes mean you're happy with the responses here?

Yes Thanks For The Help