How allowing the moving of a window only within another window?

[Gianni]

If I have a Main Windows and 2 child windows, all those 3 windows can be freely moved on the screen.
Is there a way (some Style or ExStyle ?) to limit the moving of the 2 childs only within the boundaries of the client area of the main window??
Thanks for any suggestion

$hGUI = GUICreate('Main GUI', 500, 500,50,50)

$hGUI_Child1 = GUICreate('#1', 150, 100,80,100,-1,-1,$hGUI)
$hGUI_Child2 = GUICreate('#2', 150, 100,280,100,-1,-1,$hGUI)
GUISetState(@SW_SHOW, $hGUI)
GUISetState(@SW_SHOW, $hGUI_Child1)
GUISetState(@SW_SHOW, $hGUI_Child2)
MsgBox(0,0,"Pause")

 

Edited August 2, 2015 by Chimp

[JohnOne]

GUIRegisterMsg ( $WM_MOVE, "_WM_MOVE" )

Check position of child

If it is at a boundary of parent, move it back.

[mikell]

?

#include <WindowsConstants.au3>
$hGUI = GUICreate('Main GUI', 300, 300, 300)

$hGUI_Child = GUICreate('#2', 150, 100,100,100,BitOr($WS_CHILD,$WS_BORDER),-1,$hGUI)
GUISetBkColor(0xffffff)
GUISetState(@SW_SHOW, $hGUI)
GUISetState(@SW_SHOW, $hGUI_Child)

GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")

MsgBox(0,0,"Pause")

Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
  if ($hWnd = $hGUI_Child) and ($iMsg = $WM_NCHITTEST) then Return $HTCAPTION
EndFunc

 

[Melba23]

Chimp,

Perhaps this?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Global $ahChild[1][2] = [[0, False]], $SC_MOVE = 0xF010

$hGUI = GUICreate("Parent Window", 633, 447, 192, 200)
GUICtrlCreateLabel("", 0, 0, 0, 0)
$mMain = GUICtrlCreateMenu("New")
$mChild = GUICtrlCreateMenuItem("Child", $mMain)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_SYSCOMMAND, "_WM_SYSCOMMAND")

While 1
    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $hGUI ; Main GUI
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $mChild

                    $hChild = _CreateMDIChild($hGUI)
            EndSwitch

        Case Else
            $hChild = _CheckMDIChildren($aMsg)
    EndSwitch

WEnd



Func _CreateMDIChild($hParent)
    ; Create child
    Local $hChild = GUICreate("Child " & $ahChild[0][0] + 1, 300, 300, 10, 0, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX, $WS_SIZEBOX))
    ; Set parent
    _WinAPI_SetParent($hChild, $hParent)
    ; Increase counter
    $ahChild[0][0] += 1
    ; Increase array size
    ReDim $ahChild[$ahChild[0][0] + 1][2]
    ; Set values
    $ahChild[$ahChild[0][0]][0] = $hChild

    $ahChild[$ahChild[0][0]][1] = False
    ; Show child
    GUISetState()
    Return $hChild

EndFunc   ;==>CreateChild



Func _CheckMDIChildren($aMsg)

    Local $fRet = False

    For $i = 1 To $ahChild[0][0]
        If $aMsg[1] = $ahChild[$i][0] Then
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    GUIDelete($ahChild[$i][0])
                    $ahChild[$i][1] = False
                Case $GUI_EVENT_MAXIMIZE
                    $ahChild[$i][1] = True
                    $ahChild[0][1] = True
                Case $GUI_EVENT_RESTORE
                    $ahChild[$i][1] = False
                    $ahChild[0][1] = False
            EndSwitch

            $fRet = True
        EndIf

    Next
    Return $fRet

EndFunc



