TCPServer UDF (multi client, event-based, able to bind console app to socket)

[Jefrey]

Hi guys/girls!

I'm gonna share this UDF I made today.

It allows you to easily create TCP servers and set actions depending on three events: OnConnect, OnDisconnect and OnReceive.

It is also multi client (you can set the clients limit) and you can also bind a Console-based executable to the socket (similar to -e parameter in NetCat). This feature is useful if you want to use some Console UDF to create your TCP server and don't want to mix it with the TCP functions. Also, as it runs on background just firing events, it won't pause your script while listening/receiving, so you can do anything else (stop and restart the server, allow the user to click buttons or just wait on an infinite loop) that your callbacks will be called once the event is fired.

It's also very easy to use. See this examples:

Example #1: A basic server

By running this (then connecting to the server using Netcat), you will receive a message box telling you when some user connects or disconnects (the socket ID and his IP address is passed as parameter to your callback function) and also when the user sends something over the TCP socket (the data sent is passed as parameter).

expandcollapse popup

#cs
    Download netcat at https://eternallybored.org/misc/netcat/
    Execute this script
    Run in CMD:
    nc -vv 127.0.0.1 8081
#ce

#include "TCPServer.au3"

; First we set the callback functions for the three events (none of them is mandatory)
_TCPServer_OnConnect("connected")
_TCPServer_OnDisconnect("disconnect")
_TCPServer_OnReceive("received")

; And some parameters
_TCPServer_DebugMode(True)
_TCPServer_SetMaxClients(10)

; Finally we start the server at port 8081 at any interface
_TCPServer_Start(8081)

Func connected($iSocket, $sIP)
    MsgBox(0, "Client connected", "Client " & $sIP & " connected!")
    _TCPServer_Broadcast('new client connected guys', $iSocket)
    _TCPServer_Send($iSocket, "Hey! Write something ;)" & @CRLF)
    _TCPServer_SetParam($iSocket, "will write")
EndFunc   ;==>connected

Func disconnect($iSocket, $sIP)
    MsgBox(0, "Client disconnected", "Client " & $sIP & " disconnected from socket " & $iSocket)
EndFunc   ;==>disconnect

Func received($iSocket, $sIP, $sData, $sPar)
    MsgBox(0, "Data received from " & $sIP, $sData & @CRLF & "Parameter: " & $sPar)
    _TCPServer_Send($iSocket, "You wrote: " & $sData)
    _TCPServer_SetParam($iSocket, 'will write again')
EndFunc   ;==>received

While 1
    Sleep(100)
WEnd

Example #2: A basic HTTP server (just one page, as it is just an example)

In this example, we run this code and point our browser to the address mentioned on the comments. A basic "It works!" page is show.

#cs
    Run this script
    Point your browser to http://localhost:8081/
#ce

#include "TCPServer.au3"

_TCPServer_OnReceive("received")

_TCPServer_DebugMode(True)
_TCPServer_SetMaxClients(10)

_TCPServer_Start(8081)


Func received($iSocket, $sIP, $sData, $sParam)

    _TCPServer_Send($iSocket, "HTTP/1.0 200 OK" & @CRLF & _
                    "Content-Type: text/html" & @CRLF & @CRLF & _
                    "<h1>It works!</h1>" & @CRLF & _
                    "<p>This is the default web page for this server.</p>" & @CRLF & _
                    "<p>However this server is just a 26-lines example.</p>")
    _TCPServer_Close($iSocket)

EndFunc   ;==>received

While 1
    Sleep(100)
WEnd

Example #3: A telnet-like server (Command Prompt bound to the socket after password requesting)

By running this example and connecting with Netcat, we will be asked for a password, which is 12345 as we set on the script. If the password is correct, we will see the Command Prompt live-updated (try running a ping to some server, for example).

expandcollapse popup

#cs
    Download netcat at https://eternallybored.org/misc/netcat/
    Execute this script
    Run in CMD:
    nc -vv 127.0.0.1 8081
#ce

#include "TCPServer.au3"

Global $sPassword = "12345" ; input server password here

