combobox in gui select and appear another combobox

faustf · June 11, 2015

hi guy

i have a questions , i want create a gui in the gui i want insert a combo box with 17 item , after select one of this item , i want active a second combo box with other item

i try to do a code in this mode but not go correctly

Func _func_categorie_combo()
    $Combo1 = GUICtrlCreateCombo("", 344, 368, 225, 25);, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
    $Label4 = GUICtrlCreateLabel("Categoria", 344, 344, 49, 17)
    GUICtrlSetData($Combo1, "Abbigliamento e Accessori|Animali e Accessori|Arredamento e Casalinghi|Attrezzature da Lavoro|Biglietti|Case|Case Vacanze e Viaggi|Corsi e Lezioni|Elettronica|Gastronomia|Lavoro|Libri Film Musica|Motori|per il tuo Matrimonio|Sport|Tempo Libero|Per Bambini", "")
    ;$Button1 = GUICtrlCreateButton("Conferma", 576, 368, 59, 21)
    $Label5 = GUICtrlCreateLabel("Sottocategoria", 344, 400, 73, 17)


    While 1

        $categoria = GUICtrlRead($Combo1)
        If $categoria <> "" Then
            ;MsgBox($MB_SYSTEMMODAL, "", "The combobox is currently displaying: " & $categoria, 0, $Form1_1)
            $Label5 = GUICtrlCreateLabel("Sottocategoria", 344, 400, 73, 17)
            $sottocategoria = $Combo2 = GUICtrlCreateCombo("Combo1", 344, 424, 225, 25);, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
            Select
                Case $categoria = "Elettronica"
            GUICtrlSetData($Combo1, "Altro Elettronica|Audio TV e Video|Cellulari e Accessori|Computer e Software|fotografia|Tablet|videogiochi e Console","")
            EndSelect
        Else
            $Label5 = GUICtrlCreateLabel("Sottocategoria", 344, 400, 73, 17)
            GUICtrlSetState(-1, $GUI_DISABLE)
            $sottocategoria = $Combo2 = GUICtrlCreateCombo("Combo1", 344, 424, 225, 25);, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
            GUICtrlSetState(-1, $GUI_DISABLE)
        EndIf
    WEnd

EndFunc   ;==>_func_categorie_combo

some one can help me thankz at all

Edited June 11, 2015 by faustf

Melba23 · June 11, 2015

faustf,

I would do it like this:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 600, 500)

$Combo1 = GUICtrlCreateCombo("", 344, 368, 225, 25);, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
$Label4 = GUICtrlCreateLabel("Categoria", 344, 344, 49, 17)
GUICtrlSetData($Combo1, "Abbigliamento e Accessori|Animali e Accessori|Arredamento e Casalinghi|Attrezzature da Lavoro|Biglietti|Case|Case Vacanze e Viaggi|Corsi e Lezioni|Elettronica|Gastronomia|Lavoro|Libri Film Musica|Motori|per il tuo Matrimonio|Sport|Tempo Libero|Per Bambini", "")
;$Button1 = GUICtrlCreateButton("Conferma", 576, 368, 59, 21)
$Label5 = GUICtrlCreateLabel("Sottocategoria", 344, 400, 73, 17)
GUICtrlSetState($Label5, $GUI_HIDE)
$Combo2 = GUICtrlCreateCombo("", 344, 424, 225, 25)
GUICtrlSetState($Combo2, $GUI_HIDE)

GUISetState()

While 1


    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Combo1
            GUICtrlSetState($Combo2, $GUI_SHOW)
            GUICtrlSetState($Label5, $GUI_SHOW)
            $categoria = GUICtrlRead($Combo1)
            Switch $categoria

                Case $categoria = "Elettronica"
                GUICtrlSetData($Combo2, "|Altro Elettronica|Audio TV e Video|Cellulari e Accessori|Computer e Software|fotografia|Tablet|videogiochi e Console","")
            EndSwitch

    EndSwitch

WEnd

Note the leading "|" in the data added to $combo2 - this ensures that it replaces any current content so that you only get the required items displayed when you change the selection in $combo1.

M23

faustf · June 11, 2015

demade

Edited June 11, 2015 by faustf

Melba23 · June 11, 2015

faustf,

You are using OnEvent mode - so there is no point in adding a GUIGetMsg in the idle loop. Here is my example rewritten to use OnEvent mode:

#include <GUIConstantsEx.au3>

Opt("GuiOnEventMode", 1)

