How to remove gray colour after tabs?

[TheDcoder]

How to remove grey area after the tabs?

Code:

; -- Created with ISN Form Studio 2 for ISN AutoIt Studio -- ;
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiButton.au3>
#include <GuiTab.au3>

$GUI = GUICreate("GUI",350,350,-1,-1,-1,-1)
GUISetBkColor(0xFFFFFF,$GUI)
$tab = GUICtrlCreatetab(10,10,335,329,-1,-1)
GuiCtrlSetState(-1,2048)
GUICtrlCreateTabItem("Page 1")
GUICtrlCreateTabItem("Page 2")
GUICtrlCreateTabItem("Page 3")
GUICtrlCreateTabItem("Page 4")
GUICtrlCreateTabItem("Page 5")
GUICtrlCreateTabItem("")
_GUICtrlTab_SetCurFocus($tab,-1)
_GUICtrlTab_SetCurFocus($tab,0)

[mLipok]

Add label.

[Melba23]

TheDcoder,

The only way I know is to create a label to cover that area - this shows you how you might do it:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTab.au3>

Local $iTabX = 10, $iTabY = 10, $iTabW = 335

$GUI = GUICreate("GUI", 350, 350)
GUISetBkColor(0xFFFFFF, $GUI)

$cTab = GUICtrlCreateTab($iTabX, $iTabY, $iTabW, 329)
GUICtrlSetState($cTab, 2048)
GUICtrlCreateTabItem("Page 1")
GUICtrlCreateTabItem("Page 2")
GUICtrlCreateTabItem("Page 3")
GUICtrlCreateTabItem("Page 4")
GUICtrlCreateTabItem("Page 5")
GUICtrlCreateTabItem("")

; Move along tab items to find end
For $iOffSetX = 10 To $iTabW
    $aRet = _GUICtrlTab_HitTest($cTab, $iOffSetX, $iTabY + 5)
    If $aRet[0] = -1 Then ExitLoop
Next

; Create a label to cover the grey area
$cLabel = GUICtrlCreateLabel("", $iTabX + $iOffSetX, $iTabY, $iTabW - $iOffSetX, 20)
GUICtrlSetBkColor($cLabel, 0xFF0000) ; Red for clarity!!!

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

M23