Berlin Clock

[Gianni]

....from the  serie "strange clocks":
see here for infos on how to read this clock

expandcollapse popup

; Berlin-Uhr
HotKeySet("{Esc}", "End")
Global $aColors[3] = ["0x757575", "0xFFCC00", "0xFF0033"] ; [off][yellow][red]
Local $iSec = 0, $iMin = 0
Global $hGui = GUICreate(' Berlin-Uhr', 275, 240)
;                      ($nrPerLine, $ctrlWidth, $ctrlHeight, $xPanelPos, $yPanelPos, $xSpace)
Local $aGuiSecsX2 = _GuiPanel(01, 55, 35, 115, 010, 5) ; Seconds blink
Local $aGuiHourX5 = _GuiPanel(04, 55, 35, 025, 055, 5) ; Hours * 5
Local $aGuiHourX1 = _GuiPanel(04, 55, 35, 025, 100, 5) ; Hours
Local $aGuiMinsX5 = _GuiPanel(11, 16, 35, 025, 145, 6) ; Mins * 5
Local $aGuiMinsX1 = _GuiPanel(04, 55, 35, 025, 190, 5) ; Mins
GUISetBkColor("0x9A9A9A", $hGui)
GUISetState(@SW_SHOW)

Do
    If @SEC <> $iSec Then ; when the second changes do what following
        $iSec = @SEC
        GUICtrlSetBkColor($aGuiSecsX2[1], $aColors[@SEC / 2 = Int(@SEC / 2)]) ; second blink
        If @MIN <> $iMin Then
            $iMin = @MIN
            For $i = 1 To 11
                If $i < 5 Then
                    GUICtrlSetBkColor($aGuiHourX5[$i], $aColors[2 * (Int(@HOUR / 5) >= $i)])
                    GUICtrlSetBkColor($aGuiHourX1[$i], $aColors[2 * (Mod(@HOUR, 5) >= $i)])
                    GUICtrlSetBkColor($aGuiMinsX1[$i], $aColors[Mod(@MIN, 5) >= $i])
                EndIf
                GUICtrlSetBkColor($aGuiMinsX5[$i], $aColors[(Int(@MIN / 5) >= $i) * (1 + ($i = 3 Or $i = 6 Or $i = 9))])
            Next
        EndIf
    EndIf
Until GUIGetMsg() = -3 ; $GUI_EVENT_CLOSE
End()

Func _GuiPanel($nrPerLine, $ctrlWidth, $ctrlHeight, $xPanelPos, $yPanelPos, $xSpace = 1)
    ; create the controls
    Local $aGuiGridCtrls[$nrPerLine + 1]
    For $i = 1 To $nrPerLine
        $left = $xPanelPos + ((($ctrlWidth + $xSpace) * ($i - 1)) - $xSpace)
        $aGuiGridCtrls[$i] = GUICtrlCreateInput("", $left, $yPanelPos, $ctrlWidth, $ctrlHeight, 0x0800) ; 0x0800 = $ES_READONLY
        GUICtrlSetBkColor(-1, $aColors[0])
    Next
    Return $aGuiGridCtrls
EndFunc   ;==>_GuiPanel

Func End()
    If WinActive($hGui) Then
        GUIDelete($hGui)
        Exit
    EndIf
EndFunc   ;==>End

 

Edited May 20, 2015 by Chimp

[lorenkinzel]

Every bit as cool & fun as the Fibonacci clock.

Much like that one,  I'm not sure if I could deal with it at 5:00 A.M.

Still a neat toy!

[Melba23]

Chimp,

Nice clock.

Sticking with the "mad clock" theme, we had fun with Qlock some years ago.

M23

[Gianni]

@lorenkinzel

thanks

@melba23

that Qlock is very nice! thanks for the link

[GreenCan]

Nice clock Chimp, by the time I have calculated what time it is, we are already 2 minutes later

I like it, makes my brain work...

Small suggestion, I would replace GUICtrlCreateInput by GUICtrlCreateLabel to avoid the blinking cursor in the first box.

GreenCan

[Gianni]

.... by the time I have calculated what time it is, we are already 2 minutes later ...

​Ha..lol.... you are right