$hGUI = GUICreate("Test", 600, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

$Combo1 = GUICtrlCreateCombo("", 344, 368, 225, 25);, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetOnEvent($Combo1, "_func_categorie_combo")
$Label4 = GUICtrlCreateLabel("Categoria", 344, 344, 49, 17)
GUICtrlSetData($Combo1, "Abbigliamento e Accessori|Animali e Accessori|Arredamento e Casalinghi|Attrezzature da Lavoro|Biglietti|Case|Case Vacanze e Viaggi|Corsi e Lezioni|Elettronica|Gastronomia|Lavoro|Libri Film Musica|Motori|per il tuo Matrimonio|Sport|Tempo Libero|Per Bambini", "")
;$Button1 = GUICtrlCreateButton("Conferma", 576, 368, 59, 21)
$Label5 = GUICtrlCreateLabel("Sottocategoria", 344, 400, 73, 17)
GUICtrlSetState($Label5, $GUI_HIDE)
$Combo2 = GUICtrlCreateCombo("", 344, 424, 225, 25)
GUICtrlSetState($Combo2, $GUI_HIDE)

GUISetState()

While 1
    Sleep(10)
WEnd



Func _func_categorie_combo()
    GUICtrlSetState($Combo2, $GUI_SHOW)
    GUICtrlSetState($Label5, $GUI_SHOW)
    $categoria = GUICtrlRead($Combo1)
    Switch $categoria

        Case $categoria = "Elettronica"
            GUICtrlSetData($Combo2, "|Altro Elettronica|Audio TV e Video|Cellulari e Accessori|Computer e Software|fotografia|Tablet|videogiochi e Console","")
        Case Else
            GUICtrlSetData($Combo2, "|")
    EndSwitch

EndFunc



Func _Exit()
    Exit
EndFunc

Now you should be able to integrate it into your script.

M23

faustf · June 11, 2015

i mod a script but , always active second box with this item

"|Altro Elettronica|Audio TV e Video|Cellulari e Accessori|Computer e Software|fotografia|Tablet|videogiochi e Console","")

and i dont understund why

Melba23 · June 11, 2015

faustf,

Well, that is not a lot to go on. Post the script and let me take a look - perhaps I can spot something untoward.

M23

faustf · June 11, 2015

yea sorry

#cs ----------------------------------------------------------------------------

    AutoIt Version: 3.3.12.0
    Author:         faustf

    Script Function:
    SUBITO.IT KIJIJI CONTROLLER
    BY faustf

#ce ----------------------------------------------------------------------------


; Script Start - Add your code below here
#include <IE.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <InetConstants.au3>
#include <WinAPI.au3>
#include <WinAPIsysinfoConstants.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <Misc.au3>
#include <INet.au3>
#include <Excel.au3>
#include <File.au3>
#include <Array.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>

Opt("GuiOnEventMode", 1)
Opt("GUICloseOnESC", 0)

If ProcessExists("iexplore.exe") Then ; Check if the internet esplorer process is running.
    ProcessClose("iexplore.exe")
EndIf


; # VARIABILI GLOBALI ===============================================================================================

Global $oIE, $PREZZO, $FILE_FOTO, $Combo1, $Combo2, $categoria, $sottocategoria, $read_categoria, $Form1_1, $Label5






_Gui()

;_entra_subito_it()
;_entra_kijiji_it()
;_kiji_temp()

Func _entra_subito_it()

    Global $oIE = _IECreate("https://www2.subito.it/account/login_form", 0, 1, 1, 1)

    Local $oForm = _IEGetObjByName($oIE, "loginform")
    Local $username = _IEFormElementGetObjByName($oForm, "login_email")
    _IEFormElementSetValue($username, "demade")
    Local $pass = _IEFormElementGetObjByName($oForm, "login_passwd")
    _IEFormElementSetValue($pass, "demade")
    Local $oSubmit = _IEGetObjById($oIE, "btnLogin")
    _IEAction($oSubmit, "click")
    _IELoadWait($oIE)
EndFunc   ;==>_entra_subito_it

Func _entra_kijiji_it()

    Local $username, $password, $oSubmit

    $oIE = _IECreate("https://www.kijiji.it/miei-annunci/accedi")
    $username = _IEGetObjByName($oIE, "email")
    _IEFormElementSetValue($username, "demade")
    $password = _IEGetObjByName($oIE, "password")
    _IEFormElementSetValue($password, "demade")
    $oSubmit = _IEGetObjById($oIE, "infoBarLoginButton")
    _IEAction($oSubmit, "click")
    _IELoadWait($oIE)
    Local $oForm = _IEFormGetCollection($oIE, 0) ; first form in page
    Local $oFormElement = _IEFormElementGetCollection($oForm, 3) ; element 3 is the submit button
    _IEAction($oFormElement, "Click") ; perform the click
    _IELoadWait($oIE)
EndFunc   ;==>_entra_kijiji_it


