FileReadLine condition

[mycloutier]

Looking on some advice on how to tackle this issue!

I have a text file that is generated from another program. My goal is to write a script that would read each line in the text file and set a variable if a certain expression is found.

For example let's say the text file contains the following 4 lines of text :

Intel(R) Active Management Technology - SOL (COM4)
Communications Port (COM1)
Standard Serial over Bluetooth link (COM7)
Standard Serial over Bluetooth link (COM6)

I need to search for the following expression "Standard Serial over Bluetooth link" and associate the corresponding COM as a variable ... in this case there are 2 ... either COM6 or COM7.

This is the code I have so far :

#include "UIAWrappers.au3"
#include <MsgBoxConstants.au3>
#include <File.au3>
#include <FileConstants.au3>

Call("COMPorts")

Func COMPorts()

$file = "C:\GunTSTool\ports.txt"
FileOpen($file, 0)

For $i = 1 to _FileCountLines($file)
    $line = FileReadLine($file, $i)
If $line = "Standard Serial over Bluetooth link" Then
    msgbox(0,'','' & '' & $line)
ElseIf $line = "Prolific USB Cable" Then
    msgbox(0,'','' & '' & $line)
ElseIf $line = "Prolific USB to serial Cable" Then
    msgbox(0,'','' & '' & $line)
EndIf
Next
FileClose($file)

EndFunc

My main issue here is that the COM number will be changing all the time, I need to search only the text before the COM ... 

 

Any ideas?

 

Marty

[BrewManNH]

StringInStr would help.

#include <MsgBoxConstants.au3>
#include <File.au3>
#include <FileConstants.au3>

COMPorts()

Func COMPorts()

    $file = "C:\GunTSTool\ports.txt"
    $hFile = FileOpen($file)
    While 1
        $line = FileReadLine($hFile)
        If @error Then ExitLoop
        Select
            Case StringInStr($line, "Standard Serial over Bluetooth link")
                MsgBox($MB_SYSTEMMODAL, '', '' & '' & $line)
            Case StringInStr($line, "Prolific USB Cable")
                MsgBox($MB_SYSTEMMODAL, '', '' & '' & $line)
            Case StringInStr($line, "Prolific USB to serial Cable")
                MsgBox($MB_SYSTEMMODAL, '', '' & '' & $line)
        EndSelect
    WEnd
    FileClose($hFile)

EndFunc   ;==>COMPorts

 

[mikell]

?

#Include <Array.au3>

$txt = FileRead("ports.txt")
$exp = "Standard Serial over Bluetooth link"

$res = StringRegExp($txt, '(?m)^.*' & $exp & '.*COM(\d+)', 3)

_ArrayDisplay($res)

 

[Danyfirex]

my Try. Just for fun.

 

#Include <Array.au3>

Local $aData= FileReadToArray("1.txt")
Local $Find = "Standard Serial over Bluetooth link"


Local $NewArray[0]

For $i=0 to UBound($aData)-1
    If StringInStr($aData[$i],$Find) Then
        ReDim $NewArray[UBound($NewArray)+1]
        $NewArray[UBound($NewArray)-1]=Number(StringMid($aData[$i],StringInStr($aData[$i],"COM")+3))
    EndIf

Next

_ArrayDisplay($NewArray)

Saludos

[mycloutier]

Thank you for all the replies. I have better idea on how to go about this ...

@‌mikell and @‌ Danyfirex both your example works as long as we are searching for "Standard Serial over Bluetooth link". I will be searching for more than one possibility...

‌@mikell with your example if I use this line of code for example, I will get a return on the array, however only getting the appropriate com number for the first option search string

$exp = "Prolific USB|Standard Serial over Bluetooth link"

‌@Danyfirex with your example I cannot get a return if I try to use more than one search string ...

Local $Find = "Prolific USB|Standard Serial over Bluetooth link"

I appreciate all the help! Thank you! :-)
 

[Danyfirex]

the main one. is not so much dinamic as mikell one. 

but. if 

Prolific USB|Standard Serial over Bluetooth link

Exist exactry same in the file. it should work.

Saludos

[guinness]

You can now use @extended instead of UBound()

Local $aArray = FileReadToArray('Filepath')
For $i  = 0 To @extended - 1
    ; ...
Next

Documentation has been updated by the way, as I noticed an example didn't exist showcasing this.

[JohnOne]

#include <String.au3>
#include <Array.au3>

$SearchString = "Standard Serial over Bluetooth link"

$SearchString &= " ("

$str = FileRead("whatever.txt")

$aPorts = _StringBetween($str, $SearchString, ")")

_ArrayDisplay($aPorts)

 

Edited July 19, 2015 by JohnOne

[mikell]

OK, using this text from your 1st post :

Intel(R) Active Management Technology - SOL (COM4)
Communications Port (COM1)
Standard Serial over Bluetooth link (COM7)
Standard Serial over Bluetooth link (COM6)

This works

#Include <Array.au3>

$txt = FileRead("ports.txt")
$exp = "Communications Port|Standard Serial over Bluetooth link"

$res = StringRegExp($txt, '(?m)^.*(?:' & $exp & ').*COM(\d+)', 3)

_ArrayDisplay($res)

Edit
To get also the name of the concerned port in the array just remove " ?: "  in the pattern

Edited July 19, 2015 by mikell