Func _WM_SYSCOMMAND($hWnd, $Msg, $wParam, $lParam)

    If $ahChild[0][1] = True Then
        For $i = 1 To $ahChild[0][0]
            If $ahChild[$i][1] Then
                If $hWnd = $ahChild[$i][0] Then
                    If BitAND($wParam, 0xFFF0) = $SC_MOVE Then Return False
                    ExitLoop

                EndIf

            EndIf

        Next
    EndIf

    Return $GUI_RUNDEFMSG
EndFunc   ;==>On_WM_SYSCOMMAND

The WM_SYSCOMMAND handler just prevents the maximized child being moved.

M23

[Gianni]

many thanks for the excellent examples
Now I have good material with which to work.
thanks again to all

[mikell]

Got it finally 

Credits to Lazycat for the idea

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate('Main GUI', 300, 300, 300, 300)
$hGUI_Child = GUICreate('#2', 150, 100,100,100,-1,BitOr($WS_EX_MDICHILD,$WS_EX_TOPMOST),$hGUI)
GUISetBkColor(0xffffff)
GUISetState(@SW_SHOW, $hGUI)
GUISetState(@SW_SHOW, $hGUI_Child)

GUIRegisterMsg($WM_WINDOWPOSCHANGING, "MY_WM_WINDOWPOSCHANGING")
Global $nGap = 10, $size = WinGetClientSize($hGUI)

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd


Func MY_WM_WINDOWPOSCHANGING($hWnd, $Msg, $wParam, $lParam)
   If $hWnd = $hGUI_Child Then
     Local $pos = WinGetPos($hGUI)
     Local $stWinPos = DllStructCreate("uint;uint;int;int;int;int;uint", $lParam)
     Local $border = ($pos[2] - $size[1]) ;/ 2
     Local $nLeft   = $pos[0] + $border
     Local $nTop = $pos[1] + $pos[3] - $size[1] - $border
     Local $nRight  = $pos[0] + $pos[2] - $border - DllStructGetData($stWinPos, 5)
     Local $nBottom = $pos[1] + $pos[3] - $border  - DllStructGetData($stWinPos, 6)
     Local $wLeft = DllStructGetData($stWinPos, 3)
     Local $wTop = DllStructGetData($stWinPos, 4)
     If $wLeft < $nLeft Or Abs($nLeft - $wLeft) < $nGap Then DllStructSetData($stWinPos, 3, $nLeft)
     If $wTop < $nTop Or Abs($nTop - $wTop) < $nGap Then DllStructSetData($stWinPos, 4, $nTop)
     If $wLeft > $nRight Or Abs($nRight - $wLeft) < $nGap Then DllStructSetData($stWinPos, 3, $nRight)
     If $wTop > $nBottom Or Abs($nBottom - $wTop) < $nGap Then DllStructSetData($stWinPos, 4, $nBottom)
  EndIf
  Return 'GUI_RUNDEFMSG'
EndFunc

 

Edited August 2, 2015 by mikell

[Gianni]

@mikell thanks for this additional effect,
The effect from the nice example of @Melba23 (thanks melba) was exactly what I had in mind, however, even this more restrictive constraint on moving of child windows may come in handy. Thanks

Edited August 3, 2015 by Chimp

[guinness]

@mikell, $tagWINDOWPOS is already used in AutoIt and uses named indexes.

[mikell]

guinness,
You're right, the culprit is my laziness which let me use the code from Lazycat (2006 !) as is 

[guinness]

A lot has changed in 9 years!

[mikell]

... but sometimes old recipes keep on being efficient 

[guinness]

I need more convincing I'm afraid. It's only in the last 5 years or so that AutoIt has move towards a proper programming language.

[mikell]

This old Lazycat's code uses basic includes, litteral struct and DllStruct* funcs which didn't change for ages
These are particular (I agree with that) circumstances where an old script should still work, why shouldn't it not ?

[guinness]

Because MSDN docs are constantly changing the structures as their OS' evolve. Lazycat's structure doesn't change with the time, where as the UDF one does. I know which one I would rather put my money with my application working with future versions of Windows.