An example of protecting a variable(s) that should be global throughout the application

[guinness]

An example (or one variation at least) that I created in a discussion we (devs/mods) were having about protecting global variables.

expandcollapse popup

; An enumeration for the getters and setters, as I hate having to write zero and one
Global Enum $VERSION_WRAPPER_GET, $VERSION_WRAPPER_SET

; Unused, as I have hidden behind functions, so users who might feel the need to do this $g_iVersion = 'Haha, I''m no a number', can't!
; Global $g_iVersion = 0

; Basically this is encapsulation and is just one of many principals found in Object Oriented Programming (OOP)

; NOTE: There is no way for me to access the "global" version variable without using the _Get/Set_Version() function(s)

Example()

Func Example()
    ; Set to 10, as only integer datatypes are allowed
    _Set_Version(10)

    ; Displays 10
    ConsoleWrite('1. ' & _Get_Version() & @CRLF)

    ; Set to a non-digit. Such a bad user/dev!
    _Set_Version('Not a number')

    ; Displays 10, as a string was passed previously that wasn't valid
    ConsoleWrite('2. ' & _Get_Version() & @CRLF)

    ; Call another function to show that it's not just visible within this function
    Another_Func()

    ; Displays 99, which was previously set in the Another_Func()
    ConsoleWrite('4. ' & _Get_Version() & @CRLF)

    ; If the variable located in __Version_Wrapper() was purely a global variable, then anything could be assigned to it
    ; without proper checking. As you can see below, the variable is only assigned to when certain criteria is met

    ; Before someone mentions performance, you have to weigh up the pros and cons of such a design choice. If you really need data to be protected
    ; from your users mingling with it, then this is one of many correct approaches to encapsulate data. Otherwise if you're not concerened, then
    ; maybe it's not for you. You're the developer when it comes down to it
EndFunc   ;==>Example

Func Another_Func()
    ; Displays 10
    ConsoleWrite('3. ' & _Get_Version() & @CRLF)

    ; Set to 99 and return back to the previous function i.e. Example()
    _Set_Version(99)
EndFunc   ;==>Another_Func

; Getter
Func _Get_Version()
    Return __Version_Wrapper($VERSION_WRAPPER_GET)
EndFunc   ;==>_Get_Version

; Setter
Func _Set_Version($iVersion)
    Return __Version_Wrapper($VERSION_WRAPPER_SET, $iVersion)
EndFunc   ;==>_Set_Version

; This is a wrapper for the local static variable that will be visible only in the function and for the duration of the application's
; lifecycle

; $iType: Either $VERSION_WRAPPER_GET or $VERSION_WRAPPER_SET
; $iVersion: Used when the type is $VERSION_WRAPPER_SET
Func __Version_Wrapper($iType, $iVersion = Null)
    ; Create a local static variable and initialise to 0
    Local Static $s_iVersion = 0

    Switch $iType
        Case $VERSION_WRAPPER_GET ; Getter
            Return $s_iVersion

        Case $VERSION_WRAPPER_SET ; Setter
            ; Now is the chance to check if the value meets certain criteria e.g. [0-9]+ and not a string datatype
            If StringRegExp($iVersion, '^\d+$') And Not IsString($iVersion) Then
                $s_iVersion = $iVersion
            EndIf

    EndSwitch

    ; Return null by default, especially if the type is as a setter
    Return Null
EndFunc   ;==>__Version_Wrapper

 

Edited July 14, 2015 by guinness

[mLipok]

Oh yes, I do so for a year.

Good example.

 

[guinness]

Oh yes, I do so for a year.

Good example.

 

Excellent news

[guinness]

This example is using a local static datastore i.e. having more than one variable doesn't require multiple static variables, just one is suffice. You will also notice I've excluded the ability to set the version of the application. Which of course can't be done if this was a global variable!

expandcollapse popup

; An enumeration for the getters and setters, as I hate having to write zero and one
Global Enum Step * 2 $APP_GETTER, $APP_SETTER

; An enumeration for the different settings
Global Enum $APP_SETTINGS_ISFIRSTRUN, $APP_SETTINGS_NAME, $APP_SETTINGS_VERSION, $APP_SETTINGS_MAX

