how to get the current date from the internet

[Darknightx37]

Hay ther i try to get the current date from the internet for a login system.

for now im using @mon @year ... to get current date but you could easily crack this system.

it would be nice if i could get the current date from a website or something to avoid this problem

if anyone has an idee pls tell me

gretz usbstick

sry for my bad english

[MikahS]

This is very old, but the only example script I could find on the forum that gets time from internet. >Link

[MikahS]

  On 3/31/2015 at 5:41 PM, Darknightx37 said:

hm thx for the fast reply but there is no URL or things like that to get the current time from the internet

or did i missed that part ?

its by IP adresses

Dim $ser[5]=["64.125.78.85","128.138.140.44","132.163.4.102","132.163.4.101","129.6.15.29"]

I know already you'll hit some errors because of version updates to AutoIt, but if you need some help figuring it out let us know. 

EDIT: Melba23's suggestion is very good, will give you a chance to maybe work with IE functionality.

Edited March 31, 2015 by MikahS

[Melba23]

Darknightx37,

Scraping this site ought to be good enough for your needs.

M23

[guinness]

Or use this >> https://www.autoitscript.com/wiki/Snippets_(_Internet_)#GetTimeOnline

[Darknightx37]

  On 3/31/2015 at 5:54 PM, guinness said:

Or use this >> https://www.autoitscript.com/wiki/Snippets_(_Internet_)#GetTimeOnline

well thx alot

[MikahS]

I need to keep your signature on standby guinness.

[guinness]

  On 3/31/2015 at 5:58 PM, MikahS said:

I need to keep your signature on standby guinness.

Haha, yes you do!

[iamtheky]

and NTP

expandcollapse popup

#include <Date.au3>

 msgbox(0, '' , _TimeFromNTP("pool.ntp.org"))

Func _TimeFromNTP($sNTPServer)
    Local $sData = ""
    TCPStartup()
    If TCPNameToIP($sNTPServer) = "" Then Return SetError(1)
    UDPStartup()
    $aSocket = UDPOpen(TCPNameToIP($sNTPServer), 123)
    $sStatus = UDPSend($aSocket, _MakePacket())
    While $sData = ""
        $sData = UDPRecv($aSocket, 100)
        Sleep(250)
    WEnd
    UDPCloseSocket($aSocket)
    TCPShutdown()


    $sValue = _UnsignedHexToDecimal(StringMid($sData, 83, 8))
    $aTimeZone = _Date_Time_GetTimeZoneInformation()

      If $aTimeZone[0] <> 2 Then
        $iTimeZoneOffset = ($aTimeZone[1]) * -1
    Else
        $iTimeZoneOffset = ($aTimeZone[1] + $aTimeZone[7]) * -1
    EndIf

    $sUTC = _DateAdd("s", $sValue, "1900/01/01 00:00:00")

    $sUTC = _DateAdd("n", $iTimeZoneOffset, $sUTC)

    Local $iMonth = StringMid($sUTC, 6, 2), $iDay = StringMid($sUTC, 9, 2), $iYear = StringMid($sUTC, 1, 4), _
    $iHour = StringMid($sUTC, 12, 2), $iMinute = StringMid($sUTC, 15, 2), $iSecond = StringMid($sUTC, 18, 2)

    $sOut = $iMonth & "/" & $iDay & "/" & $iYear & " " & $iHour & ":" & $iMinute & ":" & $iSecond

    return $sOut

EndFunc

Func _MakePacket()
    Local $x, $sPacket = "1b0e01000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000"
    While $sPacket
        $x &= Chr(Dec(StringLeft($sPacket, 2)))
        $sPacket = StringTrimLeft($sPacket, 2)
    WEnd
    Return $x
EndFunc

Func _UnsignedHexToDecimal($sInput)
    $x = StringRight($sInput, 1)
    $sInput = StringTrimRight($sInput, 1)
    Return Dec($sInput) * 16 + Dec($x)
EndFunc

*think i just changed formatting between mine and the original.

Edited March 31, 2015 by boththose

[guinness]

boththose,

Is the code you posted different to the one you linked to? As it's common practice if no changes have been made to just post a link to the working code, thus there is a reduction in duplicate code.

Edited March 31, 2015 by guinness

[iamtheky]

i did change stuff, cant remember all i changed, and a tad busy so i used the also common practice of posting what i know works and linking to where i got it from.

*looks like i must have had an issue with timezone and not liked the output, nor did i need the ability to actually set the time....maybe something else but i think its just moved around rather than changed.

Edited March 31, 2015 by boththose

