CmdLine UDF (get value/existence/flag)

[Jefrey]

I wrote this very simple functions to parse command line arguments.

It can get:

Simple key/value

Example. The following code:

#include "cmdline.au3"

MsgBox(0, _CmdLine_Get('color'))

Will return "white" if you run the script in one of these ways (quotes are optional but mandatory if you're going to use spaces):

• script.exe -color "white"
• script.exe --color white
• script.exe /color white

Existence

Example. The following code:

#include "cmdline.au3"

If _CmdLine_KeyExists('givemecoffee') Then
   ConsoleWrite('You want coffee.')
Else
   ConsoleWrite('You do not want coffee.')
EndIf

Will return "You want coffee." if you run one of these:

• script.exe -givemecoffee
• script.exe --givemecoffee
• script.exe /givemecoffee

And the following code:

#include "cmdline.au3"

If _CmdLine_ValueExists('givemecoffee') Then
   ConsoleWrite('You want coffee.')
Else
   ConsoleWrite('You do not want coffee.')
EndIf

Will return "You want coffee." if you run one of these:

• script.exe givemecoffee
• script.exe "givemecoffee"

Flags

Example. This script:

#include "cmdline.au3"

ConsoleWrite("You want: ")

If _CmdLine_FlagEnabled('C') Then
  ConsoleWrite("coffee ")
EndIf

If _CmdLine_FlagEnabled('B') Then
   ConsoleWrite("beer ")
EndIf

ConsoleWrite(" and you do not want: ")

If _CmdLine_FlagDisabled('V') Then
  ConsoleWrite("vodka ")
EndIf

If _CmdLine_FlagDisabled('W') Then
   ConsoleWrite("wine ")
EndIf

ConsoleWrite(" but you did not tell me if you want: ")

If Not _CmdLine_FlagExists('S') Then
   ConsoleWrite("soda ")
EndIf

If Not _CmdLine_FlagExists('J') Then
   ConsoleWrite("juice ")
EndIf

Will return "You want: coffee beer  and you do not want: vodka wine  but you did not tell me if you want: soda juice" if you run:

• script.exe +CB -VW

Getting argument by its index

You can also read the $CmdLine (1-based index) through this function. The advantage is that if the index does not exist (the user did not specify the argument), it won't break your script. It will just return the value you specify in the second function parameter.

#include "cmdline.au3"

$first_argument = _CmdLine_GetValByIndex(1, False)

If Not $first_argument Then
   ConsoleWrite("You did not specify any argument.")
Else
   ConsoleWrite("First argument is: " & $first_argument)
EndIf

Just a note: The second value of _CmdLine_GetValByIndex function can be an integer value, a string, a boolean value, an array or anything you want it to return if the index does not exist in $CmdLine array.

This parameter is also available in _CmdLine_Get() function, also as a second function parameter. In this case, it will return this value if the key was not found. Example:

#include "cmdline.au3"

$user_wants = _CmdLine_Get("iwant", "nothing")

ConsoleWrite("You want " & $user_wants)

So, if you run:

• script.exe /iwant water

It will return "You want water". But if you run just:

• script.exe

It will return "You want nothing". Please note that, as these two are the only functions in this library meant to return strings, the second parameter is not available for the other functions. By default, if you do not specify any fallback value, it returns null if the wanted value could not be found.

Also, please note that this UDF can NOT parse arguments in the format (key=value). Example:

• script.exe key=value IT WILL NOT WORK

 

Here is the code:

expandcollapse popup

#include-once

#comments-start
   CmdLine small UDF
   coder: Jefrey (jefrey[at]jefrey.ml)
#comments-end

Func _CmdLine_Get($sKey, $mDefault = Null)
   For $i = 1 To $CmdLine[0]
      If $CmdLine[$i] = "/" & $sKey OR $CmdLine[$i] = "-" & $sKey OR $CmdLine[$i] = "--" & $sKey Then
         If $CmdLine[0] >= $i+1 Then
            Return $CmdLine[$i+1]
         EndIf
      EndIf
   Next
   Return $mDefault
EndFunc

Func _CmdLine_KeyExists($sKey)
   For $i = 1 To $CmdLine[0]
      If $CmdLine[$i] = "/" & $sKey OR $CmdLine[$i] = "-" & $sKey OR $CmdLine[$i] = "--" & $sKey Then
         Return True
      EndIf
   Next
   Return False
EndFunc

Func _CmdLine_ValueExists($sValue)
   For $i = 1 To $CmdLine[0]
      If $CmdLine[$i] = $sValue Then
         Return True
      EndIf
   Next
   Return False
EndFunc

Func _CmdLine_FlagEnabled($sKey)
   For $i = 1 To $CmdLine[0]
      If StringRegExp($CmdLine[$i], "\+([a-zA-Z]*)" & $sKey & "([a-zA-Z]*)") Then
         Return True
      EndIf
   Next
   Return False
EndFunc

Func _CmdLine_FlagDisabled($sKey)
   For $i = 1 To $CmdLine[0]
      If StringRegExp($CmdLine[$i], "\-([a-zA-Z]*)" & $sKey & "([a-zA-Z]*)") Then
         Return True
      EndIf
   Next
   Return False
EndFunc

Func _CmdLine_FlagExists($sKey)
   For $i = 1 To $CmdLine[0]
      If StringRegExp($CmdLine[$i], "(\+|\-)([a-zA-Z]*)" & $sKey & "([a-zA-Z]*)") Then
         Return True
      EndIf
   Next
   Return False
EndFunc

Func _CmdLine_GetValByIndex($iIndex, $mDefault = Null)
   If $CmdLine[0] >= $iIndex Then
      Return $CmdLine[$iIndex]
   Else
      Return $mDefault
   EndIf
EndFunc

Edited April 18, 2015 by Jefrey

[mLipok]

Thanks for sharing
Very useful UDF.

mLipok

 

btw:
added here , and please fix your signature.

 

Edit:

Can you make a zip with your UDF and post it to this thread or As described herein or here

Edited May 9, 2015 by mLipok

[robertocm]

Dear Jefrey,

Many Thanks,

Let me share a version of some of your examples trying to get StdOut from ConsoleWrite in Uncompiled scripts

save this as 01_child.au3

#include "cmdline.au3"

Local $Output = _CmdLine_Get('color')
MsgBox(0, "", $Output)
ConsoleWrite($Output)

save this as 01_main.au3

#include <Constants.au3>

#cs ----------------------------------------------------------------------------
Will return "white" if you run the script in one of these ways
(quotes are optional but mandatory if you're going to use spaces)
#ce ----------------------------------------------------------------------------
Local $sFilePath = '"' & @ScriptDir & '\01_child.au3"'
RunWait(@AutoItExe & " " & $sFilePath & ' -color "white"')

RunWait(@AutoItExe & " 01_child.au3" & ' -color white')

RunWait(@AutoItExe & " 01_child.au3" & ' --color white')
RunWait(@AutoItExe & " 01_child.au3" & ' /color white')

$iPID = Run(@AutoItExe & " /AutoIt3ExecuteScript " & "01_child.au3" & ' /color "white cafe"', "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
ProcessWaitClose($iPID)
Local $sOutput = ""
$sOutput = StdoutRead($iPID)
MsgBox(0, "Stdout Read", "Stdout Read: " & @CRLF & $sOutput)
ConsoleWrite($sOutput & @CRLF)

 

And this could be for example 04:

create 04_child.au3 in the same way as explained above

and save below code as 04_main.au3

#include <Constants.au3>

#cs ----------------------------------------------------------------------------
Flags
Will return "You want: coffee beer  and you do not want: vodka wine  but you did not tell me if you want: soda juice" if you run:
    script.exe +CB -VW
#ce ----------------------------------------------------------------------------

;Local $sFilePath = '"' & @ScriptDir & '\04_child.au3"'
;Local $iPID = Run(@AutoItExe & " /AutoIt3ExecuteScript " & $sFilePath & ' +CB -VW', "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
Local $iPID = Run(@AutoItExe & " /AutoIt3ExecuteScript " & "04_child.au3" & ' +CB -VW', "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

;This would be if compiled:
;Local $iPID = Run(@ComSpec & " /C 04_child.exe +CB -VW", @ScriptDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

ProcessWaitClose($iPID)
Local $sOutput = ""
$sOutput = StdoutRead($iPID)
MsgBox(0, "Stdout Read", "Stdout Read: " & @CRLF & $sOutput)
ConsoleWrite($sOutput & @CRLF)

 

Edited December 25, 2016 by robertocm