Weird Browser Issue

[Chimaera]

Just been playing with it and came up with this so i can call it when needed

Local $BClose = _BrowserClose()

Func _BrowserClose()
        Local $sBrowserString = "|iexplore.exe|chrome.exe|firefox.exe"
        Global $aBrowserKeys = StringSplit($sBrowserString, "|")
;~      _ArrayDisplay( $aBrowserKeys)
        For $i = 1 To $aBrowserKeys[0]
            While ProcessExists($aBrowserKeys[$i])
;~              ConsoleWrite($aBrowserKeys[$i] & @CRLF)
                ProcessClose($aBrowserKeys[$i])
            WEnd
        Next
EndFunc ;==>  _BrowserClose()

I tried with the guinness version but couldnt get it to cycle through the browser names properly

Thanks to all for the help

[JohnOne]

Looks good, and don't worry about a bottleneck is does not apply, while your script is in that loop it is not doing anything else.

In your script though, I would warn the user that their browsers are about to be closed, and give them the opportunity to save any work.

[guinness]

don't worry about a bottleneck is does not apply

Wrong. Edited March 15, 2015 by guinness

[Chimaera]

In your script though, I would warn the user that their browsers are about to be closed, and give them the opportunity to save any work.

Its a tech checking a machine no users involved

[JohnOne]

No worries then.

[guinness]

Chimaera,

Anything you can do with a For loop you can do with a While loop. If you want I can send you a link to programming basics, as understanding loops is a fundamental concept that every programmer should understand at some point. Your comment about While loops only being for GUIs has been on my mind today, which means the help file is lacking clarification or we've told you this.

For $i = 0 To 10 ; This loop
    ConsoleWrite($i & @CRLF)
Next

ConsoleWrite(@CRLF)

Local $j = 0 ; Is the same as this loop
While $j <= 10
    ConsoleWrite($j & @CRLF)
    $j += 1
WEnd

Edited March 15, 2015 by guinness

[Chimaera]

As we all know loops and arrays are mostly my bugbear, that and anything above three lines of code

Like ive said before im not a programmer, part time hobbyist maybe, theres holes in my knowledge you could drive a bus through.

However i try but ive never been able to grasp the concept of certain things, i played with while/wend outside of the main exit button loop before it and ended up getting in a right mess so i stopped using them because i figured i was off the edge doing daft stuff

And since i found in that instance it wasnt a good idea i never went back to it until now, if i had made your example work as i wanted then i wouldnt be using it now in all honesty.

I tend to stick to what works in my limited sense of Autoit which is diffucult to explain to proper programmers like yourself

[guinness]

Maybe give yourself a little more credit than that, though I take what you have said and won't pester you anymore.

[Chimaera]

Well maybe a little but not much, and your not pestering at all, you should know by now with me if you need to know something just ask.

Getting back to this

Local $aList = ProcessList('chrome.exe')
If $aList[0][0] > 0 Then ; An array is returned and @error is NEVER set, so lets check the count.
    _ArrayDisplay($aList)
    Local $bIsProcessClosed = False ; Declare a variable to hold a boolean.
    For $i = 1 To $aList[0][0]
        $bIsProcessClosed =  ProcessClose($aList[$i][1]) ; In AutoIt 0 or 1 can be considered boolean too. It's like a bit in SQL or in C, where 1 and 0 means true or false.
    Next
EndIf

If $aList[0][0] > 0 Then Is this just saying because processlist doesnt return an error then if its greater than 0 just carry on?

Local $bIsProcessClosed = False why did we suddenly end up as boolean? Is this not sufficent   Local $bIsProcessClosed = ''

$bIsProcessClosed = ProcessClose($aList[$i][1]) i dont get this line at all is the one for the PID? or something else? 

If its for the PID what does your comment relate to?

Bear in mind ive just had google Boolean so dont get too technical

Edited March 16, 2015 by Chimaera

[guinness]

Honestly I just copied the code you gave me and fixed it up.

 

If $aList[0][0] > 0 Then Is this just saying because processlist doesnt return an error then if its greater than 0 just carry on?

Correct. As it doesn't return @error and it returns an array, then check the count element contains 1 or above.

 

Local $bIsProcessClosed = False why did we suddenly end up as boolean? Is this not sufficent Local $bIsProcessClosed = ''

There is a wiki article on best practices which states it's best to use the datatype associated by the prefix e.g. this variable ($sName) holds a string, therefore doing this ... $sString = 0 is wrong as it's assigning an integral datatype to a variable which should hold a string. Why? Well my thought process behind this (and as I explained to czardas) is I wanted users to get used to thinking this way of having variables hold only one specific datatype. It leads to less errors AND when a user moves to bigger & better languages like C# and Java, then it's not a big habit to change. We're lucky (or unlucky in some cases) that any datatype can be assigned to a variable in AutoIt, but in many cases I have seen, some people forget what datatype is in a variable and can do awful things e.g. 

Local $x;
$x = "Something" ; It's a string
; ... somewhere down the line.
$x = $x + 10 ; But wait isn't x a string and not an integral datatype? What happens here?
ConsoleWrite(x & @CRLF)

$bIsProcessClosed = ProcessClose($aList[$i][1]) i dont get this line at all is the one for the PID? or something else?

If its for the PID what does your comment relate to?

I copied it from your code, but my point was in other languages 0 and 1 are considered boolean as well, so since ProcessClose returns only 0 or 1, lets treat it like a boolean and not an integer.

The code would be better like this...

Local $aList = ProcessList('chrome.exe')
If $aList[0][0] > 0 Then ; An array is returned and @error is NEVER set, so lets check the count.
    _ArrayDisplay($aList)
    Local $bIsProcessClosed = False ; Declare a variable to hold a boolean.
    For $i = 1 To $aList[0][0]
        $bIsProcessClosed =  ProcessClose($aList[$i][1]) ; In AutoIt 0 or 1 can be considered boolean too. It's like a bit in SQL or in C, where 1 and 0 means true or false.
        If Not $bIsProcessClosed Then ConsoleWrite('CLOSE ERROR PID: ' & $aList[$i][1] & @CRLF)
    Next
EndIf

Edited March 16, 2015 by guinness

[Chimaera]

Ok ill have a think about it

Thanks for the time and explanation, ill get back to it later im still trying to convert your earlier example to work like i made johns with multiple browser types so there may be another question or two yet lol

[guinness]

Not too difficult...unless I misunderstood your point.
 

#include <StringConstants.au3>

Local $aList = 0
Local $aProcesses = StringSplit('chrome.exe|firefox.exe', '|', $STR_NOCOUNT) ; Multiple processes
For $i = 0 To UBound($aProcesses) - 1
    $aList = ProcessList($aProcesses[$i])
    If $aList[0][0] > 0 Then ; An array is returned and @error is NEVER set, so lets check the count.
        _ArrayDisplay($aList)
        Local $bIsProcessClosed = False ; Declare a variable to hold a boolean.
        For $j = 1 To $aList[0][0]
            $bIsProcessClosed = ProcessClose($aList[$j][1]) ; In AutoIt 0 or 1 can be considered boolean too. It's like a bit in SQL or in C, where 1 and 0 means true or false.
            If Not $bIsProcessClosed Then ConsoleWrite('CLOSE ERROR PID: ' & $aList[$j][1] & @CRLF)
        Next
    EndIf
Next

[Chimaera]

Yes thats what i meant

Ive been wrestling with why array add wouldnt add the array from process list for the last 1/2 hour

And i think the answer is because its a multiple array not one line

Thx again ill go and study