Example()

Func Example()

    ; Displays myAppName
    ConsoleWrite('1. ' & _Get_Name() & @CRLF)

    ; Set to a new name
    _Set_Name('A_New_Name')

    ; Displays 'A_New_Name'
    ConsoleWrite('2. ' & _Get_Name() & @CRLF)

    ; Displays 99.100.99.1
    ConsoleWrite('3. ' & _Get_Version() & @CRLF)

    ; Set to a new name
    _Set_Name('')

    ; Displays 'A_New_Name', as the string was empty previously
    ConsoleWrite('4. ' & _Get_Name() & @CRLF)

    ; If the variable located in __AppSettings_Wrapper() was purely a global variable, then anything could be assigned to it
    ; without proper checking. As you can see below, the variable is only assigned to when certain criteria is met

    ; Before someone mentions performance, you have to weigh up the pros and cons of such a design choice. If you really need data to be protected
    ; from your users mingling with it, then this is one of many correct approaches to encapsulate data. Otherwise if you're not concerened, then
    ; maybe it's not for you. You're the developer when it comes down to it
EndFunc   ;==>Example

; Getter
Func _Get_Name()
    Return __AppSettings_Wrapper($APP_GETTER, $APP_SETTINGS_NAME)
EndFunc   ;==>_Get_Name

; Setter
Func _Set_Name($sName)
    Return __AppSettings_Wrapper($APP_SETTER, $APP_SETTINGS_NAME, $sName)
EndFunc   ;==>_Set_Name

; Getter
Func _Get_Version()
    Return __AppSettings_Wrapper($APP_GETTER, $APP_SETTINGS_VERSION)
EndFunc   ;==>_Get_Version

; This is a wrapper for the local static variable that will be visible only in the function and for the duration of the application's
; lifecycle

; $iGetterOrSetter: Either $APP_GETTER or $APP_SETTER
; $iType: The parameter type e.g. name, version etc...
; $vValue: Used when the type is $APP_SETTER
Func __AppSettings_Wrapper($iGetterOrSetter, $iType, $vValue = Null)
    ; Create a local static variable and initialise to 0
    Local Static $s_aAppSettings[$APP_SETTINGS_MAX] = [True] ; First element is $APP_SETTINGS_ISFIRSTRUN

    ; If the first run, then initialise the $s_aAppSettings array with default values
    If $s_aAppSettings[$APP_SETTINGS_ISFIRSTRUN] Then
        $s_aAppSettings[$APP_SETTINGS_ISFIRSTRUN] = False ; Set to false, as now the array has been initialised
        $s_aAppSettings[$APP_SETTINGS_NAME] = 'myAppName'
        $s_aAppSettings[$APP_SETTINGS_VERSION] = '99.100.99.1'
    EndIf

    Switch $iGetterOrSetter
        Case $APP_GETTER ; Getter
            Switch $iType
                Case $APP_SETTINGS_NAME
                    Return $s_aAppSettings[$APP_SETTINGS_NAME]

                Case $APP_SETTINGS_VERSION
                    Return $s_aAppSettings[$APP_SETTINGS_VERSION]

            EndSwitch

        Case $APP_SETTER ; Setter
            Switch $iType
                Case $APP_SETTINGS_NAME
                    If $vValue Then
                        $s_aAppSettings[$APP_SETTINGS_NAME] = $vValue
                    EndIf

                Case $APP_SETTINGS_VERSION
                    ; No setter for the version attribute

            EndSwitch

    EndSwitch

    ; Return null by default, especially if the type is as a setter
    Return Null
EndFunc   ;==>__AppSettings_Wrapper

 

[mLipok]

One question:

; An enumeration for the getters and setters, as I hate having to write zero and one
Global Enum Step * 2 $APP_GETTER, $APP_SETTER

Why you are using Step * 2 ?

 

[guinness]

Just felt like it, as I wanted to showcase something different from the first example

[mLipok]

But this is very intresting , I've never used multiplication in enums steps. 
Now I see that in this way I can make a "BIT masked" enums.

I think I have an idea of new example to HelpFile, but first I must play a litle with it.

Thanks.

[guinness]

Okay great