_TCPServer_OnConnect("connected")
_TCPServer_OnDisconnect("disconnect")
_TCPServer_OnReceive("received")

_TCPServer_DebugMode(True)
_TCPServer_SetMaxClients(10)

_TCPServer_Start(8081)

Func connected($iSocket, $sIP)
    _TCPServer_Send($iSocket, "Welcome! Please input password: ")
    _TCPServer_SetParam($iSocket, 'login')
EndFunc   ;==>connected

Func disconnect($iSocket, $sIP)
    MsgBox(0, "Client disconnected", "Client " & $sIP & " disconnected from socket " & $iSocket)
EndFunc   ;==>disconnect

Func received($iSocket, $sIP, $sData, $sParam)
    If $sParam = "login" Then
        If $sData <> $sPassword Then
            _TCPServer_Send($iSocket, "Wrong password. Try again: ")
            Return
        Else
            _TCPServer_SetParam($iSocket, 'command')
            _TCPServer_BindAppToSocket($iSocket, 'cmd.exe')
        EndIf
    ElseIf $sParam = "command" Then
        _TCPServer_SendToBound($iSocket, $sData)
    EndIf

EndFunc   ;==>received

While 1
    Sleep(100)
WEnd

The limit is your imagination? Well, no sure. We have this limit:

• You can't create more than one server with this UDF in the same script. However, you can pause and resume (read 'stop and start again') your server at any time in your script, without having to reset the server settings. And of course you can have many clients (or just one, it's your choice!) in the same server. Or run multiple instances.

Functions list:

_TCPServer_Start

_TCPServer_Stop

_TCPServer_Close

_TCPServer_Send

_TCPServer_Broadcast

_TCPServer_SetParam

_TCPServer_BindAppToSocket

_TCPServer_SendToBound

_TCPServer_UnBindAppToSocket

_TCPServer_GetMaxClients

_TCPServer_IsServerActive

_TCPServer_ListClients

_TCPServer_OnConnect

_TCPServer_OnDisconnect

_TCPServer_OnReceive

_TCPServer_SetMaxClients

_TCPServer_DebugMode

_TCPServer_AutoTrim

_TCPServer_SocketToIP

_TCPServer_SocketToConnID

_TCPServer_ConnIDToSocket

 

Help file and more examples included!

Latest version: 1.0.0.1

Download: TCPServer UDF.rar

Changelog

• 1.0 - First release - 18/04/2015
• 1.0.0.1 - Bug fix __TCPServer_Accept internal function / help file recompiled - 26/04/2015

Perhaps you will need to uncompress the file first, so the help file will work.

Fork this on Github: http://github.com/jesobreira/TCPServerUDF

TCPServer UDF.rar

 

Edited December 4, 2015 by Jefrey

[Allow2010]

thanks, looks promising and may be just what i am looking for...

[Allow2010]

Help FIle not working for me (Win8.1 X64)

it opens, and i get a tree with all functions, but no text and the name is still TCPMaker, which might have been a working title

Edited April 18, 2015 by Allow2010

[Jefrey]

Help FIle not working for me (Win8.1 X64)

it opens, and i get a tree with all functions, but no text and the name is still TCPMaker, which might have been a working title

 

Hi, thanks for your reply!

That looks strange... But I've uploaded a HTML version on the original post. Could you test it, please?

[Allow2010]

html version works in firefox but some pictures are missing (icons in the tree) see screenshot, and it ssems as if some info is missing...

Does not work in InternetExplorer.

Edited April 18, 2015 by Allow2010

[Jefrey]

html version works in firefox but some pictures are missing (icons in the tree) see screenshot, and it ssems as if some info is missing...

Does not work in InternetExplorer.

 

As well as some of us say, sometimes documenting is harder than programming

HelpMaker really 'forgot' to put a folder with the graphics used on the page. Luckly I've found this folder on Google. So here is the updated version:

TCPServer HTML Help.rar

[mLipok]

Thanks for sharing.

I add this UDF here:

https://www.autoitscript.com/wiki/User_Defined_Functions#Internet_protocol_suite

[Allow2010]

