Jump to content

Can't figure why button not working

31290

By 31290,
in AutoIt GUI Help and Support

 Share

Recommended Posts

31290 Adventurer

31290

Posted
Posted

Hi everyone, 

I'm requesting your help over here because I can't figure something that is going to pull all of my hear and, if possible, I would like to make another ask.

Here's the deal:

#include <FileConstants.au3>
#include <Array.au3>
#include <ButtonConstants.au3>
#include <ColorConstants.au3>
#include <ComboConstants.au3>
#Include <Constants.au3>
#include <Crypt.au3>
#include <Date.au3>
#include <File.au3>
#Include <FontConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <ProgressConstants.au3>
#include <ScreenCapture.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $FileChosen = ""
; Global $Images = "C:\SAC_IS\ATL_Laptop\Resources\Images\"
Global $UploadSource = ""
Global $UploadDest = "\\epeldol01\Automated Task List Suite\Bug Tracker\"
Opt("GUIOnEventMode", 1)

UploadGui()

Func UploadGui()
;ADD SMALL ICON!
; e.g GUISetIcon ($Images & "\ResultsGUI.ico")
Global $UploadGui = GUICreate ("Upload", 300, 300, -1, -1)
    ; GUICtrlCreatePic ($Images & "\SAClogo.jpg", 30, 10, 240, 80)
    GUISetBkColor ($Color_White)
    GuiCtrlCreateLabel ("-- ATLS BUG TRACKER --", 85, 100, 150, 25)
    GUICtrlSetFont (-1, 8.5, 700, 0)
    GUICtrlCreateLabel ("-Step one:", 10, 130, 100, 30)
    GUICtrlSetFont (-1, 8.5, 700, 0)
    GUICtrlCreateButton ("Choose file to upload", 90, 125, 120, 25)
    GUICtrlSetOnEvent (-1, "_ChooseFile")
    GuiCtrlCreateLabel ("-Step two:", 10, 170, 100, 30)
    GUICtrlSetFont (-1, 8.5, 700, 0)
    GUICtrlCreateButton ("Give us details", 100, 165, 100, 25)
    GUICtrlSetOnEvent (-1, "_Details")
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit", $UploadGui)
    ; GUICtrlSetOnEvent (-1, "_UploadFile")
    ; Global $NameOfFile = 
    While 1
       GuiSetState (@SW_SHOW)
    WEnd
EndFunc
    
Func _ChooseFile()
    ; Display an open dialog to select a file.
    Global $UploadSource = FileOpenDialog("Select File to Upload", @HomePath & "\", "Images (*.jpg;*.bmp)")
    ; If $UploadSource <> "" Then
    ; GUISetOnEvent 
        
EndFunc

Func _UploadFile()
If $UploadSource = "" Then
MsgBox ($MB_SYSTEMMODAL, "", "No file was selected. Choose a file first!")
Else
_CopyToLdrep($UploadSource, $UploadDest)
EndIf
EndFunc

    ;Upload Function
; Func _CopyToLdrep ($fromfile, $tofile)
    ; Local $FOF_RESPOND_YES = 16
    ; Local $FOF_SIMPLEPROGRESS = 256
    ; $winShell = ObjCreate ("shell.application")
    ; $winShell.namespace ($tofile).CopyHere ($fromFile, $FOF_RESPOND_YES)
; EndFunc

    ;Details Function
Func _Details()
    Opt("GUIOnEventMode", 1)
$DetailsGui = GUICreate ("Details", 300, 400, -1, -1)
    ; GUICtrlCreatePic ($Images & "\SAClogo.jpg", 30, 10, 240, 80)
    GUISetBkColor ($Color_White)
    GuiCtrlCreateLabel ("-- ATLS BUG TRACKER --", 85, 100, 150, 25)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    GuiCtrlCreateEdit ("Please describe the context, Date & Time, etc..." & @CRLF & "Also, provide your name and phone number just in case.", 5, 100, 290, 250)
    GuiCtrlCreateButton ("Submit", 125, 370, -1, -1)
    GuiCtrlSetOnEvent (-1, "_Submit")
    
While 1
GuiSetState (@SW_SHOW)
Wend
EndFunc

Func _Exit()
    Exit
EndFunc

Func _Submit()
msgbox (0, "re", "re")
EndFunc

I'm trying to create a sort of upload module for my techs to be able to submit "bugs"... The first GUI works perfectly but when I want to "Submit" the text they entered there's no way that button is working. I can't even close the windows with the little cross. But, when isolating the function and running it like:

#include <FileConstants.au3>
#include <Array.au3>
#include <ButtonConstants.au3>
#include <ColorConstants.au3>
#include <ComboConstants.au3>
#Include <Constants.au3>
#include <Crypt.au3>
#include <Date.au3>
#include <File.au3>
#Include <FontConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <ProgressConstants.au3>
#include <ScreenCapture.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

test()

Func test()
Opt("GUIOnEventMode", 1)
$DetailsGui = GUICreate ("Details", 300, 400, -1, -1)
    ; GUICtrlCreatePic ($Images & "\SAClogo.jpg", 30, 10, 240, 80)
    GUISetBkColor ($Color_White)
    GuiCtrlCreateLabel ("-- ATLS BUG TRACKER --", 85, 100, 150, 25)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    GuiCtrlCreateEdit ("Please describe the context, Date & Time, etc..." & @CRLF & "Also, provide your name and phone number just in case.", 5, 100, 290, 250)
    GuiCtrlCreateButton ("Submit", 125, 370, -1, -1)
    GuiCtrlSetOnEvent (-1, "_Submit")
    GuiSetState (@SW_SHOW)
While 1
Sleep (10)
Wend
EndFunc

Func _Exit()
    Exit
EndFunc

Func _Submit()
msgbox (0, "re", "re")
EndFunc

This is working nicely and my msgbox proves it.

Second ask is that when a tech finished to choose a file and when he clicked on the "Submit" button, how can I add some "checkmark" meaning this is done and that he can perform the upload? (Indeed, both conditions must me fulfilled to send files to the server). Or maybe a disabled "Send files" button... But I can't figure that out.

Thanks very much in advance for the help you could provide :)

