scripting.dictionary in the role of map

[iamtheky]

I took the long way here but have arrived. I am trying to replicate map functions as I hunt for the most enjoyable way to play with INI style data (which is why the func names are all _map*).  This is by no means complete but it is a working demo.  As always feel free to improve this, and then post that.

UDF

expandcollapse popup

;_MapInit
;_MapAddKeyValuePair
;_MapReassignKey
;_MapAppendToKey
;_MapRemoveKey
;_MapGetValue
;_MapToString
;_MapToArray
;_MapTo2dArray
;_MapFrom2DArray
;_MapToIniSection
;_MapFromIniSection



Func _MapInit()
  Local $map = ObjCreate("Scripting.Dictionary")

    If Not IsObj($map) Then
        Exit MsgBox(0, "Error", "Object not created")
    EndIf

  return $map
EndFunc ;_MapInit



Func _MapAddKeyValuePair($map , $key , $value)
    If $map.Exists($key) Then
        msgbox(0, 'Error' , '"' & $key & '"' & ' already exists with a value of ' & '"' & $map.Item($key) & '"')
    Else
        $map.Add($key, $value)
    EndIf
EndFunc ;_MapAddKeyValuePair



Func _MapReassignKey($map , $key , $value)
    If $map.Exists($key) Then
        $map.remove($key)
        $map.Add($key, $value)
    Else
        $map.Add($key, $value)
    EndIf
EndFunc ;_MapReassignKey



Func _MapAppendToKey($map , $key , $value)
    If $map.Exists($key) Then
        $sCurrent = $map.Item($key)
        $map.remove($key)
        $map.Add($key, $sCurrent & ";" & $value)
    Else
        $map.Add($key, $value)
    EndIf
EndFunc ;_MapAppendToKey



Func _MapRemoveKey($map , $key)
        $map.remove($key)
EndFunc ;_MapRemoveKey



Func _MapGetValue($map , $key)
    return $map.Item($key)
EndFunc ;_MapGetValue



Func _MapToString($map)
    local $sOut = ""

for $key in $map.Keys
     $sOut &= $key & " = " & $map.Item($key) & @LF
Next

return stringreplace($sOut , @LF , "" , -1)
EndFunc ;_MapToString



Func _MapToArray($map)
local $aArray[$map.count]

    $i = 0
    for $key in $map.Keys
            $aArray[$i] = $key & " = " & $map.Item($key)
            $i += 1
    Next

return $aArray
EndFunc ;_MapToArray



Func _MapTo2dArray($map)
local $aArray[$map.count][2]

    $i = 0
    for $key in $map.Keys
        $aArray[$i][0] = $key
        $aArray[$i][1] = $map.Item($key)
        $i += 1
    Next

return $aArray
EndFunc ;_MapTo2dArray



Func _MapToIniSection($map , $section , $filepath , $fSort = 0)
    $aMap = _MapTo2dArray($map)
    _ArrayInsert($aMap , 0 , ubound($aMap) - 1)
    If $fSort = 1 Then _ArraySort($aMap)
    IniWriteSection($filepath , $section , $aMap)
EndFunc ;MapToIniSection



Func _MapFromIniSection($filepath , $section)
    $map = _MapInit()
    $aArray = IniReadSection($filepath , $section)
        for $i = 1 to ubound($aArray) - 1
            $map.add($aArray[$i][0] , $aArray[$i][1])
        Next

return $map
EndFunc



Func _MapFrom2DArray($2Darray)
Local $map = ObjCreate("Scripting.Dictionary")

    If Not IsObj($map) Then
        Exit MsgBox(0, "Error", "Object not created")
    EndIf

    for $i = 0 to ubound($2Darray) - 1
            _MapAddKeyValuePair($map , $2Darray[$i][0] , $2Darray[$i][1])
    Next

return $map
EndFunc ;_MapToArray

 

Example:

expandcollapse popup

#include 'dictmap.au3'
#include<array.au3>

;map initialize - MUST BE FIRST

$myDictionary = _MapInit()

;map add key/value pairs

_MapAddKeyValuePair($myDictionary , "KeyEntry0" , "ValueEntry0")    ; adding key/value pairs
_MapAddKeyValuePair($myDictionary , "KeyEntry1" , "ValueEntry1")
_MapAddKeyValuePair($myDictionary , "KeyEntry2" , "ValueEntry2")
_MapAddKeyValuePair($myDictionary , "KeyEntry3" , "ValueEntry3")
_MapAddKeyValuePair($myDictionary , "KeyEntry4" , "ValueEntry4")
_MapAddKeyValuePair($myDictionary , "KeyEntry5" , "ValueEntry5")

;map get value of key

msgbox(0, "Value of KeyEntry1" , _MapGetValue($myDictionary , "KeyEntry1"))  ;see single value

;map add duplicate failure

_MapAddKeyValuePair($myDictionary , "KeyEntry1" , "ValueEntry1_replaced")  ;duplicate test

;map reassign key

_MapReassignKey($myDictionary , "KeyEntry1" , "ValueEntry1_replaced")  ;Key exists so Reassign the value
msgbox(0, "Value of reassigned KeyEntry1" , _MapGetValue($myDictionary , "KeyEntry1"))  ;see changed entry

;map append to key

_MapAppendToKey($myDictionary , "KeyEntry4" , "ValueEntry4_append")  ; append stuff to keyentry4

;map remove key

_MapRemoveKey($myDictionary , "KeyEntry0")  ; remove key 0

;map to string

msgbox(0, 'Map String - No Sort' , _MapToString($myDictionary))  ;entire Map To string

;map to array

$aMyDictionary = _MapToArray($myDictionary)    ;Entire Map To Array
_ArraySort($aMyDictionary)
_ArrayDisplay($aMyDictionary , "1D Sorted")

