Recording a log when there is an error in the script.

[Belini]

I would like to record a log whenever it appears the MsgBox () indicating which line gave error, one can say that this place MsgBox () is called?

Attached an error example:

[mLipok]

 

btw.

please fix your signatures

 

Edited June 19, 2015 by mLipok

[jchd]

Better yet: fix the faulty code.

[Belini]

@mLipok thanks for replying but I just want to find where the MsgBox is generated to put this point an error log!

@jchd It is precisely to fix the script I need to log in this way because other people who use my code can send me the error log if any in the code!

[l3ill]

You could use something like this:

#include <File.au3>

While 1

    $hWnd = WinGetHandle("AutoIt Error")

    If WinExists($hWnd) Then
        Local $sText = WinGetText($hWnd)
        _FileWriteLog(@ScriptDir & "\Example.log", $sText)

    EndIf

    Sleep(50)

WEnd

 

This is just the basic idea and still needs some work.

Edited June 21, 2015 by l3ill

[mLipok]

@mLipok thanks for replying but I just want to find where the MsgBox is generated to put this point an error log!

It is generated in AutoIt.exe....
You can only Hook this message and then you can do what you want.

mLipok

ps.
I personally would like AutoIt if it had its own specialized function that can intercept the message and cast it into the hands of the person who writes the script

 

[water]

@mLipok thanks for replying but I just want to find where the MsgBox is generated to put this point an error log!

As this function has been written by trancexx maybe she can chime in and tell us if/how it is possible to grab the error information of the MsgBox.

[mLipok]

The example was here:

Func Intercept_MessageBoxW($hWnd, $sText, $sTitle, $iType)
    Local $aCall = DllCall("user32.dll", "int", "MessageBoxW", _
            "hwnd", $hWnd, _
            "wstr", $sText, _
            "wstr", StringReplace($sTitle, "AutoIt", @ScriptName), _
            "uint", $iType)
    If @error Or Not $aCall[0] Then Return 0
    Return $aCall[0]
EndFunc

 

For my needs I changed it to this:

Func Intercept_MessageBoxW($hWnd, $sText, $sTitle, $iType)
;~  http://www.autoitscript.com/forum/topic/154081-avoid-autoit-error-message-box-in-unknown-errors/
    Local $sText_old = $sText
    If _
            StringInStr($sText, @ScriptFullPath) <> 0 And _
            StringInStr($sText, 'Error:') <> 0 And _
            StringInStr($sTitle, 'AutoIt Error') <> 0 _
            Then
        $sTitle = StringReplace($sTitle, "AutoIt Error", "Error:")

        $sText_old = StringRegExpReplace($sText_old, '(?i)(Line )(\d*)( *)', 'Błąd wystąpił w linii nr: $2' & @CRLF & @CRLF)
        $sText_old = StringRegExpReplace($sText_old, '(?i)(Error: )(.*)', @CRLF & 'Opis błędu:' & @CRLF & '$2')
        $sText = 'Program ' & @ScriptName & @CRLF & 'wykonał nieprawidłową operację i zostanie zamknięty.' & @CRLF & @CRLF & $sText_old & @CRLF
        $sText &= '=======================================' & @CRLF
        $sText &= '.....' & @CRLF
        FileWrite(@ScriptDir & '\Error.log' , $sText)
    EndIf
    Local $aCall = DllCall("user32.dll", "int", "MessageBoxW", _
            "hwnd", $hWnd, _
            "wstr", $sText, _
            "wstr", $sTitle, _
            "uint", $iType)
    If @error Or Not $aCall[0] Then Return 0
    Return $aCall[0]
EndFunc   ;==>Intercept_MessageBoxW

 

Edited June 21, 2015 by mLipok
wording , and code tags

[Belini]

I personally would like AutoIt if it had its own specialized function that can intercept the message and cast it into the hands of the person who writes the script

 

I also think it would be good this way!

Since there is no way to generate the log where the MsgBox () is created I will then use the way suggested by @l3ill.

#include <File.au3>

While 1
    If WinExists("AutoIt Error") Then
        _FileWriteLog(@ScriptDir & "\Example.log", WinGetText("AutoIt Error"))
        exit
    EndIf
    sleep(100)
WEnd

 

Edited June 21, 2015 by Belini