Validate Date (dd.mm.yyyy)

[DarkBanana]

Hello,

I'm currently working on a method that checks if a given date is valid.

My solution looks like this:

Func _Valid($Check)
   $match = StringRegExp($Check,"^(\d{2})\.(\d{2})\.(\d{4})$",1)
   If IsArray($match) then 
      
      If Mod($match[1],2) = 0 And $match[0] > 30 Then Return False
      If Mod($match[1],2) = 1 And $match[0] > 31 Then Return False
         
      If Mod($match[2],4) = 0 And $match[0] > 29 then Return False
      If Mod($match[2],4) <> 0 And $match[0] > 28 then Return False
      
      Return True
   Else
      Return False
   EndIf
  
EndFunc

I haven't included leap years like 1600,2000,2400, which is fine for my purpose.

I wonder if my function works 100% right?

But what I'm really interested in is: What is the most compact function to do this job?

Or how do YOU validate dates?

 

Thanks

[mikell]

https://www.autoitscript.com/autoit3/docs/libfunctions/_DateIsValid.htm

[DarkBanana]

I know that there's a function in the Date library that does this. But it only accepts yyyy.mm.dd right?

So I could convert my format to this format and use _DateIsValid().

But I thought that there is a better or more elegant or more interesting solution!?

[BrewManNH]

From the help file.

 

This function takes a date input in one of the following formats:
"yyyy/mm/dd[ hh:mm[:ss]]" or "yyyy/mm/dd[Thh:mm[:ss]]"
"yyyy-mm-dd[ hh:mm[:ss]]" or "yyyy-mm-dd[Thh:mm[:ss]]"
"yyyy.mm.dd[ hh:mm[:ss]]" or "yyyy.mm.dd[Thh:mm[:ss]]"

[jchd]

As a general rule of thumb, dates and timestamps in IT should only be stored in some computational format (Julian date, Unix epoch, ISO string, etc.) and only converted back and forth for human interface.

[iamtheky]

and you are going to have problems next month

msgbox(0, '' , _Valid("28.04.2015"))
msgbox(0, '' , _Valid("29.04.2015"))
msgbox(0, '' , _Valid("30.04.2015"))


Func _Valid($Check)
   $match = StringRegExp($Check,"^(\d{2})\.(\d{2})\.(\d{4})$",1)



   If IsArray($match) then

      If Mod($match[1],2) = 0 And $match[0] > 30 Then Return False
      If Mod($match[1],2) = 1 And $match[0] > 31 Then Return False

      If Mod($match[2],4) = 0 And $match[0] > 29 then Return False
      If Mod($match[2],4) <> 0 And $match[0] > 28 then Return False

      Return True
   Else
      Return False
   EndIf

EndFunc

And this month, including today, are False as well.   Im pretty sure that says:  if it passes the mod 4 check, every month can only have 28 days.  Which is wrong in every possible way.

Edited March 31, 2015 by boththose

[mikell]

At new year's eve too

msgbox(0, '' , _Valid("31.12.2015"))


Func _Valid($Check)
   $match = StringRegExp($Check,"^(\d{2})\.(\d{2})\.(\d{4})$",1)
   If IsArray($match) then

      If Mod($match[1],2) = 0 And $match[0] > 30 Then Return False
      If Mod($match[1],2) = 1 And $match[0] > 31 Then Return False

      If Mod($match[2],4) = 0 And $match[0] > 29 then Return False
      If Mod($match[2],4) <> 0 And $match[0] > 28 then Return False

      Return True
   Else
      Return False
   EndIf
EndFunc

[jchd]

Corollary to ... myself: first convert data into computer-friendly format as soon as possible, then process it. Only convert it back for display, print ou speech.

[iamtheky]

i didnt see you were also excluding the third criteria of leap-ness.  post #9 would probably hold up then.

Edited March 31, 2015 by boththose

[mikell]

Anyway trying to handle most cases/exceptions you are going to build a more and more complicated function, and end with a nicely reinvented wheel - a  _DateIsValid()-clone func

