REGEX help

[Sea]

Hi everybody I would like to have a regex for this file
 
 

; extension = bfb
; cost_per_hour = 0
; g_code_prefix = 5E4669726D776172653A56312E30370A3B205B6D6D5D
;     206D6F64650A4732310A3B206162736F6C757465206D6F64650A4739
;     300A
; fan_off = M107
; z_speed_mm_per_s = 2.5
; bed_offset_x_mm = -35

I want an array like that '>.

I succes to read each line with StringRegExp($Value, "(w+)(?: = )(.+)", 3) but it fail with multiline for g_code_prefix.

Thanks you in advance

Edited April 7, 2015 by Sea

[jguinch]

One way :

#Include <Array.au3>

$sString = "extension = bfb" & @CRLF & _
           "cost_per_hour = 0" & @CRLF & _
           "g_code_prefix = 5E4669726D776172653A56312E30370A3B205B6D6D5D" & @CRLF & _
           "    206D6F64650A4732310A3B206162736F6C757465206D6F64650A4739" & @CRLF & _
           "    300A" & @CRLF & _
           "fan_off = M107" & @CRLF & _
           "z_speed_mm_per_s = 2.5" & @CRLF & _
           "bed_offset_x_mm = -35"
           
$aLines = StringRegExp( StringRegExpReplace($sString, "\R\h+", "") , "\N+", 3)

_ArrayDisplay($aLines)

[Sea]

Thanks but that's mean I need to edit my data before process them I don't really like this.

And I don't have variable_name and value separated.

But its a nice idea to add a StringRegExpReplace

Edited April 7, 2015 by Sea

[jchd]

Another:

#include <Array.au3>

Local $sInput = _
"; extension = bfb" & @CRLF & _
"; cost_per_hour = 0" & @CRLF & _
"; g_code_prefix = 5E4669726D776172653A56312E30370A3B205B6D6D5D" & @CRLF & _
";     206D6F64650A4732310A3B206162736F6C757465206D6F64650A4739" & @CRLF & _
";     300A" & @CRLF & _
"; fan_off = M107" & @CRLF & _
"; z_speed_mm_per_s = 2.5" & @CRLF & _
"; bed_offset_x_mm = -35" & @CRLF       ; this last line break optional

$sInput = StringRegExpReplace($sInput, "\R;\s{2,}", "")
ConsoleWrite($sInput & @LF)

Local $aOutput = StringRegExp($sInput, "(?mx) ^ ; \s+ (\w+) \s+ = \s+ (.+) $", 3)
If Not @error Then
    Local $aResult[UBound($aOutput) / 2][2]
    For $i = 0 To UBound($aResult) - 1
        $aResult[$i][0] = $aOutput[2 * $i]
        $aResult[$i][1] = $aOutput[2 * $i + 1]
    Next
    _ArrayDisplay($aResult)
Else
    ConsoleWrite("Non-conformal input." & @LF)
EndIf

[jguinch]

ouups, sorry I didn't copy the ";" at the beginning of each line....

so, another attempt :

#Include <Array.au3>

$sContent = FileRead("file.txt")
$aLines = StringRegExp( StringRegExpReplace($sContent, "(?:\R;\h{2,}|(?<=\n|^);\h+)", "") , "\N+", 3)
_ArrayDisplay($aLines)

Edited April 7, 2015 by jguinch

[jchd]

And the leading '; ' ???

[Sea]

Amazing jchd thanks you a lot.

Local $aOutput = StringRegExp($sInput, "(?mx) ^ ; \s+ (\w+) \s+ = \s+ (.+) $", 3)

can you explain it plz? ^^'

MX => multi lines so new line is determinated by a ; ?

Why $ in the end?

Thanks you its really what I need

Btw thanks you too jguinch but I prefer the jchd output

[jchd]

This useful site explains it all thusly:

/(?mx) ^ ; \s+ (\w+) \s+ = \s+ (.+) $/

    (?mx) Match the remainder of the pattern with the following options:
        m modifier: multi-line. Causes ^ and $ to match the begin/end of each line (not only begin/end of string)
        x modifier: extended. Spaces and text after a # in the pattern are ignored
    ^ assert position at start of a line
    ; matches the character ; literally
    \s+ match any white space character [\r\n\t\f ]
        Quantifier: + Between one and unlimited times, as many times as possible, giving back as needed [greedy]
    1st Capturing group (\w+)
        \w+ match any word character [a-zA-Z0-9_]
            Quantifier: + Between one and unlimited times, as many times as possible, giving back as needed [greedy]
    \s+ match any white space character [\r\n\t\f ]
        Quantifier: + Between one and unlimited times, as many times as possible, giving back as needed [greedy]
    = matches the character = literally
    \s+ match any white space character [\r\n\t\f ]
        Quantifier: + Between one and unlimited times, as many times as possible, giving back as needed [greedy]
    2nd Capturing group (.+)
        .+ matches any character (except newline)
            Quantifier: + Between one and unlimited times, as many times as possible, giving back as needed [greedy]
    $ assert position at end of a line

[Sea]

I din't know this site. Thanks you a lot

[SorryButImaNewbie]

That site looks usefull indeed!

[jchd]

Not only it offers several regex flavors (by default it is PCRE [ = AutoIt] compatible), but you can actually see a pattern at work step by step by hitting "regexp debugger". That's an excellent feature to learn how a pattern backtracks.

Enter g in the option box (right to the pattern box) to mimic our StringRegExp option 3 (global match).