Read/Display file content - non txt file

[mLipok]

Some time ago I ask How to Read/Display file content - non txt file ?.

here is my new version:

expandcollapse popup

Example()

Func Example()

    Local $hTimer = 0
    Local $sText = ''

    $hTimer = TimerInit()
    $sText = _GetTextFromTextStream(@ScriptDir & "\TEST123_Polish.skk")
    MsgBox(0, '# of lines = ' & @extended & ' in ' & Round(TimerDiff($hTimer) / 1000, 3) & ' sec.', $sText)

    $hTimer = TimerInit()
    $sText = _GetTextFromTextStream(@ScriptDir & "\TEST123_Polish.skk", False)
    MsgBox(0, '# of lines = ' & @extended & ' in ' & Round(TimerDiff($hTimer) / 1000, 3) & ' sec.', $sText)

    ; the text should be like this
    #cs
        Polish Diacritic mark: ąćęłńóśżź
        English: acelnoszz
    #ce


EndFunc   ;==>Example

; #FUNCTION# ====================================================================================================================
; Name ..........: _GetTextFromTextStream
; Description ...: Get text from binary file.
; Syntax ........: _GetTextFromTextStream($sFileFullPath[, $bGetAsLine = True])
; Parameters ....: $sFileFullPath       - a string value.
;                  $bGetAsLine          - [optional] a boolean value. Default is True.
; Return values .: Text or set @error to non zero
; Author ........: mLipok
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _GetTextFromTextStream($sFileFullPath, $bGetAsLine = True)
    Local Const $iForReading = 1, $iForWriting = 2, $iForAppending = 3
    Local Const $iTristateUseDefault = -2, $iTristateTrue = -1, $iTristateFalse = 0

    Local $oFSO = ObjCreate("Scripting.FileSystemObject")
    If @error Then Return SetError(1, 0, '')

    Local $oFile = $oFSO.GetFile($sFileFullPath)
    If @error Then Return SetError(2, 0, '')

    Local $oTS = $oFile.OpenAsTextStream($iForReading, $iTristateUseDefault)
    If @error Then Return SetError(3, 0, '')

    Local $sText = ''
    Local $sTemp = ''
    Do
        If $bGetAsLine Then
            $sText &= $oTS.ReadLine
        Else
            $sText &= $oTS.Read(1)
        EndIf
    Until $oTS.AtEndOfStream

    Local $iLineCounter = $oTS.Line

    $oTS.Close
    $oFile = ''
    $oFSO = ''

    Return SetExtended($iLineCounter, $sText)

EndFunc   ;==>_GetTextFromTextStream

_GetTextFromTextStream.ZIP

Edited February 26, 2015 by mlipok

[UEZ]

Nice catch using the Scripting.FileSystemObject object but the output is different compared to link you have provided.

 

Br,

UEZ

[mLipok]

Yes, I know. That's life.

But it is enough for me and the speed is just outstanding.

 

mLipok

[TheSaint]

Thanks for sharing.

Perhaps you could do a brief list at first post, of the file types this is likely to support (i.e. doc, rtf, pdf, etc).

And perhaps what isn't supported ... and a reason maybe?

You don't have to do any of that of course, but I reckon it would be a good idea.

[orbs]

i can confirm it supports .doc files (Word 97-2003 format). although along with the text it does produce the entire metadata. a method to trim away the metadata must be specific per file type, i imagine.

[JohnOne]

I'm unsure I understand what this is doing that FileRead is not, apart from stripping EOL chars.

[mLipok]

This function is useful for me to search files based on their content.

I know that there are other methods but require calling other programs.

Unless someone will show me some other native method.

[mLipok]

I'm unsure I understand what this is doing that FileRead is not, apart from stripping EOL chars.

Can you show example with the same *.skk file?

[JohnOne]

No, I'm just saying I don't understand what it does, description, "gets text from a binary file", fileread can do that.

[mLipok]

If you try then you understand.

[llewxam]

I guess I cheat, I use BinaryToString followed by StringRegExp but this is my solution. Tested with your .skk file searching for "LaserJet 1020" which worked, works on PDFs, .xls, .doc (but NOT .xlsx or .docx unfortunately) and many other file types.

Anyhoo, never shared this before, thought this was a good time.

Ian

Edit - posted an updated version, see my sig for the link.

Edited March 2, 2015 by llewxam

[Melba23]

llewxam,

 

NOT .xlsx or .docx

See >this post to understand why - and subsequent posts to see how you can still search these file types.

M23

[llewxam]

Melba23, I know I have said it before, but I love you man!!!

I will add a special case to my above app shortly and start a new thread in the Examples section with the updated code.

THANKS!!!

Ian

[TheSaint]

Anyhoo, never shared this before, thought this was a good time.

Thanks for sharing, and Melba23 beat me to it.

I look forward to what you come up with.

mlipok may even come up with something more expansive now, perhaps incorporating some of your ideas and others ... or both of you will.

[mLipok]

I guess I cheat, I use BinaryToString followed by StringRegExp but this is my solution. Tested with your .skk file searching for "LaserJet 1020" which worked, works on PDFs, .xls, .doc (but NOT .xlsx or .docx unfortunately) and many other file types.

Anyhoo, never shared this before, thought this was a good time.

Ian

 

I checked.

It works the way I wanted.

It dawned on me.

 

I'll have a few questions, but first I need to formulate them well.

It will take some time, because today I have other tasks to perform (laundry, cleaning, putting the baby to sleep, watch a romantic comedy with my wife EDIT: ... And other interesting things which I will not describe here ...).

 

Best regards,

mLipok

 

Edited February 28, 2015 by mlipok

[mLipok]

Cramp it were that simple.

Local $sRead = FileRead(@ScriptDir & '\TEST123_Polish.skk')
$sRead = StringReplace($sRead, Chr(0), ' ')
MsgBox(0, '$sRead', $sRead)

But I'm angry with myself

Two years of unnecessary waiting.

Now I can finally make use of my head 

 

mLipok