Check for macros in excel

[water]

This code returns true for your example workbook:
 

#include <Excel.au3>
#include <File.au3>

Global $sFile = "C:\temp\Huis-3D-Excel-Pendulum_97.xls"
$oExcel = _Excel_Open()
$oWorkbook = _Excel_BookOpen($oExcel, $sFile)
ConsoleWrite("Workbook has macros: " & _CheckMacros($oWorkbook, $sFile) & @CRLF)

; Code taken from http://www.siddharthrout.com/2012/04/12/check-if-an-excel-file-has-a-macro/
Func _CheckMacros($oWorkbook, $sFilepath)
    Local $sCode, $sFiletype, $sDrive, $sDir, $sFilename, $sExtension
    _PathSplit($sFilepath, $sDrive, $sDir, $sFilename, $sExtension)
    Switch StringMid($sExtension, 2)
        ; Excel files which can have a macro
        Case "XLS", "XLSM", "XLTM", "XLT", "XLA", "XLSB", "XLAM"
            With $oWorkbook.VBProject
                ; Components are like sheet1, thisworkbook, module etc.
                If .VBComponents.Count > 0 Then
                    For $i = 1 To .VBComponents.Count
                        ; Get the entire code in the module
                        $sCode = .VBComponents.Item($i).CodeModule.Lines(1, .VBComponents.Item($i).CodeModule.CountOfLines)
                        $sCode = " " & StringReplace($sCode, @CRLF, " ") & " "
                        If StringInStr($sCode, " Sub ") > 0 Then Return True
                    Next
                EndIf
            EndWith
    EndSwitch
    Return False
EndFunc   ;==>_CheckMacros

 

[Smigacznr1]

I got error:

Only Object-type variables allowed in a "With" statement.:
With $oWorkbook.VBProject
With $oWorkbook^ ERROR

[Smigacznr1]

OK. I found solution for my last error:

https://support.microsoft.com/en-us/kb/282830

[Smigacznr1]

Everything works as expected. Thank for help and your time water

[water]

Glad to be of service