Func _Gui()

    $Form1_1 = GUICreate("Form1", 1135, 672, 183, 0)

    _menu_file()

    $Tab1 = GUICtrlCreateTab(16, 40, 1113, 609)
    $TabSheet1 = GUICtrlCreateTabItem("TabSheet1")
    $Tutti = GUICtrlCreateCheckbox("Tutti", 40, 88, 49, 17)
    $Subito_it = GUICtrlCreateCheckbox("Subito_it", 40, 120, 65, 17)
    GUICtrlSetState(-1, $GUI_CHECKED)
    $Kijiji_it = GUICtrlCreateCheckbox("Kijiji_it", 40, 152, 57, 17)
    GUICtrlSetState(-1, $GUI_CHECKED)
    $Secondamano_it = GUICtrlCreateCheckbox("Secondamano_it", 40, 184, 97, 17)
    $Bakeca_it = GUICtrlCreateCheckbox("Bakeca_it", 40, 216, 97, 17)
    $Input1 = GUICtrlCreateInput("Input1", 48, 304, 249, 21)
    $Edit1 = GUICtrlCreateEdit("", 48, 368, 281, 145)
    GUICtrlSetData(-1, "")
    $Titolo = GUICtrlCreateLabel("Titolo", 48, 280, 30, 17)
    $Descrizione = GUICtrlCreateLabel("Descrizione", 48, 344, 59, 17)
    $Input2 = GUICtrlCreateInput("Input2", 48, 544, 57, 21)
    $PREZZO = GUICtrlCreateLabel("Prezzo", 48, 520, 36, 17)
    $Paypal = GUICtrlCreateCheckbox("Paypal si/no", 48, 592, 97, 17)
    GUICtrlSetState(-1, $GUI_CHECKED)
    $checcbox = GUICtrlCreateCheckbox("Nascondi il numero ", 192, 544, 121, 17)
    GUICtrlSetState(-1, $GUI_CHECKED)
    $Offro = GUICtrlCreateRadio("Offro", 240, 104, 49, 17)
    GUICtrlSetState(-1, $GUI_CHECKED)
    $Cerco = GUICtrlCreateRadio("Cerco", 240, 128, 57, 17)
    $Inserisci = GUICtrlCreateButton("Inserisci", 1016, 600, 75, 21)
    $Input3 = GUICtrlCreateInput("Input3", 336, 120, 193, 21)
    $Foto = GUICtrlCreateButton("Foto", 552, 120, 83, 21)
    $Label1 = GUICtrlCreateLabel("Percorso Foto", 336, 96, 70, 17)
    $Label2 = GUICtrlCreateLabel(",00 €", 112, 548, 28, 17)
    $Input4 = GUICtrlCreateInput("Input4", 176, 208, 121, 21)
    $Label3 = GUICtrlCreateLabel("Comune", 176, 184, 43, 17)
    $List1 = GUICtrlCreateList("", 336, 152, 297, 175)

    $Combo1 = GUICtrlCreateCombo("", 344, 368, 225, 25);, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
    $Label4 = GUICtrlCreateLabel("Categoria", 344, 344, 49, 17)

    GUICtrlSetData($Combo1, "Abbigliamento e Accessori|Animali e Accessori|Arredamento e Casalinghi|Attrezzature da Lavoro|Biglietti|Case|Case Vacanze e Viaggi|Corsi e Lezioni|Elettronica|Gastronomia|Lavoro|Libri Film Musica|Motori|per il tuo Matrimonio|Sport|Tempo Libero|Per Bambini", "")
    ;$Button1 = GUICtrlCreateButton("Conferma", 576, 368, 59, 21)

    $Label5 = GUICtrlCreateLabel("Sottocategoria", 344, 400, 73, 17)
    GUICtrlSetState($Label5, $GUI_HIDE)

    $Combo2 = GUICtrlCreateCombo("Combo1", 344, 424, 225, 25)
    GUICtrlSetState($Combo2, $GUI_HIDE)

    $TabSheet2 = GUICtrlCreateTabItem("TabSheet2")
    GUICtrlCreateTabItem("")
    GUISetState(@SW_SHOW)

    GUICtrlSetOnEvent($Inserisci, "_inserisci")
    _func_categorie_combo()


EndFunc   ;==>_Gui

Func _func_categorie_combo()



    GUICtrlSetState($Combo2, $GUI_SHOW)
    GUICtrlSetState($Label5, $GUI_SHOW)
    $categoria = GUICtrlRead($Combo1)
    Switch $categoria

        Case $categoria = "Elettronica"
            GUICtrlSetData($Combo2, "|Altro Elettronica|Audio TV e Video|Cellulari e Accessori|Computer e Software|fotografia|Tablet|videogiochi e Console", "")
        Case Else
            GUICtrlSetData($Combo2, "|")

    EndSwitch


EndFunc   ;==>_func_categorie_combo