;Map to 2D array

$a2DmyDictionary = _MapTo2dArray($myDictionary)    ;Entire Map To 2D Array
_ArraySort($a2DmyDictionary)
_ArrayDisplay($a2DmyDictionary , "2D Sorted")

;map from array

$MapFrom2D = _MapFrom2DArray($a2DmyDictionary)
for $key in $MapFrom2D.keys
   msgbox(0, 'MapFromArray' , $key & @LF & $MapFrom2D.item($key))
Next

;map to ini

_MapToIniSection($myDictionary , "TEST_SECTION_01_Unsorted" , @ScriptDir & "\TEST_SECTION.ini") ;unsorted
_MapToIniSection($myDictionary , "TEST_SECTION_02_Sorted" , @ScriptDir & "\TEST_SECTION.ini" , 1) ;sorted
ShellExecute(@ScriptDir & "\TEST_SECTION.ini")

;map from ini

$MapFromIni = _MapFromIniSection( @ScriptDir & "\TEST_SECTION.ini" , "TEST_SECTION_01_Unsorted")
$aMapFromIni = _MapToArray($MapFromIni)    ;Entire Map To Array
_ArraySort($aMapFromIni)
_ArrayDisplay($aMapFromIni , "from INI")

 

Edited September 21, 2015 by boththose

[guinness]

Use ByRef like I did, just to explicitly state that pass by reference and not value.

[iamtheky]

I just want to be careful to only use it when it is most useful.   I think it does a disservice in funcs like _ArrayDisplay.  Are there any 'best practices' on ByRef usage you would recommend?

Edited August 17, 2015 by boththose

[guinness]

What makes you say that? It's used in _ArrayDisplay() because even though arrays are copy-on-write, by using ByRef, if _ArrayDisplay() was to change an element in the array, then the whole array wouldn't be copied i.e. less memory. Objects are passed around using references in most languages I know, but as AutoIt can be a little mysterious to some, it's good to state that this is a reference and not straight value copy, even though they both reference the same block of memory.

[iamtheky]

What makes you say that?

because I pretty much use it for debug, and being able to oneline it with functions that return arrays would be super.  e.g. _ArrayDisplay(stringsplit())

if _ArrayDisplay() was to change an element in the array, then the whole array wouldn't be copied

How can array display change an element?

[JohnOne]

I would infer that transpose flag changes the array. If that is not the case then I would then suggest the help file description of that flag be corrected.

[jchd]

_ArrayDisplay was just an example.

Note that not all variables or expressions can be passed ByRef:

_Disp("abcdef")
_Disp("abc" & "def")
_Disp("abc" & StringUpper("def"))
_Disp(StringUpper("def"))
_Disp(1+2+3*(4+5+6)/2)

; but
$t = DllStructCreate("short int16;byte octet[3];ulong large")
$t.large = 456
ConsoleWrite(VarGetType($t.large) & @LF)
_Disp($t.large)

Func _Disp(ByRef $s)
    ConsoleWrite($s & @LF)
EndFunc

 

[guinness]

What happens if you disable Au3Check?

[jchd]

It is disabled but it doesn't cough when enabled.

[guinness]

Now I managed to run the example and see what you mean. Interesting stuff, though guess it's to be expected!

@jchd, is correct @boththose, it was just an example and not suggesting in anyway that _ArrayDisplay() would mess with the array. I was merely pointing out the purposes of ByRef and when it's good to use it.

[iamtheky]

So if I dont use ByRef with autoit, do I always take the copy penalty?  Or is the way I am doing my add, reassigns, and appends just poor form (because I am not returning anything, just modifying the passed map without ByRef)?

[guinness]

Well this is an object, so the variable holds a reference value and not an object. But it would be good practice in terms of readability to show that a reference to a map object is being passed around. As I said, up to you, but it's something I would do of course.

[iamtheky]

*Updated the original with a couple of functions to move between INI and dictionary

Edited August 21, 2015 by boththose

[Zedna]

Very nice!

1) Make it as UDF (#include <map.au3>)

2) Add opposite functions to _MapToArray(),_MapTo2dArray(): _MapFromArray(),_MapFrom2dArray()

Edited September 18, 2015 by Zedna

[iamtheky]

Thanks.  And for sure number 2, I learned a bit building these forward, have to imagine I can only learn more building their opposites.

I admittedly have never built a proper a UDF, but will certainly take a stab at the formatting (and probably have to build some error checking).

 

[Zedna]

As a start just make it as UDF without formatting/docs/error checking.

As UDF it's very easy to use.

[iamtheky]

Separated examples from user functions, and added MapFrom2DArray.  I went with dictmap for the name: not only is it a fine amalgamation, it homophonically explains what is going on

[Zedna]

[iamtheky]

So you can store arrays in dictionaries....so there can be lots of rewriting.

#include 'dictmap.au3'
#include<array.au3>

;map initialize - MUST BE FIRST

$myDictionary = _MapInit()

;map add key/value pairs

_MapAddKeyValuePair($myDictionary , "KeyEntry0" , "ValueEntry0")    ; adding key/value pairs
_MapAddKeyValuePair($myDictionary , "KeyEntry1" , "ValueEntry1")
_MapAddKeyValuePair($myDictionary , "KeyEntry2" , "ValueEntry2")


local $aTestarray[2]
      $aTestarray[0] = "ValueEntry3-1"
      $aTestarray[1] = "ValueEntry3-2"

_MapAddKeyValuePair($myDictionary , "KeyEntry3" , $aTestarray)

For $value in $myDictionary.Item("KeyEntry3")
    consolewrite($value & @LF)
Next

 

[LarsJ]

Is the entire array stored or just the pointer/reference? Copy or ByRef?