StringLeft help!

[CaptainSparky]

Hello good friends of Autoit, so I am making a chatbot using Autoit but I got stuck on this part:

I already have stringright($var,stringlen($var) - stringlen(" = ") - StringInStr($var," = ") + 1) the program is made to read a text file and extract from a specific line the text after = and before =, for example:

example line of text file: something = okay this is a text

and I needed to extract the right part (which I already have done) and the left part (which I need help with) so how can you make stringleft to get all text before "="?

Thanks in advance.

Here's my code if you need it:

expandcollapse popup

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#include <Misc.au3>
#Include <Array.au3>

Global $BrainLocation = @ScriptDir & "\brain.txt"
Global $FormName = "Project Lisa"
Global $ReatInput = "null"
Global $Memory[100]
Global $BrainLineCount = 1
Global $Random[100]
Global $RandomCount = 0
Global $SplitInput[100]
Global $BrainCount = 0

Loader()

Func Loader()

    Global $Form = GUICreate($FormName, 417, 279, 192, 124)
    Global $Output = GUICtrlCreateEdit("", 8, 8, 401, 225, BitOR($ES_AUTOVSCROLL,$ES_AUTOHSCROLL,$ES_WANTRETURN,$WS_HSCROLL),0)
    Global $Input = GUICtrlCreateInput("", 104, 240, 209, 21)
    GUISetState(@SW_SHOW)
    ControlFocus($FormName,"",$input)
    HotKeySet("{ENTER}","SendText")

    Main()

EndFunc

func Main()

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd

EndFunc


Func SendText()

    $ReatInput = GUICtrlRead($Input)
    GUICtrlSetData($Output,@CRLF & "You > " & $ReatInput,1)

    CreateRandoms()

EndFunc

Func CreateRandoms()

    While $RandomCount <> 100
        $Random[$RandomCount] = Random(1,$RandomCount,1)
        $RandomCount += 1
    WEnd
    $RandomCount = 0

    BrainLoader()

EndFunc

Func BrainLoader()

    $ReatBrain = FileReadLine($Brainlocation,$BrainLineCount)
    $BrainStringRight = stringright($ReatBrain,stringlen($ReatBrain) - stringlen(" = ") - StringInStr($ReatBrain," = ") + 1)
    MsgBox(0,"",$Brainstringright)
    $BrainStringLenRight = Stringlen($brainstringright)
    MsgBox(0,"",$Brainstringright)
    $BrainActualString = 0 + $BrainStringLenRight - 10
    MsgBox(0,"",$BrainActualString)
    $test = StringLeft($ReatBrain,$brainactualstring)
    MsgBox(0,"",$test)
    $BrainSplitedStrings = StringSplit($BrainStringRight,",")

    If $BrainSplitedStrings[1] <> "" Then
        $_1 = "true"
        $BrainCount += 1
    EndIf

    If $ReatInput = $BrainActualString Then
        $BrainRan = Random(1,$braincount)
        GUICtrlSetData($output,@CRLF & "Lisa > " & $BrainSplitedStrings[$BrainRan],1)
        $BrainLineCount = 1
        Main()
    Else
        main()
    EndIf
    $BrainLineCount += 1
    BrainLoader()

EndFunc

[javiwhite]

if you need both parts of the text, why don't you just use stringsplit?

$text = "some = text"
$Split = StringSplit($text,"=")
ConsoleWrite($Split[1]) ;Some
ConsoleWrite(@CR)
ConsoleWrite($Split[2]) ;Text

Many Thanks

Javi

[CaptainSparky]

Holy cow! HOW DID I DIDN'T THINK OF THAT? how stupid of me. Thank you good friend.

[Skysnake]

Also look at the Regular Expressions?

[TheDcoder]

You might wanna look at my StringTrimRightUntil & StringTrimLeftUntil functions here

They are more efficient & simple! TD

[CaptainSparky]

Thank you guys.

[CaptainSparky]

Sorry that didn't work out... I need the opposite ( the left version ) of this one : stringright($var,stringlen($var) - stringlen(" = ") - StringInStr($var," = ") + 1)

I need to stringleft after/before a specific character(s) for example in the one above is after =, the one I need should be Get all text BEFORE =.

anyone? thanks in advance

Edited June 8, 2015 by TheNewHunter

[CaptainSparky]

Okay I got it guys.

[javiwhite]

StringSplit all the way my friend, Even if it's just for ease of reading when you come back to a code a few months later (it's amazing how a solution to a problem you face can seem innovative at the time, But then Jargon when you come back to the code.) Even if you're just looking for the left part of the string, StringSplit can accomplish this:

$text = "some = text"
$Left = StringSplit($text,"=")[1] ;Notice the array number
$Right = StringSplit($text,"=")[2] ;These run the stringsplit command, And then return that element to the variable from the resulting array
Consolewrite($Left)
ConsoleWrite(@CR)
ConsoleWrite($Right)

Just a handy little trick I discovered after a while of using AutoIt, The same applies to any commands that return arrays.

Cheers

Javi

[MikahS]

@TheNewHunter Make sure you post your solution, so that anyone that has the same problem can see how you solved it. 

[Malkey]

Also look at the Regular Expressions?

Using a regular expression allows control over optional spaces before and after the equal sign, and having those spaces (if they exist) not appearing in the required 'before and after' text.

$text = "some = text"

; These StringRegExpReplace replaces all text matched with nothing, "".   (Match the characters to be deleted)

$Left = StringRegExpReplace($text, "\h*=.*$", "")
; "\h*"  Match all spaces (if they exist) immediately before "=".   Note:- A space is a character, and can be classified as a horizontal whitespace character.
; "="    Match the equal character.
; ".*$"  Match all characters (if any exist) to the end of the test string (from immediately after "=").

$Right = StringRegExpReplace($text, "^.*=\h*", "")
; "^.*"  Match all characters (if any exist) from the beginning of the test string to immediately before "=".
; "="    Match the equal character.
; "\h*"  Match all spaces (if they exist) immediately after "=".
; See AutoIt help file under StringRegExp for regular expression syntax.

ConsoleWrite("Left:  " & $Left & @LF)
ConsoleWrite("Right: " & $Right & @LF)

@javiwhite
Another handy little trick, if you are writing your scripts in SciTE, is to type in lower case "cw ".  That is, type"cw" followed by a space. This is the SciTE4AutoIt3 abbreviation for "ConsoleWrite(| & @LF) ".  I use it often.  
The complete list of SciTe-AutoIt abbreviations can be found in the SciTe help file > under the "Index" tab  > SciTE4AutoIt3-AbbreviationList.
 

[iamtheky]

Just a handy little trick I discovered after a while of using AutoIt, The same applies to any commands that return arrays.

You have no validation that stringsplit succeeded and risk throwing an exception attempting to access an element that does not exist, so you may want to do a stringinstr to verify an equals sign is present prior to running that.  or just split it once and check for an error then access the elements.