AudBox

[Wombat]

I've started making tools for myself to lighten the work load while writing code.

 

This is one such tool I've made I thought others might like to use/fork for anything they may be working on.

AudBox is a combination of three functions into one.

• MsgBox
• SoundPlay
• SoundSetWaveVolume

It shortens the code necessary to present a visual and audible notification to the user, with options for built-in defaults for fast coding as well as volume control over the audio.

 

The snippet is as follows:

 

expandcollapse popup

#include-once

; #FUNCTION# =========================================================================================================
; Name...........: _AudBox
; Description ...: Creates a notification combination of MsgBox and SoundPlay with volume control
; Syntax.........: _AudBox($flg, $Title, $txt, [$timeout, [$guiHWND, [$Aud, [$wait, [ $Volume]]]]])
; Requirement(s).: v3.2.12.1 or higher
; Author ........: Wombat
; Example........; No
;=====================================================================================================================

Func _AudBox($flg, $Title, $txt, $timeout=0, $guiHWND='', $Aud=1, $wait=0, $Volume=0)

    Local $auFLAG, $auTITLE, $auTEXT, $auTIMEOUT, $auHWnd=$guiHWND, $auSOUND, $auWAIT, $MsgRet

    ;Set the flag

    If $flg='' Then
        $auFLAG=0
    Else
        $auFLAG=$flg
    EndIf

    ;Set the title

    Switch $Title
        Case 1
            $auTITLE="Windows Notification"
        Case 2
            $auTITLE=@ScriptName & " - Error!"
        Case 3
            $auTITLE=@ScriptName & " - Attention!"
        Case 4
            $auTITLE=@ScriptName & " - Done!"
        Case 5
            $auTITLE=@UserName & ", please contact an administrator!"
        Case Else
            If IsString($Title) Then
                $auTITLE=$Title
            Else
                If $Title=Default Then $auTITLE=@ScriptName

                If $Title='' Then $auTITLE=@ScriptName
            EndIf

    EndSwitch

    ;Set the text

    If $txt='' Then
        If Not @Compiled Then ConsoleWriteError("ERROR! - _AudBox() function was not provided with text" & @CRLF)
        Return SetError(1, 3, "No text provided")
    Else
        $auTEXT=$txt
    EndIf

    ;Set the timeout

    If $timeout=Default Then
        $auTIMEOUT=0
    Else
        $auTIMEOUT=$timeout
    EndIf

    ;Set the audio

    Switch $Aud
        Case 2
            $auSOUND = @WindowsDir & "\Media\Windows Error.wav"
        Case 3
            $auSOUND = @WindowsDir & "\Media\Windows Notify.wav"
        Case 4
            $auSOUND = @WindowsDir & "\Media\Windows Ding.wav"
        Case 5
            $auSOUND = @WindowsDir & "\Media\Windows User Account Control.wav"
        Case 6
            $auSOUND = @WindowsDir & "\Media\Windows Balloon.wav"
        Case 7
            $auSOUND = @WindowsDir & "\Media\Windows Default.wav"
        Case 8
            $auSOUND = @WindowsDir & "\Media\Windows Exclamation.wav"
        Case 9
            $auSOUND = @WindowsDir & "\Media\Windows Navigation Start.wav"
        Case Else
            $auSOUND=$Aud
    EndSwitch

    ;Set the wait behavior

    If $wait=Default Then
        $auWAIT=0
    Else
        $auWAIT=$wait
    EndIf

    ;Set volume

    If $Volume=Default Then
        SoundSetWaveVolume(15)
    Else
        SoundSetWaveVolume($Volume)
    EndIf

    SoundPlay($auSOUND, $auWAIT)
    $MsgRet = MsgBox($auFLAG, $auTITLE, $auTEXT, $auTIMEOUT, $auHWnd)
    Return $MsgRet

EndFunc

 

An example of it's use:

#include "AudBox.au3"

$test="This is a test"


;    _AudBox Parameters:
;
;   1.) MsgBox parameter FLAG
;   2.) MsgBox parameter TITLE
;   3.) MsgBox parameter TEXT
;   4.) MsgBox parameter TIMEOUT
;   5.) MsgBox parameter HWND
;
;   6.) SoundPlay parameter Audio file path
;   7.) SoundPlay parameter wait option
;   
;   8.) SoundSetWaveVolume parameter volume percent
;       
;   _AudBox(1, 2, 3, 4, 5, 6, 7, 8)



_AudBox(0, 2, $test, 10, Default, 2, 0, 100)