Func _kiji_temp()

    $PREZZO = "100000"
    $Descrizione = "LA DESCRIZIONE DEVE  AVERE PIU DI DODICI CARATTERI NUMERICI E  ALFANUMERICI PUPPA!!!"
    ;$location_foto= "C:\Users\Stefano\Pictures\Nikon Transfer\001\"
    $location_foto = "C:\Users\e-Office\Desktop\ridotte"
    ;   $FILE_FOTO = '"_DSC0001_01.NEF" "_DSC0001_01.JPG"'
    $FILE_FOTO = '"_DSC0011.JPG"'
    _entra_kijiji_it()
    _IENavigate($oIE, "https://www.kijiji.it/pubblica-annuncio")
    _IELoadWait($oIE)
    ;#cs
    Sleep(10000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(2000)
    Send("{TAB}")
    Sleep(3000)
    Send("{E}") ;  seleziono la categoria
    Sleep(3000)
    Send("{TAB}") ; con questo tab seleziono la sottocategoria
    Sleep(2000)
    Send("{T}")
    Sleep(2000)
    Send("{TAB}") ; con questo  cancello la vecchia location e ne imposto una nuova
    Sleep(2000)
    Send("{BACKSPACE 10}")
    Sleep(2000)
    Send("EMPOLI")
    Sleep(2000)
    Send("{TAB 3}") ; con questo tab  metto il titolo
    Send("PROVA")
    Send("{TAB}") ;  con questo tab   vado in prezzo
    Send("" & $PREZZO & "")
    Send("{TAB}") ; con queso tab e  space fleggo il checkbox  o un conto paypal                 C:\Users\Stefano\Pictures\Nikon Transfer
    Send("{SPACE}")
    Send("{TAB 2}") ;  con questi due tab  vedo nel riquadro descrizione
    Send("" & $Descrizione & "")
    Send("{TAB}") ;   con questo tab e  space  apro immagini
    Send("{TAB}") ;   con questo tab e  space  apro immagini
    Send("{TAB}") ;   con questo tab e  space  apro immagini
    Sleep(5000)
    Send("{SPACE}")
    Sleep(3000)
    Send("{TAB 4}") ;   con questo tab e  space inserisco la cartella di default dove pesca le foto
    Send("{SPACE}")
    Send("" & $location_foto & "")
    Send("{ENTER}")
    Sleep(2000)
    Send("{TAB 5}") ; seleziono tutte le foto
    Sleep(2000)
    Send("" & $FILE_FOTO & "")
    Send("{ENTER}")
    Sleep(30000)

    Local $txt_img_allert = _IEBodyReadText($oIE)
    Local Const $sFilePath = @ScriptDir & "\FileWrite.txt"
    Local $hFileOpen = FileOpen($sFilePath, $FO_APPEND)
    FileWrite($hFileOpen, $txt_img_allert & @CRLF)

    Local $aArray_controllo_img = StringRegExp($txt_img_allert, '(?i)Puoi inserire altre (.*?) immagini.', $STR_REGEXPARRAYGLOBALMATCH)

    If @error Then

        MsgBox(0, '', 'errore')
    Else
        MsgBox(0, 'controllo img', $aArray_controllo_img[0])
    EndIf


    Send("{TAB 39}")
    Send("{ENTER}")
    
EndFunc   ;==>_kiji_temp



Func _inserisci()

    _controlli_gui() ;  questa  funzione  serve per controllare  che  tutto sia inserito correttamente




EndFunc   ;==>_inserisci


Func _controlli_gui() ; funzione di controllo se  sulla gui è tutto inserito correttamente





EndFunc   ;==>_controlli_gui



Func _menu_file()

    $MenuItem2 = GUICtrlCreateMenu("MenuItem2")
    $MenuItem3 = GUICtrlCreateMenuItem("MenuItem3", $MenuItem2)
    $MenuItem1 = GUICtrlCreateMenu("MenuItem1")


    GUISetOnEvent($GUI_EVENT_CLOSE, "_Close")
EndFunc   ;==>_menu_file

;============= chiusura programma
Func _close()
    Exit
EndFunc   ;==>_close
;===============================================================
;Keep the GUI alive
;===============================================================
While 1
    Sleep(1000)
WEnd

Melba23 · June 11, 2015

faustf,

Did you actually read the code I posted above? My example code has these lines:

$Combo1 = GUICtrlCreateCombo("", 344, 368, 225, 25);, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetOnEvent($Combo1, "_func_categorie_combo")

so that the function which sets the data in $combo2 is called each time $combo1 is actioned. All you do in the script you just posted is call that function once at the end of the _Gui function - no wonder the data never changes as you never react to any changes in $combo1.

M23

faustf · June 11, 2015

o yea , sorry i dont know why i don't saw , and i have read your example many time uff but thankz so much

Melba23 · June 11, 2015

faustf,

So does it work correctly now?

M23

faustf · June 11, 2015

yea perfect thankz alot

combobox in gui select and appear another combobox

Recommended Posts

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members