can _GUICtrlListView_GetSelectedIndices distinguish between selected or not?

[MuffettsMan]

running the following code on a listview that has nothing selected:

$selectedRow = _GUICtrlListView_GetSelectedIndices($GUI_BackupQueueListView) ; return the selected row
      ConsoleWriteGUI("$selectedRow ID: " & $selectedRow & @CRLF)

      $rowID = _GUICtrlListView_GetItemText($GUI_BackupQueueListView, Number($selectedRow), 0)
      $rowName = _GUICtrlListView_GetItemText($GUI_BackupQueueListView, Number($selectedRow), 1)
      ConsoleWriteGUI("ID: " & $rowID & " Name: " & $rowName & @CRLF)

i was hoping it would error or something but it returns the first value in the list (which when the script loads nothing is selected)

is there a way to distinguish if something is selected or not?

[MuffettsMan]

so basically, how can i tell if the first row is selected or no row is selected?

[Melba23]

MuffettsMan,

You need to check the returned value from the function. If using the default string return, you get an empty string if nothing is selected - if using the array return, the [0] element gives the count of selected items. This works fine for me:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <GuiListView.au3>

$hGUI = GUICreate("Test", 500, 500)

$cLV = GUICtrlCreateListView("Column", 10, 10, 200, 200)
For $i = 0 To 9
    GUICtrlCreateListViewItem("Item " & $i, $cLV)
Next

$cButton = GUICtrlCreateButton("Selected", 10, 300, 80, 30)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            $sSel = _GUICtrlListView_GetSelectedIndices($cLV)
            MsgBox($MB_SYSTEMMODAL, "Selected", "-" & $sSel & "-") ; shows when return is an empty string

            $aSel = _GUICtrlListView_GetSelectedIndices($cLV, True)
            MsgBox($MB_SYSTEMMODAL, "Selected count", $aSel[0]) ; Shows count of selected items
    EndSwitch
WEnd

All this is clearly explained in the Help file.

M23

[MuffettsMan]

Thx Melba,  I think the definition of clearly starts to degrade when you don't know what you are doing  - I must have jacked up when using Number($selectedRow) instead $selectedRow[0] like I should have been using looking at it now i don't know what i was thinking

 

Edit:

blaugh i think i get it... the code was doing what i said not what i meant....  when i did the number($var) of a null it prob just sets it to 0 - no where did i actually check to see if it was legit /sigh

Edited April 16, 2015 by MuffettsMan

[Melba23]

MuffettsMan,

 

the code was doing what i said not what i meant

Yup, always annoying when the code refuses to read your mind and just executes exactly what you told it to do.

M23

[MuffettsMan]

autoit feature / enhancement request - mind reader UDF... aka the birth of skynet!