See ya :)

~~~ Doom Shall Never Die, Only The Players ~~~

Link to comment
Share on other sites
  • Moderators
Melba23 Universalist

Melba23

Posted
  • Moderators
Posted

31290,

Why the loops around each GUISetState? This version seems to work better:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Opt("GUIOnEventMode", 1) ; Only needed once

Global $FileChosen = ""
; Global $Images = "C:\SAC_IS\ATL_Laptop\Resources\Images\"
Global $UploadSource = ""
Global $UploadDest = "\\epeldol01\Automated Task List Suite\Bug Tracker\"

Global $UploadGui



UploadGui()

; Always return to an idle loop in the main section of the script
While 1
    Sleep(10)
WEnd



Func UploadGui()
    $UploadGui = GUICreate("Upload", 300, 300, -1, -1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit", $UploadGui)

    GUICtrlCreateLabel("-- ATLS BUG TRACKER --", 85, 100, 150, 25)
    GUICtrlCreateLabel("-Step one:", 10, 130, 100, 30)
    GUICtrlCreateLabel("-Step two:", 10, 170, 100, 30)

    GUICtrlCreateButton("Choose file to upload", 90, 125, 120, 25)
    GUICtrlSetOnEvent(-1, "_ChooseFile")

    GUICtrlCreateButton("Give us details", 100, 165, 100, 25)
    GUICtrlSetOnEvent(-1, "_Details")

    GUISetState(@SW_SHOW)
EndFunc   ;==>UploadGui



Func _ChooseFile()
    ; Display an open dialog to select a file.
    Global $UploadSource = FileOpenDialog("Select File to Upload", @HomePath & "\", "Images (*.jpg;*.bmp)")
    ; If $UploadSource <> "" Then
    ; GUISetOnEvent



EndFunc   ;==>_ChooseFile



Func _UploadFile()
    If $UploadSource = "" Then
        MsgBox($MB_SYSTEMMODAL, "", "No file was selected. Choose a file first!")
    Else
        ;_CopyToLdrep($UploadSource, $UploadDest)
        MsgBox($MB_SYSTEMMODAL, "Uploading", $UploadSource)
    EndIf

EndFunc   ;==>_UploadFile



;Details Function
Func _Details()
    
    $DetailsGui = GUICreate("Details", 300, 400, -1, -1)
    
    GUICtrlCreateLabel("-- ATLS BUG TRACKER --", 85, 100, 150, 25)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    
    GUICtrlCreateEdit("Please describe the context, Date & Time, etc..." & @CRLF & "Also, provide your name and phone number just in case.", 5, 100, 290, 250)
    
    GUICtrlCreateButton("Submit", 125, 370, -1, -1)
    GUICtrlSetOnEvent(-1, "_Submit")

    GUISetState(@SW_SHOW)

EndFunc   ;==>_Details

Func _Exit()
    Exit
EndFunc   ;==>_Exit

Func _Submit()
    MsgBox(0, "re", "re")
EndFunc   ;==>_Submit

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites
31290 Adventurer

31290

Posted
  • Author
Posted

It seems that I have many problems with loops... But hey, many thanks M23, much appreciated :)

BTW, do you have some clues for me about my second question?

When a tech finished to choose a file and when he clicked on the "Submit" button, how can I add some "checkmark" meaning this is done and that he can perform the upload? (Indeed, both conditions must me fulfilled to send files to the server). Or maybe a disabled "Send files" button... But I can't figure that out.

 I guess I won't have to destroy previous GUI as all variable used by it sill be destroyed as well?

Thanks again :)

