_FileWriteToLine problem

[compact21]

Hello guys, i'm runing into a problem using _FileWriteToLine function.

I want to write something on line 12 of this test file but it wont work until i already have the file written up to line 12 so i can replace or add some strings to that line.

Any ideea how could i write to a specific line on a new (blank) text file?

#include <File.au3>
_FileWriteToLine(@ScriptDir & "\test file.txt", 12, "something to write", 1)

 

test file.txt

Edited July 19, 2015 by compact21

[Jos]

Check that there are enough lines with _FileCountLines() and append enough @CRLF to the file first?

Jos

[guinness]

This isn't a bug, it's a feature request. I will refactor the code and post here for test.

[guinness]

expandcollapse popup

#include <Array.au3>
#include <FileConstants.au3>

_FileWriteToLine_Mod(@ScriptDir & "\Example_FileWriteToLineMod.txt", 16, "Data", True)
MsgBox($MB_SYSTEMMODAL, '', @error)

Func _FileWriteToLine_Mod($sFilePath, $iLine, $sText, $bOverWrite = False)
    If $iLine <= 0 Then Return SetError(4, 0, 0)
    If Not IsString($sText) Then
        $sText = String($sText)
        If $sText = "" Then Return SetError(6, 0, 0)
    EndIf
    If $bOverWrite = Default Then $bOverWrite = False
    If Not (IsBool($bOverWrite) Or $bOverWrite = 0 Or $bOverWrite = 1) Then Return SetError(5, 0, 0) ; For old versions.
    If Not FileExists($sFilePath) Then Return SetError(2, 0, 0)

    Local $aArray = FileReadToArray($sFilePath)
    Local $iUBound = UBound($aArray) - 1

    If $iUBound = -1 Then
        Dim $aArray[1] ; Dim is required to set the return value of FileReadToArray() as an array.
    EndIf

    ; If $iUBound < $iLine Then Return SetError(1, 0, 0)
    If $iUBound < $iLine Then
        ; Redim the array to a new size, so the line number can be written to.
        ReDim $aArray[$iLine]
        $iUBound = $iLine
    EndIf

    Local $hFileOpen = FileOpen($sFilePath, FileGetEncoding($sFilePath) + $FO_OVERWRITE)
    If $hFileOpen = -1 Then Return SetError(3, 0, 0)

    ; As the array is 0-based, reduce the line number by 1.
    $iUBound -= 1
    $iLine -= 1

    ; Set to the specific line.
    $aArray[$iLine] = ($bOverWrite ? $sText : $aArray[$iLine] & @CRLF & $sText) & @CRLF

    ; Loop through the data and concatenate.
    Local $sData = ""
    For $i = 0 To $iUBound
        $sData &= $aArray[$i] & @CRLF
    Next
    $sData = StringTrimRight($sData, StringLen(@CRLF) * 2) ; Required to strip trailing EOL

    FileWrite($hFileOpen, $sData)
    FileClose($hFileOpen)
    Return 1
EndFunc   ;==>_FileWriteToLine_Mod

I am in doubt people will want this in the library. If they do then make a feature request in the bug tracker.

Edited July 19, 2015 by guinness

[Jos]

Don't think anything is wrong in the existing UDF as it does return 0 and sets the @error when the requested line doesn't exists.

#include <File.au3>
$rc = _FileWriteToLine(@ScriptDir & "\test.txt", 12, "something to write", 1)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $rc = ' & $rc & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console

Jos

[guinness]

I know, I added the feature to the code above for @compact21.

[compact21]

I know, I added the feature to the code above for @compact21.

thanks. i never said it is a bug, i should probably have said "i have a problem with _FileWriteToLine.

I solved it by adding @CRLF like Jos said.

[guinness]

OH well.