[Darknightx37]

  On 3/31/2015 at 5:54 PM, guinness said:

Or use this >> https://www.autoitscript.com/wiki/Snippets_(_Internet_)#GetTimeOnline

this is pritty instable cause the server is often not avalebil can you maybe give me an example foranother website like this where i can get the time from a url?

[jchd]

NTP servers are pretty stable and reliable, just because it's their only purpose to be a primary or secondary time server for Internet own time reference.

[guinness]

  On 3/31/2015 at 7:31 PM, Darknightx37 said:

this is pritty instable cause the server is often not avalebil can you maybe give me an example foranother website like this where i can get the time from a url?

What jchd said. Though I have found the site to be stable for me.

[Yashied]

expandcollapse popup

#Include <StructureConstants.au3>
#Include <Date.au3>

Func _NTP_FT($sServer, $fLocal = True)

;~  http://book.itep.ru/4/44/sntp4416.htm

    Local $tNTP = DllStructCreate('byte Header[4];byte RootDelay[4];byte RootDispersion[4];byte ReferenceIdentifier[4];byte ReferenceTimestamp[8];byte OriginateTimestamp[8];byte ReceiveTimestamp[8];byte TransmitTimestamp[8];byte KeyIdentifier[4];byte MessageDigest[16]')
    Local $tPacket = DllStructCreate('byte Packet[68]', DllStructGetPtr($tNTP))
    Local $bPacket = 0, $tFT, $tQW, $aSocket, $aResult

;~  0x1B000000 = 00011011 00000000 00000000 00000000b (LI = 00b VN = 011b Mode = 011b Stratum = 00000000b Poll = 00000000b Precision = 00000000b)
    $tNTP.Header = Binary('0x1B000000')
    UDPStartup()
    If @Error Then
        Return SetError(1, 0, 0)
    EndIf
    $aSocket = UDPOpen(TCPNameToIP($sServer), 123)
    If @Error Then
        ; Nothing
    Else
        UDPSend($aSocket, $tPacket.Packet)
        If @Error Then
            ; Nothing
        Else
            While 1
                $bPacket = UDPRecv($aSocket, 68, 1)
                If (@Error) Or ($bPacket) Then
                    ExitLoop
                EndIf
                Sleep(100)
            WEnd
        EndIf
    EndIf
    UDPCloseSocket($aSocket)
    UDPShutdown()
    If Not $bPacket Then
        Return SetError(2, 0, 0)
    EndIf
    $tFT = DllStructCreate($tagFILETIME)
    If $fLocal Then
        $tQW = DllStructCreate('uint64 Timestamp')
    Else
        $tQW = DllStructCreate('uint64 Timestamp', DllStructGetPtr($tFT))
    EndIf
    $tPacket.Packet = $bPacket
    $tQW.Timestamp = Dec(StringMid(DllStructGetData($tNTP, 'TransmitTimestamp'), 3, 8), 2) * 10000000 + 94354848000000000
    If $fLocal Then
        $aResult = DllCall('kernel32.dll', 'bool', 'FileTimeToLocalFileTime', 'struct*', $tQW, "struct*", $tFT)
        If (@Error) Or (Not $aResult[0]) Then
            Return SetError(3, 0, 0)
        EndIf
    EndIf
    Return $tFT
EndFunc   ;==>_NTP_FT

$tFT = _NTP_FT('pool.ntp.org')

ConsoleWrite(_Date_Time_FileTimeToStr($tFT) & @CRLF)

[mLipok]

@Yashied
why its return:

  Quote

01/01/1900 02:00:01

Edited April 1, 2015 by mLipok

[Yashied]

What AutoIt version? Please check the following:

 

Dec(StringMid(DllStructGetData($tNTP, 'TransmitTimestamp'), 3, 8), 2)

Edited April 1, 2015 by Yashied

[mLipok]

Au3.3.10.2 return 1

Au3.3.13.20 return 0

[Yashied]

I'm using 3.3.12.0

[mLipok]

  On 4/1/2015 at 8:59 AM, mLipok said:

@Yashied

why its return:

01/01/1900 02:00:01

on

Au3.3.13.20 this rerturn empty string.

but then I try again with Au3.3.10.2 and again empty string.

It is strange behavior.

 

  On 4/1/2015 at 9:23 AM, Yashied said:

What AutoIt version? Please check the following:

 

Dec(StringMid(DllStructGetData($tNTP, 'TransmitTimestamp'), 3, 8), 2)

 

  On 4/1/2015 at 9:36 AM, Yashied said:

I'm using 3.3.12.0

and what result you have ?