Rename all folders in a directory

[Yuljup]

Greetings 

I've read a few threads here about bulk renaming of files, but I haven't quite found what I'm looking for.

I'm trying to rename all folders in a directory. Lets say my source directory is the following:

servershare$

Is it possible to list all folders in this directory and add something to each subfolder name? - For example: _renamed

 

View of source directory: servershare$

Directory before bulk rename:

Folder1

Folder2

Folder3

Directory after bulk rename:

Folder1_renamed

Folder2_renamed

Folder3_renamed

 

Any help would be much appreciated 

[l3ill]

_FileListToArray

DirMove

[Yuljup]

l3ill,

 

Thanks for getting back to me.

I'm sorry, but I'm not too experienced with AutoIt.

How would you go about using these two functions for this?

Would I have to use DirMove on every row or something?

Could you please give me an example to point me in the right direction?

[TheDcoder]

#include <Array.au3>

Global $aFolders = _FileListToArray($sPath, '*', 2, True)

Global $sSuffix = '_renamed'

For $i = 1 To Ubound($aFolders) - 1
    DirMove($aFolders[$i], $aFolders[$i] & $sSuffix)
Next

TD

Edited April 9, 2015 by TheDcoder

[Yuljup]

TheDcoder,

 

Fantastic! This is exactly what I needed 

I modified it a little bit:

#include <Array.au3>
#include <File.au3>

BulkRename()
Func BulkRename()
    $sPath = "C:\Temp"
    $aFolders = _FileListToArray($sPath, '*', 2, True)

    Global $sSuffix = '_renamed'

    For $i = 0 To Ubound($aFolders) - 1
        DirMove($aFolders[$i], $aFolders[$i] & $sSuffix)
    Next
EndFunc

Thank you!

[guinness]

Global variables should be declared outside of a function and as this is Local. I have no clue why TheDcoder used Global for the first variable and not the second.

This is better... 

#include <File.au3>

BulkRename()

Func BulkRename()
    Local $sPath = "C:\Temp"
    Local $aFolders = _FileListToArray($sPath, '*', $FLTA_FOLDERS, True)
    If @error Then Return False ; If an error occurred

    Local $sSuffix = '_renamed'

    For $i = 1 To $aFolders[0]
        DirMove($aFolders[$i], $aFolders[$i] & $sSuffix)
    Next
    Return True
EndFunc 

I think both of you could benefit from reading this >> https://www.autoitscript.com/wiki/Variables_-_using_Global,_Local,_Static_and_ByRef

There is also a bug in there code, as it starts from 1 in the array NOT 0.

Edited April 9, 2015 by guinness

[TheDcoder]

I have no clue why TheDcoder used Global for the first variable and not the second

Oops.... I was in a hurry, so I had to write the code here (i.e write code between code tags) and I didn't notice that first variable was un-declared

Hope it explains why I did it, TD

[guinness]

But there is also a bug in your code whereby you access the first element which contains the count of the array and not the first folder name.

[TheDcoder]

@guinness Sorry, Didn't notice that in the online documentation

[l3ill]

Its more a Ubound thing. Ubound counts by default all of the positions of the array including the index (first position) the amount of array elements.

So basically you are trying to rename the arrays index...

(Sometimes seen as Ubound - 1)

See Remarks Ubound

cya

Bill

[BrewManNH]

Its more a Ubound thing. Ubound counts by default all of the positions of the array including the index (first position) the amount of array elements.

The error had nothing to do with UBound, it was because the original script started the For loop at 0, and the array returned from the function keeps the file count in the [0] array element.

 

(Sometimes seen as Ubound - 1)

 

See Remarks Ubound

 

cya

Bill

This doesn't apply either, the For loop was written correctly, other than starting at 0, because UBound counts all the elements in the array, but because arrays are zero based a 10 item array runs from 0 to 9 and not 0 to 10, which is why you have to use UBound($array) - 1. If you don't do that, you're counting to one element past the end of the array and you'd get an array out of bounds error.

[jguinch]

Also, the "classic" way :

_RenameFoldersWithSuffix("C:\Temp", "_renamed")

Func _RenameFoldersWithSuffix($sFolder, $sSuffix)
    Local $sFilename
    Local $hDirs = FileFindFirstFile($sFolder & "\*")
    While 1
        $sFilename = FileFindNextFile($hDirs)
        If @error Then ExitLoop
        If @extended AND NOT DirMove($sFolder & "\" & $sFilename, $sFolder & "\" & $sFilename & $sSuffix) Then Return 0
    WEnd
    Return 1
EndFunc

[l3ill]

@ Brewman - My post was just pointing TD to the Online Documentation that shows guinness' point about the bug he mentioned.

But thanks for your clarification ...;-)

[guinness]

I was under the same impression as BrewManNH, that you were pointing out the issue with UBound and not starting from index 0.