want to know how to replicate this Gui

[damian666]

hi guys, i was wondering if anyone knew how to replicate the following feature, a menubar on a listview i think it is :s

 

thanx in advance

[mLipok]

If I good understand you (and good see it) ,

You trying to add separate menu inside each Tab , or something similar ?

[damian666]

yes, thats exactly what im trying

[mLipok]

You can add Labels and PopUp menu for each Label.

[damian666]

hmm, that could work, ill try

[Melba23]

damian666,

I would do it using child GUIS like this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>

$hGUI = GUICreate("Test", 500, 500)

$cTab = GUICtrlCreateTab(10, 10, 480, 300)

$cTabItem_0 = GUICtrlCreateTabItem("Tab 0")

$cTabItem_1 = GUICtrlCreateTabItem("Tab 1")

$cTabItem_2 = GUICtrlCreateTabItem("Tab 2")

GUICtrlCreateTabItem("")

GUISetState(@SW_SHOW, $hGUI)

; Get tab position
$aTab_Pos = ControlGetPos($hGUI, "", $cTab)
; Get size of user area
$aTab_Rect = _GUICtrlTab_GetItemRect($cTab, 0)

; Create Child GUIs
$hChild_0 = GUICreate("Child 0", $aTab_Pos[2] - 6, $aTab_Pos[3] - $aTab_Rect[3] - 6, $aTab_Pos[0] + 2, $aTab_Pos[1] + $aTab_Rect[3] + 2, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
GUICtrlCreateMenu("Menu 00")
GUICtrlCreateMenu("Menu 01")
GUICtrlCreateMenu("Menu 02")
$aClient = WinGetClientSize($hChild_0)
GUICtrlCreateListView("Col 00|Col 01|Col 02", 10, 10, $aClient[0] - 20, $aClient[1] - 20)
GUISetState(@SW_SHOW, $hChild_0)
GUISetBkColor(0xFFCCCC, $hChild_0)

$hChild_1 = GUICreate("Child 1", $aTab_Pos[2] - 6, $aTab_Pos[3] - $aTab_Rect[3] - 6, $aTab_Pos[0] + 2, $aTab_Pos[1] + $aTab_Rect[3] + 2, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
GUICtrlCreateMenu("Menu 10")
GUICtrlCreateMenu("Menu 21")
GUICtrlCreateMenu("Menu 32")
GUICtrlCreateListView("Col 10|Col 11|Col 12", 10, 10, $aClient[0] - 20, $aClient[1] - 20)
GUISetBkColor(0xCCFFCC, $hChild_1)
GUISetState(@SW_HIDE, $hChild_1)

$hChild_2 = GUICreate("Child 2", $aTab_Pos[2] - 6, $aTab_Pos[3] - $aTab_Rect[3] - 6, $aTab_Pos[0] + 2, $aTab_Pos[1] + $aTab_Rect[3] + 2, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
GUICtrlCreateMenu("Menu 20")
GUICtrlCreateMenu("Menu 21")
GUICtrlCreateMenu("Menu 22")
GUICtrlCreateListView("Col 20|Col 21|Col 20", 10, 10, $aClient[0] - 20, $aClient[1] - 20)
GUISetBkColor(0xCCCCFF, $hChild_2)
GUISetState(@SW_HIDE, $hChild_2)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cTab
            Switch GUICtrlRead($cTab)
                Case 0
                    _HideAll()
                    GUISetState(@SW_SHOW, $hChild_0)
                Case 1
                    _HideAll()
                    GUISetState(@SW_SHOW, $hChild_1)
                Case 2
                    _HideAll()
                    GUISetState(@SW_SHOW, $hChild_2)
            EndSwitch
    EndSwitch
WEnd

Func _HideAll()
    GUISetState(@SW_HIDE, $hChild_0)
    GUISetState(@SW_HIDE, $hChild_1)
    GUISetState(@SW_HIDE, $hChild_2)
EndFunc

Please ask if you have any questions.

M23

[damian666]

hi melba23,

thats a lot of code for such a little feature

does this work with Opt("GUIOnEventMode", 1) ?

[Melba23]

damian666,

 

thats a lot of code for such a little feature

If you want a menu control inside a tab control I can see no other way of doing it - making a user-drawn menu bar would be a lot more work.

 

does this work with Opt("GUIOnEventMode", 1) ?

Did you even try?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>

Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("Test", 500, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

$cTab = GUICtrlCreateTab(10, 10, 480, 300)
GUICtrlSetOnEvent($cTab, "_Tab")

$cTabItem_0 = GUICtrlCreateTabItem("Tab 0")

$cTabItem_1 = GUICtrlCreateTabItem("Tab 1")

$cTabItem_2 = GUICtrlCreateTabItem("Tab 2")

GUICtrlCreateTabItem("")

GUISetState(@SW_SHOW, $hGUI)

; Get tab position
$aTab_Pos = ControlGetPos($hGUI, "", $cTab)
; Get size of user area
$aTab_Rect = _GUICtrlTab_GetItemRect($cTab, 0)

; Create Child GUIs
$hChild_0 = GUICreate("Child 0", $aTab_Pos[2] - 6, $aTab_Pos[3] - $aTab_Rect[3] - 6, $aTab_Pos[0] + 2, $aTab_Pos[1] + $aTab_Rect[3] + 2, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
GUICtrlCreateMenu("Menu 00")
GUICtrlCreateMenu("Menu 01")
GUICtrlCreateMenu("Menu 02")
$aClient = WinGetClientSize($hChild_0)
GUICtrlCreateListView("Col 00|Col 01|Col 02", 10, 10, $aClient[0] - 20, $aClient[1] - 20)
GUISetState(@SW_SHOW, $hChild_0)
GUISetBkColor(0xFFCCCC, $hChild_0)

$hChild_1 = GUICreate("Child 1", $aTab_Pos[2] - 6, $aTab_Pos[3] - $aTab_Rect[3] - 6, $aTab_Pos[0] + 2, $aTab_Pos[1] + $aTab_Rect[3] + 2, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
GUICtrlCreateMenu("Menu 10")
GUICtrlCreateMenu("Menu 21")
GUICtrlCreateMenu("Menu 32")
GUICtrlCreateListView("Col 10|Col 11|Col 12", 10, 10, $aClient[0] - 20, $aClient[1] - 20)
GUISetBkColor(0xCCFFCC, $hChild_1)
GUISetState(@SW_HIDE, $hChild_1)

$hChild_2 = GUICreate("Child 2", $aTab_Pos[2] - 6, $aTab_Pos[3] - $aTab_Rect[3] - 6, $aTab_Pos[0] + 2, $aTab_Pos[1] + $aTab_Rect[3] + 2, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
GUICtrlCreateMenu("Menu 20")
GUICtrlCreateMenu("Menu 21")
GUICtrlCreateMenu("Menu 22")
GUICtrlCreateListView("Col 20|Col 21|Col 20", 10, 10, $aClient[0] - 20, $aClient[1] - 20)
GUISetBkColor(0xCCCCFF, $hChild_2)
GUISetState(@SW_HIDE, $hChild_2)

While 1
    Sleep(10)
WEnd

Func _Exit()
    Exit
EndFunc   ;==>_Exit

Func _Tab()
    Switch GUICtrlRead($cTab)
        Case 0
            _HideAll()
            GUISetState(@SW_SHOW, $hChild_0)
        Case 1
            _HideAll()
            GUISetState(@SW_SHOW, $hChild_1)
        Case 2
            _HideAll()
            GUISetState(@SW_SHOW, $hChild_2)
    EndSwitch
EndFunc   ;==>_Tab

Func _HideAll()
    GUISetState(@SW_HIDE, $hChild_0)
    GUISetState(@SW_HIDE, $hChild_1)
    GUISetState(@SW_HIDE, $hChild_2)
EndFunc   ;==>_HideAll

M23

[damian666]

to be honest, no i didnt, i had no clue how to modify the code from the example to onevent mode, i always use o event, never use the other way xd

i think your right, this is the best way, thank you very much

dami