@Jefrey

Again Thank you for your UDF.

For me there are still symbols missing in the new version oft html help.

If you find a way, i (personally, maybe others see it different) would prefer a working chm file.

Also i would like to have headers for every function in the code explaining parameters, returncodes and what the function does if you are willing to write them...most functions and udfs have them...its often easier to stay in the code while learning...

[coffeeturtle]

Jefrey! Excellent job and thank you for sharing!

I have a dumb question, sorry.

If _TCPServer_Start is only accepting the "port", is it possible to use a different IP Address another way? For example, exposing the server to the internet and thus needing to use the external IP address.

By the way, the help file itself works perfectly!

Thank you again!

Hi guys/girls!

I'm gonna share this UDF I made today.

It allows you to easily create TCP servers and set actions depending on three events: OnConnect, OnDisconnect and OnReceive.

It is also multi client (you can set the clients limit) and you can also bind a Console-based executable to the socket (similar to -e parameter in NetCat). This feature is useful if you want to use some Console UDF to create your TCP server and don't want to mix it with the TCP functions. Also, as it runs on background just firing events, it won't pause your script while listening/receiving, so you can do anything else (stop and restart the server, allow the user to click buttons or just wait on an infinite loop) that your callbacks will be called once the event is fired.

It's also very easy to use. See this examples:

The limit is your imagination? Well, no sure. We have this limit:

• You can't create more than one server with this UDF in the same script. However, you can pause and resume (read 'stop and start again') your server at any time in your script, without having to reset the server settings. And of course you can have many clients (or just one, it's your choice!) in the same server.

Functions list:

_TCPServer_Start

_TCPServer_Stop

_TCPServer_Close

_TCPServer_Send

_TCPServer_Broadcast

_TCPServer_SetParam

_TCPServer_BindAppToSocket

_TCPServer_SendToBound

_TCPServer_UnBindAppToSocket

_TCPServer_GetMaxClients

_TCPServer_IsServerActive

_TCPServer_ListClients

_TCPServer_OnConnect

_TCPServer_OnDisconnect

_TCPServer_OnReceive

_TCPServer_SetMaxClients

_TCPServer_DebugMode

_TCPServer_AutoTrim

_TCPServer_SocketToIP

_TCPServer_SocketToConnID

_TCPServer_ConnIDToSocket

 

Help file and more examples included!

Latest version: 1.0

TCPServer UDF.zip

Note: if the CHM help file does not work for you, use the HTML version below and run index.hta or index.htm.

HTML help.rar

Edited April 20, 2015 by coffeeturtle

[Allow2010]

By the way, the help file itself works perfectly!

 

Hmm, i tried again on win8 and win7 and for me the helpfile does not work...only the tree comes up, but no text on the right side...

[coffeeturtle]

Hmm, i tried again on win8 and win7 and for me the helpfile does not work...only the tree comes up, but no text on the right side...

 

Sorry to ask you this basic question, but do you have all of the files unzipped to one folder? Launching Help.chm from within that folder with all of the files should be good. Otherwise, index.hta would probably be the best option.

[mLipok]

Help FIle not working for me (Win8.1 X64)

it opens, and i get a tree with all functions, but no text and the name is still TCPMaker, which might have been a working title

 

Did you unzip Zip archive , or you just click on downloaded zip file which as I suspect opens in Explorer, and did you open this CHM directly from Zip archive ?

[Allow2010]

Thanks for your idea, i rechecked and found the problem:

I unpacked to my NAS and so i started the chm from an undc path myservermysharefileshelp.chm

Never had this with precompiled chm files...maybe this is because you reference some files from inside the chm and they can not be found on und path.

This seems to be a problem...from a alocal folder the chm works fine. Sorry for causing troubles...

[mLipok]

This is IExplorer security issue.

Edit: 

This is related to: security zones

Edited April 23, 2015 by mLipok

[Allow2010]