Exit

I use it in some of my scripts, maybe someone else will enjoy it.

Let me know if you see any mistakes/opportunities.

 

 

Changelog - 4/14/2015

 - Added Switch's where applicable.

Changelog - 4/13/2015

 - Added UDF information section to support easy calltip creation via the calltip manager in scite.

AudBox.au3

Edited April 14, 2015 by Wombat

[JohnOne]

Things like...

If $Aud=1 Then $auSOUND=@WindowsDir & "\Media\chimes.wav"

        If $Aud=2 Then $auSOUND=@WindowsDir & "\Media\Windows Error.wav"

        If $Aud=3 Then $auSOUND=@WindowsDir & "\Media\Windows Notify.wav"

        If $Aud=4 Then $auSOUND=@WindowsDir & "\Media\Windows Ding.wav"

        If $Aud=5 Then $auSOUND=@WindowsDir & "\Media\Windows User Account Control.wav"

        If $Aud=6 Then $auSOUND=@WindowsDir & "\Media\Windows Balloon.wav"

        If $Aud=7 Then $auSOUND=@WindowsDir & "\Media\Windows Default.wav"

        If $Aud=8 Then $auSOUND=@WindowsDir & "\Media\Windows Exclamation.wav"

        If $Aud=9 Then $auSOUND=@WindowsDir & "\Media\Windows Navigation Start.wav"

You should use If,, elseIf 

Or a switch case block, otherwise you are making a lot of comparisons that are not needed.

[Wombat]

Things like...

If $Aud=1 Then $auSOUND=@WindowsDir & "\Media\chimes.wav"

        If $Aud=2 Then $auSOUND=@WindowsDir & "\Media\Windows Error.wav"

        If $Aud=3 Then $auSOUND=@WindowsDir & "\Media\Windows Notify.wav"

        If $Aud=4 Then $auSOUND=@WindowsDir & "\Media\Windows Ding.wav"

        If $Aud=5 Then $auSOUND=@WindowsDir & "\Media\Windows User Account Control.wav"

        If $Aud=6 Then $auSOUND=@WindowsDir & "\Media\Windows Balloon.wav"

        If $Aud=7 Then $auSOUND=@WindowsDir & "\Media\Windows Default.wav"

        If $Aud=8 Then $auSOUND=@WindowsDir & "\Media\Windows Exclamation.wav"

        If $Aud=9 Then $auSOUND=@WindowsDir & "\Media\Windows Navigation Start.wav"

You should use If,, elseIf 

Or a switch case block, otherwise you are making a lot of comparisons that are not needed.

 

This is exactly why I posted it, feedback's what i needed. I agree a switch case block would be best here. Honestly the code was written quick and dirty and could use a little tlc.

Thanks for the comment.

[mLipok]

I would suggest this approch:

Switch $Aud
    Case 2
        $auSOUND = @WindowsDir & "\Media\Windows Error.wav"
    Case 3
        $auSOUND = @WindowsDir & "\Media\Windows Notify.wav"
    Case 4
        $auSOUND = @WindowsDir & "\Media\Windows Ding.wav"
    Case 5
        $auSOUND = @WindowsDir & "\Media\Windows User Account Control.wav"
    Case 6
        $auSOUND = @WindowsDir & "\Media\Windows Balloon.wav"
    Case 7
        $auSOUND = @WindowsDir & "\Media\Windows Default.wav"
    Case 8
        $auSOUND = @WindowsDir & "\Media\Windows Exclamation.wav"
    Case 9
        $auSOUND = @WindowsDir & "\Media\Windows Navigation Start.wav"
    Case Else
        ; do something
EndSwitch

[Wombat]

Original post edited to include switches and a change-log to better track edits.

Attached script also updated.

[JohnOne]

Something you might want to think about.

Switch $Title
        Case 1
            $auTITLE="Windows Notification"
        Case 2
            $auTITLE=@ScriptName & " - Error!"
        Case 3
            $auTITLE=@ScriptName & " - Attention!"
        Case 4
            $auTITLE=@ScriptName & " - Done!"
        Case 5
            $auTITLE=@UserName & ", please contact an administrator!"
        Case Else
            If IsString($Title) Then
                $auTITLE=$Title
            Else
                If $Title=Default Then $auTITLE=@ScriptName

                If $Title='' Then $auTITLE=@ScriptName ; This '' is a string, so should really be processed in the If condition rather than the else condition
            EndIf

    EndSwitch