How to get line number where a string was found?

[kadanefewi]

Hey guys.

I need to obtain the line number where a given string was found, I couldn't find a function.

All I can think of is counting the number of CR & LF characters, would that work? How can I represent them to Autoit, if that's the best solution?

Thanks for the input.

[BrewManNH]

You could use FileReadToArray and search the array to find where the string is located, the array row would be equivalent to the line number.

[mikell]

StringSplit on @crlf may be enough

Local $sString = "alpha" &@crlf& "beta" &@crlf& "gamma" &@crlf& "delta" &@crlf& "epsilon"
Msgbox(0,"", $sString)

Local $n = -1, $word = "gam"
$aString = StringSplit($sString, @crlf, 3)
For $i = 0 to UBound($aString)-1
   If StringInStr($aString[$i], $word) Then $n = $i
Next
Msgbox(0,"", '"' & $word & '"' & (($n = -1) ? " not found" : " found on line " & $n+1))

 

[BrewManNH]

Unless it's a file he's reading from, then he'd still need a FileRead just to convert the read text to an array with StringSplit which FileReadToArray already does for you.

[mikell]

Right 

[Malkey]

Here is another method - no array, only strings.

; Local $sString = FileRead("FullPath\FileName") ; If viewing file contents for script's accuracy, word wrap may cause visual errors.
Local $sString = "alpha" & @CRLF & "beta" & @CRLF & "gamma" & @CRLF & "delta" & @CRLF & "epsilon & gamble game"
MsgBox(0, "Original String", $sString, 3)

Local $n, $word = "gam", $iCharPos = -1, $Start = 1, $sRes = ""
While $iCharPos <> 0
    $iCharPos = StringInStr($sString, $word, 1, 1, $Start) ;  $STR_CASESENSE (1) = case sensitive, occurrence = 1
    StringRegExpReplace(StringMid($sString, 1, $iCharPos), "\R", "") ; By default \R matches @CRLF, @CR or @LF only.
    $n = @extended + 1 ; @extended contains the number of replacements performed.
    $Start = $iCharPos + 1
    If ($sRes = "") Or ($iCharPos <> 0) Then $sRes &= '"' & $word & '"' & (($iCharPos = 0) ? " not found" : " found on line " & $n) & @CRLF
WEnd

MsgBox(0, "Result", $sRes)