Help Again - Identify exactly: $Var Is "Binary" or "String" or "Number"

[Trong]

I need a function to identify string, is number/string or Binary.
 

;
Local $Var='1z 2z-1z0z"0"z-1.2z1.0z2.1z0.2z2,1z0,6z99 z-0,3zStrzngz0x00z0xFFz1-z1.1-z2-z0xF0Fz~z!z@z#z$z%z^z&z*z)z(z_z+z|z>z<z?z:z;z}z{z]z[z-z=z\z/z.z,z';
Local $sVar=StringSplit($Var,"z"),$x;
For  $x = 1 To UBound($sVar)-1;
    Local $IsWhat=IsWhat($sVar[$x]);
    ConsoleWrite($sVar[$x]&" is: "&$IsWhat&@CRLF);
Next;
;
Func IsWhat($IsWhat);
    ;Return $IsWhat;
    Return "IsBinary Or IsString Or IsNumber";
EndFunc;
;
;
;
;
;
;
;
;
;
;
;

[Melba23]

Trong,

VarGetType - look in the Help file for more details.

M23

[Trong]

Trong,

VarGetType - look in the Help file for more details.

M23

It is bad!

Func IsWhat($IsWhat);
    Return VarGetType($IsWhat)
EndFunc;

Edit:

It does not work correctly with the quote.

Identify anything is string!

Edited February 25, 2015 by Trong

[Melba23]

Trong,

It is good:

$sString = "String"
ConsoleWrite(IsWhat($sString) & @CRLF)

$iInteger = 2
ConsoleWrite(IsWhat($iInteger) & @CRLF)

$nDouble = 1.234
ConsoleWrite(IsWhat($nDouble) & @CRLF)

Func IsWhat($IsWhat)
    Return VarGetType($IsWhat)
EndFunc

And I thought you were going to stop using the "Quote button?

M23

[Trong]

I remember, but the quote is necessary in this case.

What happens when:

$nDouble = "1.234";IsString 

1.234 is a Number

[bogQ]

no, "1.234" is a string 1.234 is a Float

try with StringIsFloat maybe?

note that you can open help file on StringIsFloat and try the example on that help file page, do a index type for StringIs and look @ variety of commands

edit:

reading from all of your topics i think you only need to check for 2 things

StringIsFloat ?

StringIsInt ?

Edited February 25, 2015 by bogQ

[BrewManNH]

Be aware though that nothing will be identified as a Binary number unless you send it to the function using Binary on the number first. Also remember, that a hexidecimal number is just a base 16 number representation of a base 10 number. So if you send it a hex number, it's going to be translated to an integer, and using Hex on it will convert it to a string.

$sString = "String"
ConsoleWrite(IsWhat($sString) & @CRLF)
$iInteger = 2
ConsoleWrite(IsWhat($iInteger) & @CRLF)
$nDouble = 1.234
ConsoleWrite(IsWhat($nDouble) & @CRLF)
$nBinary = 0x556
ConsoleWrite(IsWhat($nBinary) & @CRLF)
ConsoleWrite(IsWhat(Binary($nBinary)) & @CRLF)
ConsoleWrite(IsWhat(Hex($nBinary)) & @CRLF)
Func IsWhat($IsWhat)
    Return VarGetType($IsWhat)
EndFunc

Edited February 25, 2015 by BrewManNH

[SmOke_N]

You could always roll your own, but as brew said above, your hex "0xAB" will be considered a binary string in this code, not an integer

Func _myCustomFunc($vVal)

    Local Const $sBin = "(?i)^0x[a-z\d]+$"
    Local $iLen = StringLen($vVal)

    Local $sType = VarGetType($vVal)
    If $sType = "Binary" Then Return "Binary"

    If $iLen > 2 And Mod($iLen, 2) = 0 And _
        StringRegExp($vVal, $sBin) Then Return "Binary"

    If StringIsInt($vVal) Then
        If Abs($vVal) <= 2147483647 Then Return "Int32"
        Return "Int64"
    EndIf

    If StringIsFloat($vVal) Then Return "Number"

    Return $sType
EndFunc

.

[Trong]

Thank all for reply.

Problems and what I need is:

If it is "string" but it is "number" it is "number".

With the Number is: 0, 1, 2, 3, 4, 5, 6 ,7 ,8 ,9 , 0, "0", "1.0", 0.1, -1.2, -2, "-3",...etc....

With the String is: 1-, 0.4-,0xA0G,QWERTYUIOPASDFGHJKLZXCVBNM,./<>?Ơ]ơ};':"~!@#$%^&*()_+|-=,...etc....

With the Binary is: 0xABCDEF0123456789

[SmOke_N]

Func _myCustomFunc($vVal)

    Local Const $sBin = "(?i)^0x[a-z\d]+$"

    If IsInt($vVal) Or StringIsInt($vVal) StringIsFloat($vVal) Then
        Return "Number"
    EndIf
    
    Local $iLen = StringLen($vVal)

    Local $sType = VarGetType($vVal)

    If $sType = "Binary" Or ($iLen > 2 And Mod($iLen, 2) = 0 And _
        StringRegExp($vVal, $sBin)) Then
        Return "Binary"
    EndIf
        
    Return $sType
EndFunc

Edit:

Hate editing in this thing

Edited February 25, 2015 by SmOke_N

[Trong]

reading from all of your topics i think you only need to check for 2 things

StringIsFloat ?

StringIsInt ?

It worked

Func _myCustomFunc($vVal)
    Local Const $sBin = "(?i)^0x[a-z\d]+$"
    If IsInt($vVal) Or StringIsInt($vVal) Or StringIsFloat($vVal) Then
        Return "Number"
    EndIf
    
    Local $iLen = StringLen($vVal)

    Local $sType = VarGetType($vVal)

    If $sType = "Binary" Or ($iLen > 2 And Mod($iLen, 2) = 0 And _
        StringRegExp($vVal, $sBin)) Then
        Return "Binary"
    EndIf
        
    Return $sType
EndFunc