GUICtrlCreateList item to update from the top instead of below

[AaronOoi]

Hi,

 

I followed the AutoIT Help guideline for GUICtrlCreateList. When i clicked at the "Add" button, it will update the list to the 3rd line and if i continue to add, it will add to 4th and 5th line, if this going further, the data will be not shown as it keep getting down to the list. I want the data to update from the top always so that the updated data is always from the first line while the rest will keeps going down. Here is an example of the scripts:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <EditConstants.au3>
#include <ComboConstants.au3>

Example()

Func Example()
  Local $sMESSAGE = "The following buttons have been clicked"

  GUICreate("My GUI list") ; will create a dialog box that when displayed is centered

  Local $idAdd = GUICtrlCreateButton("Add", 64, 32, 75, 25)
  Local $idClear = GUICtrlCreateButton("Clear", 64, 72, 75, 25)
  Local $idMylist = GUICtrlCreateList("buttons that have been clicked", 176, 32, 121, 97,$CBS_AUTOHSCROLL)
  GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
  GUICtrlSetData(-1, $sMESSAGE)
  Local $idClose = GUICtrlCreateButton("my closing button", 64, 160, 175, 25)

  GUISetState(@SW_SHOW)

  ; Loop until the user exits.
  While 1
    Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE
        ExitLoop
      Case $idAdd
        GUICtrlSetData($idMylist, "You clicked button No1|")
      Case $idClear
        GUICtrlSetData($idMylist, "")
      Case $idClose
        MsgBox($MB_SYSTEMMODAL, "", "the closing button has been clicked", 2)
        Exit
    EndSwitch
  WEnd
EndFunc   ;==>Example

 

 

 

 

Edited July 15, 2015 by AaronOoi

[BrewManNH]

This should do what you want.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <EditConstants.au3>
#include <ComboConstants.au3>
#include <GUIListbox.au3> ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

Example()

Func Example()
    Local $sMESSAGE = "The following buttons have been clicked"

    GUICreate("My GUI list") ; will create a dialog box that when displayed is centered

    Local $idAdd = GUICtrlCreateButton("Add", 64, 32, 75, 25)
    Local $idClear = GUICtrlCreateButton("Clear", 64, 72, 75, 25)
    Local $idMylist = GUICtrlCreateList("buttons that have been clicked", 176, 32, 121, 97, $CBS_AUTOHSCROLL)
    GUICtrlSetLimit(-1, 200) ; to limit horizontal scrolling
    GUICtrlSetData(-1, $sMESSAGE)
    Local $idClose = GUICtrlCreateButton("my closing button", 64, 160, 175, 25)

    GUISetState(@SW_SHOW)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idAdd
;~        GUICtrlSetData($idMylist, "You clicked button No1|")
                _GUICtrlListBox_InsertString($idMylist, "You clicked button No1|", 0) ; <<<<<<<<<<<<<<<<<<<<<
            Case $idClear
                GUICtrlSetData($idMylist, "")
            Case $idClose
                MsgBox($MB_SYSTEMMODAL, "", "the closing button has been clicked", 2)
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Example