Func __TCPServer_Accept()
    If $__TCPServer_Sockets[0] >= $_TCPServer_MaxClients Then
        ;Return
    EndIf
    $accept = TCPAccept($__TCPServer_MainSocket)
    If $accept = -1 Then Return
    For $i = 1 To $_TCPServer_MaxClients
        If $__TCPServer_Sockets[$i] = 0 Then ; socket is empty
            $__TCPServer_Sockets[$i] = $accept
            $__TCPServer_Sockets[0] += 1
            $__TCPServer_SocketCache[$i][0] = $accept
            $__TCPServer_SocketCache[$i][1] = _TCPServer_SocketToIP($accept)
            If $_TCPServer_DebugMode Then __TCPServer_Log("Client " & _TCPServer_SocketToIP($accept) & " connected to socket " & $accept)
            Call($_TCPServer_OnConnectCallback, $__TCPServer_Sockets[$i], _TCPServer_SocketToIP($__TCPServer_Sockets[$i]))
            Return 0
        EndIf
    Next
EndFunc   ;==>__TCPServer_Accept

i think the ;retrun must be uncommented...else the maxlients limit is ignored...?!

[Jefrey]

Hi, sflr, I've been busy with some things in college. Good to see that your problem was solved,  @Allow2010! Thanks for those who helped! As soon as I get some time again, I'll document it on the UDF itself (each function).

@coffeeturtle,

If _TCPServer_Start is only accepting the "port", is it possible to use a different IP Address another way? For example, exposing the server to the internet and thus needing to use the external IP address.

Yes! By default, _TCPServer_Start will listen on 0.0.0.0, which, theoretically, will listen in any interface. But if you want to listen in other interface, like the external IP, just pass it as second (optional) parameter:

#include <Inet.au3>
#include "TCPServer.au3"

_TCPServer_Start(8081, _GetIP())

; or 

_TCPServer_Start(8082, '127.0.0.1')

_TCPServer_Start(8083, 'mydomain.no-ip.com')

Of course there are other questions to consider, like if the port is visible to the internet (open and redirected to the host in the router).

@Allow2010,

 think the ;retrun must be uncommented...else the maxlients limit is ignored...?!

Damn... how could it pass in front of me... I commented it for debugging while developing it. It must be uncommented, you're right. I must upload the patched version ASAP to the original post. Thanks for pointing it!

Edit: UDF updated on the original post!

Edited April 26, 2015 by Jefrey

[LukeLe]

@Jefrey Thank you for the excellent work & sharing!

FYI, I'm working on a project that makes a Socket Relay, it receives data from clients (for example, 2 clients) then pass received data to destinations (e.g 3)

I have one question related to the TCPRcv

Func __TCPServer_Recv()
    For $i = 1 To $_TCPServer_MaxClients
        If ($__TCPServer_Sockets[$i] = 0) Then ContinueLoop ;If socket is not exist then move to the next entry

        Dim $sData
        $recv = TCPRecv($__TCPServer_Sockets[$i], 1000000)
        If @error = 10054 Then ; Disconnected by user
            __TCPServer_KillConnection($i)
            ContinueLoop
        EndIf

        If $recv Then
            $sData = $recv
            Do
                $recv = TCPRecv($__TCPServer_Sockets[$i], 1000000)
                $sData &= $recv
            Until $recv = ""
            If $_TCPServer_AutoTrim Then
                $sData = StringStripWS($sData, 1 + 2)
            EndIf
            If $_TCPServer_DebugMode Then __TCPServer_Log("Client " & _TCPServer_SocketToIP($__TCPServer_Sockets[$i]) & " sent " & $sData)
            Call($_TCPServer_OnReceiveCallback, $__TCPServer_Sockets[$i], _TCPServer_SocketToIP($__TCPServer_Sockets[$i]), $sData, $__TCPServer_Pars[$i])
            
        EndIf
    Next
EndFunc   ;==>__TCPServer_Recv

May I ask, after getting data from $recv = TCPRecv($__TCPServer_Sockets[$i], 1000000)

you call another TCPRecv($__TCPServer_Sockets[$i], 1000000) until it has no data.
What does this thing do?
If I remove the Do...Util block, does it has any risk?

Edited June 28, 2019 by LukeLe
add full function __TCPServer_Recv