ObjEvent() - return value - question

[mLipok]

HelpFile says:

"If the second parameter is omitted, it will return the name of the current Error handler function or function, depending what was used when registering."

I do not quite understand the difference.
Can somebody make an simple example of one and second cases, to show the differences ?

 

[trancexx]

If you use string format when registering a handler, you will get result as string. If you pass function when registering, you will get result as that function. Latter probably confuses you. Here's an example of that case:

; Register COM Error Handler
$oErrorHandler = ObjEvent("AutoIt.Error", Abcd)
Func Abcd()
    ConsoleWrite("Error Handler Invoked" & @CRLF)
EndFunc



; Some Object which is not
$oNonObject = Null
; Call method to invoke error handler
$oNonObject.DummyCall()

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Get the function that was used for registering
$vTheErrorFunction = ObjEvent("AutoIt.Error")

; Invoke it manually
$vTheErrorFunction()
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

...You should get two lines of "Error Handler Invoked" printed as the result of that snippet.

[mLipok]

I think now It is clear to me.
I will check later when I back home.

 

[Melba23]

mLipok & trancexx,

Would you both be happy with this amended wording:

If the second parameter is omitted, the function return will depend on the method used to register the function initially: if registered using a string containing the function name, it returns that string - if registered with the function as an object, it returns that object.

M23

Edited July 18, 2015 by Melba23
Typo

[mLipok]

the function as an object, it returns that object

?

Please wait few hours.

I be able to do some reasearch and then I be able to answer.

 

[Melba23]

mLipok,

I have done the research - that is indeed what happens as shown in this expanded version of trancexx's example:

expandcollapse popup

$oErrorHandler = ObjEvent("AutoIt.Error", Abcd)
; Some Object which is not
$oNonObject = Null
; Call method to invoke error handler
$oNonObject.DummyCall()
; Get the function that was used for registering
$vTheErrorFunction = ObjEvent("AutoIt.Error")
; Nothing to ConsoleWrite

ConsoleWrite("=" & $vTheErrorFunction & @CRLF)
; Invoke it manually
$vTheErrorFunction()

ConsoleWrite(@CRLF)

; Register COM Error Handler with string name
$oErrorHandler = ObjEvent("AutoIt.Error", "Wxyz")
; Some Object which is not
$oNonObject = Null
; Call method to invoke error handler
$oNonObject.DummyCall()
; Get the function that was used for registering
$vTheErrorFunction = ObjEvent("AutoIt.Error")
; Returns the string
ConsoleWrite("=" & $vTheErrorFunction & @CRLF)
; Error
$vTheErrorFunction()

Func Abcd()
    ConsoleWrite("Abcd Error Handler Invoked" & @CRLF)
EndFunc



Func Wxyz()
    ConsoleWrite("Wxyz Error Handler Invoked" & @CRLF)
EndFunc

Once you are happy with what happens, please let me know if the suggested text is clear enough.

M23

[mLipok]

ok btw. I'm going to fulfill the obligations paternal (fun, reading, lulling 6 year old son)

[Melba23]

mLipok,

Enjoy that time - it passes far too quickly.

M23

[mLipok]

First I want to introduce my modified version, which shows more precisly whats going on (at least for me):

expandcollapse popup

ConsoleWrite(@CRLF & ">TEST1:" & @CRLF)
$oErrorHandler = ObjEvent("AutoIt.Error", Abcd)
; Some Object which is not
$oNonObject = Null
; Call method to invoke error handler
$oNonObject.DummyCall()
; Get the function that was used for registering
$vTheErrorFunction = ObjEvent("AutoIt.Error")
; Nothing to ConsoleWrite

ConsoleWrite("$vTheErrorFunction=" & $vTheErrorFunction & @CRLF)
ConsoleWrite("VarGetType($vTheErrorFunction)=" & VarGetType($vTheErrorFunction) & @CRLF)

ConsoleWrite(@CRLF & ">TEST2:" & @CRLF)
; Invoke it manually
$vTheErrorFunction()

ConsoleWrite(@CRLF & ">TEST3:" & @CRLF)
; Register COM Error Handler with string name
$oErrorHandler = ObjEvent("AutoIt.Error", "Wxyz")
; Some Object which is not
$oNonObject = Null
; Call method to invoke error handler
$oNonObject.DummyCall()
; Get the function that was used for registering
$vTheErrorFunction = ObjEvent("AutoIt.Error")
; Returns the string
ConsoleWrite("$vTheErrorFunction=" & $vTheErrorFunction & @CRLF)
ConsoleWrite("VarGetType($vTheErrorFunction)=" & VarGetType($vTheErrorFunction) & @CRLF)

ConsoleWrite(@CRLF & ">TEST4:" & @CRLF)
; Error
$vTheErrorFunction()

; This following line never happens, as one script line above fires the error.
ConsoleWrite(">END:" & @CRLF)
EXIT

Func Abcd()
    ConsoleWrite("Abcd Error Handler Invoked" & @CRLF)
EndFunc

Func Wxyz()
    ConsoleWrite("Wxyz Error Handler Invoked" & @CRLF)
EndFunc

 

and now answering to your posts: 

mLipok & trancexx,

Would you both be happy with this amended wording:

If the second parameter is omitted, the function return will depend on the method used to register the function initially: if registered using a string containing the function name, it returns that string - if registered with the function as an object, it returns that object.

M23

I would like to propose, a little modified description:

"
If the second parameter is omitted, the function return will depend on the method used to register the function initially: if registered using a string containing the function name, it returns that string (function name) - if registered with the function as an object, it returns that function (first class object).
"

Exactly with this desired link.

EDIT: btw: I would also propose to add this example script to HelpFile.

Edited July 18, 2015 by mLipok

[mLipok]

@Melba23

Any decision ?

 

[mLipok]

I have further questions:

in first example

https://www.autoitscript.com/autoit3/docs/functions/ObjEvent.htm

; Custom sink object
    Local $oIEEvents = ObjEvent($oIE, "_IEEvent_", "DWebBrowserEvents2")

is declared as local.

 

and here:

https://www.autoitscript.com/autoit3/docs/intro/ComRef.htm

........
Local $oEventObject = ObjEvent($oIE, "IEEvent_", "DWebBrowserEvents") ; Start receiving Events.
........
$oEventObject.stop ; Tell IE we want to stop receiving Events
$oEventObject = 0 ; Kill the Event Object
........

Question 1:

$oEventObject.stop

Whether this stop method is specific to IE or specific to AutoIt ? Edit: but maybe it is a COM Feature - if so, can anybody point me to MSDN ?

 

btw. 

Wait few minutes I make an example .....

EDIT: 

after testing example is not needed, only the question is interesting.

Edited September 11, 2015 by mLipok

[trancexx]

It's internal AutoIt thing. These objects have the method on top of interface description for internal handling. Stop() is currently the only one defined.

It has nothing to do with IE, Microsoft or whatever.

[mLipok]

So this should be better documented in HelpFile .
I will do a track ticket but before must change the example of ObjEvent.

Thanks.

mLipok