msgbox(0, '' , _Valid("20.13.2015"))

Edited March 31, 2015 by mikell

[DarkBanana]

#include <Date.au3>

Func _Valid($Check)
   $match = StringRegExp($Check,"^(\d{2})\.(\d{2})\.(\d{4})$",1)
   If IsArray($match) then Return _DateIsValid($match[2] & "." & $match[1] & "." & $match[0])
   Return False
EndFunc

So I should stick to _DateIsValid() and just convert the user input (dd.mm.yyyy) to yyyy.mm.dd right?

[mikell]

Right. Very easy with a little StringRegExpReplace 

[iamtheky]

..while reinventing, where are the gaps here?

msgbox(0, '' , _Valid("28.02.1900"))
msgbox(0, '' , _Valid("29.02.1900"))
msgbox(0, '' , _Valid("28.02.2000"))
msgbox(0, '' , _Valid("29.02.2000"))

Func _Valid($Check)
   $match = StringRegExp($Check,"^(\d{2})\.(\d{2})\.(\d{4})$",1)
   If IsArray($match) then

      If Mod($match[1],2) = 0 And $match[0] > 30 Then Return False
      If Mod($match[1],2) = 1 And $match[0] > 31 Then Return False

      If Mod($match[2],4) = 0 And $match[0]  > 29 And $match[1] = 2 then Return False
      If Mod($match[2],4) = 0 And Mod($match[2],400) And $match[0] > 28 And $match[1] = 2 then Return False
      If Mod($match[2],4) <> 0 And Mod($match[2],400) And $match[0] > 28 And $match[1] = 2 then Return False

      Return True
   Else
      Return False
   EndIf

EndFunc

Edited March 31, 2015 by boththose

[DarkBanana]

I have to admit I don't know where my head is today.There's so much wrong with my previous code  

[mikell]

#include <Date.au3>

msgbox(0, '' , _Valid("31.03.2015"))

Func _Valid($Check)
   Return _DateIsValid(StringRegExpReplace($Check, "^(\d{2})\.(\d{2})\.(\d{4})$", "$3.$2.$1"))
EndFunc

"What is the most compact function to do this job?"

Edited March 31, 2015 by mikell

[DarkBanana]

Yeah that's probably the best solution.

@boththose

Check 31.12.2015

If Mod($match[1],2) = 0 And $match[0] > 30 Then Return False
If Mod($match[1],2) = 1 And $match[0] > 31 Then Return False

This part is totally wrong.

[iamtheky]

easy fix (and i dont think the last),  and it may be a big ugly slow wheel, but at least its new.  and i bet your next is better.

Dont be discouraged from learning how to manipulate the data yourself just because there is a prepackaged solution.  For example, it may be a lot less typing to use an _array function, but they are not the most compact ListView functions.  And I always enjoy seeing alternate solution threads, especially when they devolve into gamesmanship resulting in a ridiculous nested ternary one-liner.

Edited March 31, 2015 by boththose

[mikell]

Agreed, though sometimes the limit is blurred between creativity and wheel reinvention  

[DarkBanana]

Found this ridiculously long regex.

msgbox(0, '' , _Valid("31.03.2015"))
msgbox(0, '' , _Valid("32.03.2015"))
msgbox(0, '' , _Valid("29.02.2015"))
msgbox(0, '' , _Valid("29.02.2000"))
msgbox(0, '' , _Valid("31.12.2015"))

Func _Valid($val)
   Return StringRegExp($val,"(^(((0[1-9]|[12][0-8])[\.](0[1-9]|1[012]))|((29|30|31)[\.](0[13578]|1[02]))|((29|30)[\.](0[4,6,9]|11)))[\.](19|[2-9][0-9])\d\d$)|(^29[\.]02[\.](19|[2-9][0-9])(00|04|08|12|16|20|24|28|32|36|40|44|48|52|56|60|64|68|72|76|80|84|88|92|96)$)")
EndFunc

Seems to work.

I don't know whats going on exactly but hey.

[guinness]

Do you have a link to where you found that regular expression?