How to get exact match of a word

[ur]

When I am searching a word from a sentence through StringInStr, it is not giving exact match but it is giving the word if the letters in the word are included in it.

Ex: If I am searching for a word Sun in a sentence below.

Sun is hot today.   --> Here it is working as expected.

But it is returning a word exist even for below sentence also.

 even though it is sunday.

As sun is there in the word sunday.

How to exclude this and only it should return true when it finds the word sun.

[BrewManNH]

StringInStr does a substring search, so you'd need to add a space after the word Sun to make sure it's looking for just Sun and not Sunday. Or use a StringRegEx instead.

[ur]

Applying space is also a problem if the string required is at the end of statement.

Can you help on how to do it in regular expression.

Edited May 29, 2015 by ur

[Melba23]

ur,

You need to use the "word boundary" delimiters:

#include <MsgBoxConstants.au3>

Global $aText[2] = ["Sun is hot today", "even though it is sunday."]

For $i = 0 To 1
    $iRet = StringRegExp($aText[$i], "(?i)\b(sun)\b")
    $sFound = (($iRet = 1) ? ("Found") : ("Not found") )
    MsgBox($MB_SYSTEMMODAL, "Result", $sFound & " in:" & @CRLF &  $aText[$i])
Next

SRE decode:

(?i)    - Case insensitive
\b      - Start at a word boundary..
(sun)   - ..look for the 3 letters in order...
\b      - ...followed by another word boundary

M23

Edited May 29, 2015 by Melba23
Fixed tags

[water]

StringInStr(" " & "Sun is hot today." & " ", " Sun ")

Edited May 29, 2015 by water

[ur]

StringInStr(" " & "Sun is hot today." & " ", " Sun ")

​But this will not work if the word we are finding is at the end of the line.

[ur]

ur,

You need to use the "word boundary" delimiters:

#include <MsgBoxConstants.au3>

Global $aText[2] = ["Sun is hot today", "even though it is sunday."]

For $i = 0 To 1
    $iRet = StringRegExp($aText[$i], "(?i)\b(sun)\b")
    $sFound = (($iRet = 1) ? ("Found") : ("Not found") )
    MsgBox($MB_SYSTEMMODAL, "Result", $sFound & " in:" & @CRLF &  $aText[$i])
Next

SRE decode:

(?i)    - Case insensitive
\b      - Start at a word boundary..
(sun)   - ..look for the 3 letters in order...
\b      - ...followed by another word boundary

M23

​But this will not work if the word we are finding is at the end of the line.

"Today is sun"
Or if we remove 2nd \b in regex then it would fail in below case

"Today is sunday" 

[water]

​But this will not work if the word we are finding is at the end of the line.

​This will work when the word ("sun") is at the end of the line. But it will not work for "sunday".

[Melba23]

ur,

But this will not work if the word we are finding is at the end of the line.

Are you sure about that? It seems to work fine for me:

#include <MsgBoxConstants.au3>

Global $aText[3] = ["Sun is hot today", "even though it is sunday.", "Hot is the sun"]

For $i = 0 To UBound($aText) - 1
    $iRet = StringRegExp($aText[$i], "(?i)\b(sun)\b")
    $sFound = (($iRet = 1) ? ("Found") : ("Not found") )
    MsgBox($MB_SYSTEMMODAL, "Result", $sFound & " in:" & @CRLF &  $aText[$i])
Next

M23

[iamtheky]

 

#include<array.au3>

Global $aText[3] = ["Sun is hot today", "even though it is sunday.", "Hot is the sun"]
$WordToMatch = "sun"

for $i = 0 to 2

$aMatch = 0
$aSplit = 0

$aSplit = stringsplit($aText[$i] , " ." , 2)
$aMatch = _ArrayFindAll($aSplit , $WordToMatch)
    If IsArray($aMatch) Then
        msgbox(0 , $aText[$i] , $aSplit[$aMatch[0]] & " is word number " & $aMatch[0] + 1)
    Else
        msgbox(0, 'Not Found' , "The Word '" & $WordToMatch & "' does not appear in:" & @CRLF & @CRLF & $aText[$i])
    EndIf
next

 

 

Edited May 29, 2015 by boththose

[ur]

Thanks for the replies to this topic.It is working with both regular expressions and space before and after.

[ur]

Can we split a sentence by using the word exact match.

Ex: It should split the string only at sun it should not split at sun part of sunday.

$word="sun"

$element = " sun is hot on sunday morning "

$strSplittedString = StringSplit ( $element, $word,$STR_ENTIRESPLIT )