~~~ Doom Shall Never Die, Only The Players ~~~

Link to comment
Share on other sites
Valuater Universalist

Valuater

Posted
Posted (edited) 
#include <FileConstants.au3>
#include <Array.au3>
#include <ButtonConstants.au3>
#include <ColorConstants.au3>
#include <ComboConstants.au3>
#include <Constants.au3>
#include <Crypt.au3>
#include <Date.au3>
#include <File.au3>
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <Misc.au3>
#include <MsgBoxConstants.au3>
#include <ProgressConstants.au3>
#include <ScreenCapture.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $FileChosen = ""
; Global $Images = "C:\SAC_IS\ATL_Laptop\Resources\Images\"
Global $UploadSource = ""
Global $UploadDest = "\\epeldol01\Automated Task List Suite\Bug Tracker\"
Opt("GUIOnEventMode", 1)

$DetailsGui = GUICreate("Details", 300, 400, -1, -1, $WS_POPUPWINDOW)
; GUICtrlCreatePic ($Images & "\SAClogo.jpg", 30, 10, 240, 80)
; GUICtrlSetState( -1,$GUI_DISABLE)

GUISetBkColor($Color_White)
GUICtrlCreateLabel("-- ATLS BUG TRACKER --", 85, 100, 150, 25)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUICtrlCreateEdit("Please describe the context, Date & Time, etc..." & @CRLF & "Also, provide your name and phone number just in case.", 5, 100, 290, 250)
GUICtrlCreateButton("Submit", 125, 370, -1, -1)
GUICtrlSetOnEvent(-1, "_Submit")
GUICtrlCreateButton("Close", 225, 370, -1, -1)
GUICtrlSetOnEvent(-1, "_Close")

GUISetState(@SW_HIDE)


;ADD SMALL ICON!
; e.g GUISetIcon ($Images & "\ResultsGUI.ico")
Global $UploadGui = GUICreate("Upload", 300, 300, -1, -1)
; GUICtrlCreatePic ($Images & "\SAClogo.jpg", 30, 10, 240, 80)
GUISetBkColor($Color_White)
GUICtrlCreateLabel("-- ATLS BUG TRACKER --", 85, 100, 150, 25)
GUICtrlSetFont(-1, 8.5, 700, 0)
GUICtrlCreateLabel("-Step one:", 10, 130, 100, 30)
GUICtrlSetFont(-1, 8.5, 700, 0)
GUICtrlCreateButton("Choose file to upload", 90, 125, 120, 25)
GUICtrlSetOnEvent(-1, "_ChooseFile")
GUICtrlCreateLabel("-Step two:", 10, 170, 100, 30)
GUICtrlSetFont(-1, 8.5, 700, 0)
$Details_Button = GUICtrlCreateButton("Give us details", 100, 165, 100, 25)
GUICtrlSetOnEvent(-1, "_Details")
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit", $UploadGui)
; GUICtrlSetOnEvent (-1, "_UploadFile")
; Global $NameOfFile =
GUISetState(@SW_SHOW)

While 1
    Sleep(10)
WEnd


; ********** FUNCTIONS **************


Func _ChooseFile()
    ; Display an open dialog to select a file.
    Global $UploadSource = FileOpenDialog("Select File to Upload", @HomePath & "\", "Images (*.jpg;*.bmp)")
    If FileExists($UploadSource) Then
        GUICtrlSetState($Details_Button, $GUI_ENABLE)
    Else
        MsgBox($MB_SYSTEMMODAL, "No File Selected", "Please select a file first", 10)
    EndIf

EndFunc   ;==>_ChooseFile

Func _UploadFile()
    If Not FileExists($UploadSource) Then
        MsgBox($MB_SYSTEMMODAL, "", "No file was selected. Choose a file first!")
    Else
        _;CopyToLdrep($UploadSource, $UploadDest)
    EndIf
EndFunc   ;==>_UploadFile

;~  ;Upload Function
;~ ; Func _CopyToLdrep ($fromfile, $tofile)
;~     ; Local $FOF_RESPOND_YES = 16
;~     ; Local $FOF_SIMPLEPROGRESS = 256
;~     ; $winShell = ObjCreate ("shell.application")
;~     ; $winShell.namespace ($tofile).CopyHere ($fromFile, $FOF_RESPOND_YES)
;~ ; EndFunc

;Details Function
Func _Details()
    GUISetState(@SW_SHOW, $DetailsGui)
EndFunc   ;==>_Details

Func _Exit()
    Exit
EndFunc   ;==>_Exit

Func _Submit()
    MsgBox(0, "re", "re")
EndFunc   ;==>_Submit

Func _Close()
    GUISetState(@SW_HIDE, $DetailsGui)
EndFunc   ;==>_Close

 

 

8)

Edited by Valuater

NEWHeader1.png

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share
Go to topic listing
×
×
  • Create New...