Changing a window's icon.

[Armand]

Hi,

I'd like to know if it's possible to change the icon of window other then my own created one.

For example - notepad's icon into some other icon.

Thanks in advance,

SK.

[guinness]

You will need to change it a little bit >> but since you have 500+ posts I guess you're not looking for a ready made solution.

[Armand]

doesn't seem to work on anything other then AU3 GUIS... I want to change other applications window's icon... like notepad's...
 
trying this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>


HotKeySet("+!t", "ChangeWindowTitle")


Global $CurrentActiveWindow, $PreviousActiveWindow


While 1
Sleep(1000)
CheckTitles()
WEnd


Func CheckTitles()
If WinGetTitle("[ACTIVE]") <> $CurrentActiveWindow Then
$PreviousActiveWindow = $CurrentActiveWindow
$CurrentActiveWindow = WinGetTitle("[ACTIVE]")
EndIf
EndFunc


Func ChangeWindowTitle()
WinSetTitle("[ACTIVE]", "", $PreviousActiveWindow)
$hWnd = WinGetHandle("[ACTIVE]")
If Not IsHWnd($hWnd) Then MsgBox(0, "ERROR", "")
_GUISetIcon($hWnd, "H:\Programming\AU3 in progress\Failure.ico", "")
EndFunc




Func _GUISetIcon($hWnd, $sFilePath, $iName)
    If Not IsHWnd($hWnd) Then
        Local $iLabel = GUICtrlCreateLabel('', -99, -99, 1, 1)
        $hWnd = _WinAPI_GetParent(GUICtrlGetHandle($iLabel))
        If @error Then
            Return SetError(@error, 0 * GUICtrlDelete($iLabel), 0)
        EndIf
        GUICtrlDelete($iLabel)
    EndIf
    Local $hIcon = _WinAPI_LoadImage(_WinAPI_GetModuleHandle($sFilePath), $iName, 1, 32, 32, 0)
    Return _SendMessage($hWnd, $WM_SETICON, 1, $hIcon)
EndFunc   ;==>_GUISetIcon

[guinness]

As I said you will need to tweak it. It's no surprise it doesn't work.

[johnmcloud]

; Author: Mikell
#include <WinAPI.au3>

Run("notepad.exe")
Do
  Sleep(10)
Until WinExists("[CLASS:Notepad]")
Local $hWnd = WinGetHandle("[CLASS:Notepad]")

_WinSetIcon($hWnd, "shell32.dll", 25)
;~ _WinSetIcon($hWnd, "X:\Path\Icon.ico")
WinSetTitle($hWnd, "", "Testing")

;=========================================
Func _WinSetIcon($hWnd, $sFile, $iIndex = 0)
    Local $tIcons = DllStructCreate("ptr Data")
    DllCall("shell32.dll", "uint", "ExtractIconExW", "wstr", $sFile, "int", $iIndex, "struct*", 0, "struct*", $tIcons, "uint", 1)
    If @error Then Return SetError(1, 0, 0)
    Local $hIcon = DllStructGetData($tIcons, "Data")
   _SendMessage($hWnd, 0x0080, 1, $hIcon ) ;$WM_SETICON = 0x0080
   _WinAPI_DestroyIcon($hIcon)
   Return 1
EndFunc

[Armand]

Awesome !

johnmcloud

Thanks for the quick solution

p.s. thank you too 

guinness

[aVen9er]

It checked and it works on 32-bit applications.

How to make it work on 64-bit applications?

[Melba23]

aVen9er,

Stick to just the one thread please - I have deleted your duplicate post.

M23

[Nine]

There may be something wrong with your code.  Using this :

#include <WinAPI.au3>
#include <WinAPIIcons.au3>
#include <WindowsConstants.au3>

Const $sTitle = "Testing"
;Run ("Testing.exe")

Do
  Sleep(10)
Until WinExists($sTitle)
Local $hWnd = WinGetHandle($sTitle)
Sleep(1000)
_WinSetIcon($hWnd, "shell32.dll", 41)

Func _WinSetIcon($hWnd, $sFile, $iIndex = 0)
  Local $hIcon = _WinAPI_ExtractIcon($sFile, $iIndex, True)
  _SendMessage($hWnd, $WM_SETICON, 1, $hIcon)
  ConsoleWrite(_WinAPI_DestroyIcon($hIcon) & @CRLF)
EndFunc   ;==>_WinSetIcon

With a compiled x64 AutoIt GUI :

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseX64=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Testing")
    Local $idOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idOK
                ExitLoop

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Works fine even if first script is x86.  Works also if second script.exe is ran inside or outside first script.

[aVen9er]

Your example works, but I am trying to change the Total Commander (x64) icon and it doesn't work. (Interestingly works on x86 Total Commander)

#include <WinAPI.au3>
#include <WinAPIIcons.au3>
#include <WindowsConstants.au3>

Const $sTitle = "[Title:Total Commander (x64);Class:TTOTAL_CMD]"

Do
    Sleep(10)
Until WinExists($sTitle)


Local $hWnd = WinGetHandle($sTitle)
Sleep(1000)
_WinSetIcon($hWnd, "shell32.dll", 41)


Msgbox(0, @ScriptName, WinExists($sTitle))      ; checked: Window exists


Func _WinSetIcon($hWnd, $sFile, $iIndex = 0)
    Local $hIcon = _WinAPI_ExtractIcon($sFile, $iIndex, True)
    _SendMessage($hWnd, $WM_SETICON, 1, $hIcon)
    ConsoleWrite(_WinAPI_DestroyIcon($hIcon) & @CRLF)
EndFunc   ;==>_WinSetIcon

 

How to change the icon in Total Commander (x64)?

Edited August 1, 2020 by aVen9er

[Jos]

Did you run the script with AutoIt3_x64.exe ?

[aVen9er]

I clicked "Run Script (x64)" it showed Msgbox, but didn't change the icon.

I also clicked "Compile Script (x64)", and then doubleclicked exe file. It also showed Msgbox, but didn't change the icon.